精华内容
下载资源
问答
  • 将TXT文档的数据按照一定的格式写入Excel,并跟据日期或者特定条件可以查询数据,并自动绘制曲线图!不含任何空间,纯代代码,方便移植。
  • VBA_读写文件

    2012-10-18 16:31:36
    介绍了VBA读写文件的方法以及需要用到的指令,函数。
  • vba文本文件读写

    2020-05-01 16:18:06
    特别注意:write2TextFile里的strbuf = .readtext,表示是读取文件内容,此时游标在所有文本后面,写入内容的话就变成追加。建议换行后再写新内容。 如果注释掉strbuf = .readtext,就从文件头开始写。如果新文本...

    设置编码格式的写入

    特别注意:write2TextFile里的strbuf = .readtext,表示是读取文件内容,此时游标在所有文本后面,写入内容的话就变成追加。建议换行后再写新内容。
    如果注释掉strbuf = .readtext,就从文件头开始写。如果新文本长度大于原内容长度,相当于实现覆盖的效果。否则会出现新文本原文本混合的情况。如果原文件文本是12345,新内容是666,写完就是66645。
    似乎adodb.stream没有删除文本的功能,所以函数里直接删除文件再创建了。
    还有其他的写入方法,可以删除文本,必要时再学习。

    Function write2TextFile(ByVal content As String, ByVal filepath As String, Optional addMode = True, Optional ByVal fso = Nothing, Optional ByVal charset = "utf-8")
        'filepath = "C:\Users\user\Desktop\1.txt"
        Set ads = CreateObject("adodb.stream")
        
        If fso Is Nothing Then
            fsoExists = True            ''''fsoExists用来关闭fso
            Set fso = CreateObject("scripting.filesystemobject")
        End If
        
        'folderExits = fso.folderexists(filepath)   ''''文件夹是否存在
        fileExits = fso.fileexists(filepath)        ''''文件是否存在
        If fileExits And Not addMode Then
            fso.DeleteFile filepath
            fileExits = False
        End If
        If Not fileExits Then
            'fso.createfolder (filepath)     'create folder     ''''创建文件夹
            Set note = fso.CreateTextFile(Filename:=filepath, overwrite:=True)      ''''创建文本文件
            note.Close      ''''这里不close下面.LoadFromFile filepath会报错
            Set note = Nothing
        End If
    
       With ads
            .charset = charset
            .Open
            .LoadFromFile filepath
            If addMode Then
                strbuf = .readtext
                .writetext vbCrLf
            End If
            
            .writetext content
            
            .savetofile filepath, 2
            .flush
            .Close
        End With
    
    
        Set ads = Nothing
        If fsoExists Then       ''''这个if判断用来关闭fso
            Set fso = Nothing
        End If
    End Function
    
    展开全文
  • VBA 读写文件

    2014-12-22 15:51:24
    处理文本文件 1、Open 语句 语法:Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength] 其中access、lock、reclength为可选参数,一般不用。 mode 指定打开文件的方式。有5种: ...
    

    处理文本文件

    1、Open 语句

    语法:Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength]

    其中access、lock、reclength为可选参数,一般不用。
    mode 指定打开文件的方式。有5种:
    Input:以输 入方式打开,即读取方式。
    Output:以输出方式打开,即写入方式。
    Append:以追加方式打开,即添加内容到文件末尾。
    Binary: 以二进制方式打开。
    Random:以随机方式打开,如果未指定方式,则以 Random 方式打开文件。

    filenumber  是一个有效的文件号,范围在 1 到 511 之间。可以指定,也可使用 FreeFile 函数可得到下一个可用的文件号。

    说明:如果 pathname 指定的文件不存在,那么,在用 Append、Binary、Output、或 Random 方式打开文件时,可以建立这一文件。

    示例:
    Open "F:/TEST.txt" For Input As #1  '以输入方式打开
    Open "F:/TEST.xls" For Binary As #1  '以二进制方式打开

    2、Close 语句

    语法:Close [filenumberlist]
         filenumberlist 参数为一个或多个文件号,若省略 filenumberlist,则将关闭 Open 语句打开的所有活动文件。

    说明:打开文件后,必须在使用完后关闭文件。

    示例:
    Dim I, FileName
    For I = 1 To 3   
        FileName = "TEST" & I    ' 创建文件名。
        Open FileName For Output As #I    ' 打开文件。
        Print #I, "This is a test."    ' 将字符串写入文件。
    Next I
    Close    ' 将三个已打开的文件全部关闭。

    3、Reset 语句

    语法:Reset

    功能:关闭所有用 Open 语句打开的磁盘文件。

    说明:Reset 语句关闭 Open 语句打开的所有活动文件,并将文件缓冲区的所有内容写入磁盘。

    示例:
    Dim FileNumber
    For FileNumber = 1 To 5   
        Open "TEST" & FileNumber For Output As #FileNumber
        Write #FileNumber, "Hello World"    ' 将数据写入文件。
    Next FileNumber
    Reset    ' 关闭文件并将缓冲区内的数据写到磁盘中。

    4、FreeFile 函数

    语法:FreeFile[(rangenumber)]
          参数 rangenumber指定一个范围,以便返回该范围之内的下一个可用文件号。指定 0(缺省值)则返回一个介于 1 – 255 之间的文件号。指定 1 则返回一个介于 256 – 511 之间的文件号。

    功能:提供一个尚未使用的文件号。

    示例:
    Dim fnum As Integer

    fnum = FreeFile

    Open "F:/TEST.txt" For Input As #fnum

    Close #fnum


    5、EOF 函数

    语法:EOF(filenumber)

    功能:返回一个 Integer,它包含 Boolean 值 True,表明已经到达为 Random 或顺序 Input 打开的文件的结尾。

    6、LOF 函数

    语法:LOF(filenumber)

    功能:返回一个 Long,表示用 Open 语句打开的文件的大小,该大小以字节为单位。

    7、Loc 函数

    语法:LOc(filenumber)

    功能:返回一个 Long,在已打开的文件中指定当前读/写位置。


    8、Input # 语句

    语法:Input #filenumber, varlist

    功能:从已打开的顺序文件中读出数据并将数据指定给变量。

    说明:通常用 Write # 将 Input # 语句读出的数据写入文件。为了能够用 Input # 语句将文件的数据正确读入到变量中,在将数据写入文件时,要使用 Write # 语句而不使用 Print # 语句。使用 Write # 语句可以确保将各个单独的数据域正确分隔开。

    示例:
    本示例使用 Input # 语句将文件内的数据读入两个变量中。本示例假设 TESTFILE文件内含数行以 Write # 语句写入的数据;也就是说,每一行数据中的字符串部分都是用双引号括起来,而与数字用逗号隔开,例如,("Hello", 234)。

    Dim MyString, MyNumber
    Open "TESTFILE" For Input As #1      ' 打开输入文件。
    Do While Not EOF(1)       ' 循环至文件尾。
        Input #1, MyString, MyNumber      ' 将数据读入两个变量。
        Debug.Print MyString, MyNumber      ' 在立即窗口中显示数据。
    Loop
    Close #1         ' 关闭文件。

    9、Write # 语句

    语法:Write #filenumber, [outputlist]

    功能:将数据写入顺序文件。

    说明:通常用 Input # 从文件读出 Write # 写入的数据。
    如果省略 outputlist,并在 filenumber 之后加上一个逗号,则会将一个空白行打印到文件中。多个表达式之间可用空白、分号或逗号隔开。空白和分号等效。

    用 Write # 将数据写入文件时将遵循几个通用的约定,使得无论什么区域都可用 Input # 读出并正确解释数据:

    ·在写入数值数据时总使用句号作为十进制分隔符。

    ·对于 Boolean 类型的数据,或者打印 #TRUE# 或者打印 #FALSE#。无论在什么地区,都不将 True 和 False 这两个关键字翻译出来。

    ·使用通用的日期格式将 Date 类型的数据写入文件中。当日期或时间的部件丢失或为零时,只将现有部分写入文件中。

    ·如果 outputlist 的数据为 Empty,则不将任何数据写入文件。但对 Null 数据,则要写入 #NULL#。

    ·如果 outputlist 数据为 Null 数据,则将 #NULL# 写入文件中。

    ·对于 Error 类型的数据,输出看起来与 #ERROR errorcode# 一样。无论在什么地区,都不将关键字 Error 翻译出来。
    与 Print # 语句不同,当要将数据写入文件时,Write # 语句会在项目和用来标记字符串的引号之间插入逗号。没有必要在列表中键入明确的分界符。Write # 语句在将 outputlist 中的最后一个字符写入文件后会插入一个新行字符,即回车换行符,(Chr(13) + Chr(10))。

    示例:
    Open "F:/test.txt" For Output As #1      ' 打开输出文件。
    Write #1, "Hello World", 1234      ' 写入以逗号隔开的数据。
    Write #1,         ' 写入空白行。

    Dim MyBool, MyDate, MyNull, MyError
    ' 赋值 Boolean、Date、Null 及 Error 等。
    MyBool = False : MyDate = #February 12, 1969# : MyNull = Null
    MyError = CVErr(32767)
    ' Boolean 数据以 #TRUE# 或 #FALSE# 的格式写入。
    ' 日期以通用日期格式写入,例如:#1994-07-13# 代表
    ' 1994 年 1 月 13 日。Null 数据以 #NULL# 格式写入。
    ' Error 数据以 #ERROR 错误代号# 的格式写入。
    Write #1, MyBool; " is a Boolean value"
    Write #1, MyDate; " is a date"
    Write #1, MyNull; " is a null value"
    Write #1, MyError; " is an error value"
    Close #1    ' 关闭文件。

    我们可以看到写入的内容为:
    "Hello World",1234

    #FALSE#," is a Boolean value"
    #1969-02-12#," is a date"
    #NULL#," is a null value"
    #ERROR 32767#," is an error value"

    10、Line Input # 语句

    语法:Line Input #filenumber, varname

    功能:从已打开的顺序文件中读出一行并将它分配给 String 变量。

    说明:通常用 Print # 与 Line Input # 语句配合使用。
    Line Input # 语句一次只从文件中读出一个字符,直到遇到回车符 (Chr(13)) 或回车–换行符 (Chr(13) + Chr(10)) 为止。回车–换行符将被跳过,而不会被附加到字符串上。

    示例:
    Dim TextLine
    Open "TESTFILE" For Input As #1     ' 打开文件。
    Do While Not EOF(1)       ' 循环至文件尾。
        Line Input #1, TextLine      ' 读入一行数据并将其赋予某变量。
        Debug.Print TextLine      ' 在立即窗口中显示数据。
    Loop
    Close #1        ' 关闭文件。

    11、Input 函数

    语法:Input(number, [#]filenumber)
    其中number 指定要返回的字符个数。

    功能:返回 String,它包含以 Input 或 Binary 方式打开的文件中的字符。

    说明:通常用 Print # 或 Put 将 Input 函数读出的数据写入文件。Input 函数只用于以 Input 或 Binary 方式打开的文件。
    与 Input # 语句不同,Input 函数返回它所读出的所有字符,包括逗号、回车符、空白列、换行符、引号和前导空格等。

    示例:
    Dim MyChar
    Open "f:/test.txt" For Input As #1
    Do While Not EOF(1)       ' 循环至文件尾。
        MyChar = Input(1, #1)      ' 读入一个字符。
        Debug.Print MyChar      ' 显示到立即窗口。
    Loop
    Close #1

    下面这个函数可以将文本文件的数据一次读入到一个字符串(但是若包含中文时会出错,因为一个中文字占2个字节)。

    Public Function ReadText(FileName As String)

    Dim fnum%, isopen As Boolean
    On Error GoTo erro
    fnum = FreeFile()
    Open FileName For Input As #fnum
    isopen = True
    ReadText = Input(LOF(fnum), fnum)

    erro:
        If isopen Then Close #fnum
        If err Then Debug.Print err.Number, err.Description

    End Function

    12、Print # 语句

    语法:Print #filenumber, [outputlist]

    outputlist 参数的设置如下:
    [{Spc(n) | Tab[(n)]}] [expression] [charpos]

    Spc(n) 用来在输出数据中插入空白字符,而 n 指的是要插入的空白字符数。
    Tab(n) 用来将插入点定位在某一绝对列号上,这里,n 是列号。使用无参数的 Tab 将插入点定位在下一个打印区的起始位置。
    expression 要打印的数值表达式或字符串表达式。
    charpos 指定下一个字符的插入点。使用分号将插入点定位在上一个显示字符之后。用 Tab(n) 将插入点定位在某一绝对的列号上,用无参数的 Tab 将插入点定位在下一个打印区的起始处。如果省略 charpos,则在下一行打印下一个字符。


    功能:将格式化显示的数据写入顺序文件中。

    说明:通常用 Line Input # 或 Input 读出 Print # 在文件中写入的数据。

    示例:
    Open "F:/test.txt" For Output As #1         ' 打开输出文件。
    Print #1, "This is a test"                  ' 将文本数据写入文件。
    Print #1,                                   ' 将空白行写入文件。
    Print #1, "Zone 1"; Tab; "Zone 2"           ' 数据写入两个区(print zones)。
    Print #1, "Hello"; " "; "World"             ' 以空格隔开两个字符串。
    Print #1, Spc(5); "5 leading spaces "       ' 在字符串之前写入五个空格。
    Print #1, Tab(10); "Hello"                  ' 将数据写在第十列。

    ' 赋值 Boolean、Date、Null 及 Error 等。
    Dim MyBool, MyDate, MyNull, MyError
    MyBool = False: MyDate = #2/12/1969#: MyNull = Null
    MyError = CVErr(32767)
    ' True、False、Null 及 Error 会根据系统的地区设置自动转换格式。
    ' 日期将以标准的短式日期的格式显示。
    Print #1, MyBool; " is a Boolean value"
    Print #1, MyDate; " is a date"
    Print #1, MyNull; " is a null value"
    Print #1, MyError; " is an error value"
    Close #1

    以上代码写入的内容如下:
    This is a test

    Zone 1        Zone 2
    Hello World
         5 leading spaces
             Hello
    False is a Boolean value
    1969-2-12  is a date
    Null is a null value
    Error 32767 is an error value

    13、Width # 语句

    语法:Width #filenumber, width
    width 必要。范围在 0–255 之间的数值表达式,在新的一行开始之前,指出在该行上可出现多少字符。如果 width 等于 0,则行的长度不受限制。width 的缺省值为 0。

    功能:将一个输出行的宽度指定给用 Open 语句打开的文件。

    示例:
    Dim I
    Open "f:/TESTFILE.txt" For Output As #1
    Width #1, 5                                 ' 设置输出行宽为 5。
    For I = 0 To 9                              ' 循环 10 次。
        Print #1, Chr(48 + I);                  ' 每行输出五个字符。
    Next I
    Close #1

    以上代码写入的内容如下:
    01234
    56789

     

    (四)处理二进制文件
    打开二进制文件可以使用Open语句的Random和Binary方式打开。二进制文件读写使用Get和Put语句。

    1、Put 语句

    语法:Put [#]filenumber, [recnumber], varname

    recnumber 可选。Variant (Long)。记录号(Random 方式的文件)或字节数(Binary 方式的文件),指明在此处开始写入。

    说明:通常用 Get 将 Put 写入的文件数据读出来。

    示例:
    Dim num As Long, text As String
    num = 12345
    text = "a string"
    Open "f:/data.bin" For Binary As #1     '打开或创建一个二进制文件
    Put #1, , num                           '写入4个字节
    Put #1, , text                          '写入8个字节(字符串长为8)
    Close #1


    2、Get 语句

    语法:Get [#]filenumber, [recnumber], varname

    recnumber 可选。Variant (Long)。记录号(Random 方式的文件)或字节数(Binary 方式的文件),以表示在此处开始读出数据。

    功能:将一个已打开的磁盘文件读入一个变量之中。

    说明:通常用 Put 将 Get 读出的数据写入一个文件。

    示例:读取以上代码写入的内容
    Dim num As Long, text As String
    Open "f:/data.bin" For Binary As #1
    Get #1, , num
    text = Space$(8)                        '准备8个字节的字符串
    Get #1, , text                          '读入
    Debug.Print num, text
    Close #1

    在立即窗口可以看到如下内容:
     12345       a string


    3、Seek 语句

    语法:Seek [#]filenumber, position
    其中position 为介于 1~ 2,147,483,647(相当于 2^31 – 1)之间的数字,指出下一个读写操作将要发生的位置。

    功能:在 Open 语句打开的文件中,设置下一个读/写操作的位置。

    说明:可以用Seek语句指定Get语句的读取位置,但在 Get 及 Put 语句中指定的记录号将覆盖由 Seek 语句指定的文件位置。

    示例:
    Dim MaxSize, NextChar, MyChar
    Open "TESTFILE" For Input As #1     
    MaxSize = LOF(1)       ' 取得文件的总字符数。
    ' 用循环读入所有记录,但是从最后的记录开始往前读。
    For NextChar = MaxSize To 1 Step -1   
        Seek #1, NextChar      ' 设置读写位置。
        MyChar = Input(1, #1)      ' 读入一字符。
    Next NextChar
    Close #1  

    4、Seek 函数

    语法:Seek(filenumber)

    功能:返回一个 Long,在 Open 语句打开的文件中指定当前的读/写位置。

    说明:在使用Get语句读取文件时,必须用LOF函数来判断是否到达文件末尾,而不是用EOF函数。可以使用Seek函数判断当前位置,然后与 LOF的值比较。

    示例:
    Do While Seek(1) < LOF(1)
       '继续读取
       ......
    Loop

     

     

    例子:

    Dim filepath As String
    Dim filenumber As Integer
    Dim contents As String

    Dim comStr As String
    Dim count As Integer
    Dim start As Integer
    Dim i As Integer
    Dim name As String

    filenumber = FreeFile()
    filepath = "c:/scripts/insert.txt"

    count = InputBox("请输入记录的条数")
    start = InputBox("请输入记录开始单元格的行数")
    contents = ""

    comStr = "insert into tml (id,name) values ("
    For i = 1 To count Step 1
        name  = Worksheets(1).Cells(start, 1).Value

        contents = contents &  i  & ",'" & name & "'" & Chr(10)
        start = start + 1
    Next i

    Open filepath For Output As #filenumber
        Print #filenumber, contents
    Close #filenumber

    展开全文
  • VBA 读写文本文件

    万次阅读 2019-05-11 16:34:13
    直接采用Open函数+Line input命令 Private Sub txt_read() Dim txt As String Open "D:\dzh.txt" For ... '对文件做任何 I/O 操作之前都必须先打开文件。Open 语句分配一个缓冲区供文件进行 I/O 之用, ...

    直接采用Open函数+Line input命令

      Private Sub txt_read()
               Dim txt As String
                Open "D:\dzh.txt" For Input As #1 '
                '对文件做任何 I/O 操作之前都必须先打开文件。Open 语句分配一个缓冲区供文件进行 I/O 之用,
                '并决定缓冲区所使用的访问方式。
                '打开文件作为数据输入用,文件号为#1
                Do While Not EOF(1)
                    Line Input #1, txt  '从已打开的顺序文件中读出一行并将它分配给 String 变量
                    'Line Input # 语句一次只从文件中读出一个字符,直到遇到回车符 (Chr(13))
                    '或回车–换行符 (Chr(13) + Chr(10)) 为止。回车–换行符将被跳过,而不会被附加到字符串上
                    MsgBox txt
                Loop
                Close #1
        End Sub
        -----------------------------------------------------------------------------------------------
    1、Open 语句 
    打开方式有 
    Input:以读取方式打开。
    Output:以写入方式打开。
    Append:以追加方式,即添加内容到文件末尾打开。
    Binary:以二进制方式打开。
    Random:以随机方式打开,如果未指定方式,则以 Random 方式打开文件。
     Open pathname For mode As [#]filenumber
     Open "c:\a.txt" For Output As #1
    filenumber  是一个有效的文件号,范围在 1 到 511 之间。
    如果 pathname 指定的文件不存在,那么,在用 Append、Binary、Output、或 Random 方式打开文件时,可以建立这一文件。 
    2、Close 语句 
    语法:Close [filenumberlist]
         filenumberlist 参数为一个或多个文件号,若省略 filenumberlist,则将关闭 Open 语句打开的所有活动文件。 
    说明:打开文件后,必须在使用完后关闭文件。
     
    3、EOF 函数 
    语法:EOF(filenumber) 
    功能:返回一个 Integer,它包含 Boolean 值 True,表明已经到达为 Random 或顺序 Input 打开的文件的结尾。
    Open "c:\a.txt"  For Input As #1 ‘以读入方式打开c:\a.txt
    Do While Not EOF(1)  '未到达结尾
              Line Input #1, s1     '读入一行,放入s1变量中
            Loop
            Close #1 
    
    展开全文
  • VBA 读写文本文件的几种方法

    万次阅读 2013-10-12 12:31:49
    1、直接采用Open函数+Line input命令 Private Sub txt_read() Dim txt As String ... '对文件做任何 I/O 操作之前都必须先打开文件。Open 语句分配一个缓冲区供文件进行 I/O 之用, '并决定缓冲区所使用

    1、直接采用Open函数+Line input命令

    Private Sub txt_read()
           Dim txt As String
            Open "D:\dzh.txt" For Input As #1 '
            '对文件做任何 I/O 操作之前都必须先打开文件。Open 语句分配一个缓冲区供文件进行 I/O 之用,
            '并决定缓冲区所使用的访问方式。
            '打开文件作为数据输入用,文件号为#1
            Do While Not EOF(1)
                Line Input #1, txt  '从已打开的顺序文件中读出一行并将它分配给 String 变量
                'Line Input # 语句一次只从文件中读出一个字符,直到遇到回车符 (Chr(13))
                '或回车–换行符 (Chr(13) + Chr(10)) 为止。回车–换行符将被跳过,而不会被附加到字符串上
                MsgBox txt
            Loop
            Close #1
    End Sub


    2、利用FileSystemObject对象(引用windows script host object model)

    Sub TextStreamTest()
        '**如果引用“windows script host object model”,可以定义如下的数据类型,编程更方便!!!!*******
        Dim fs As FileSystemObject, f As File, ts As TextStream, s As String
        '打开一个只读文件,不能对此文件进行写操作/
        '打开一个用于写操作的文件。如果和此文件同名的文件已存在,则覆盖以前内容/
        '打开一个文件并写到文件的尾部
        Const ForReading = 1, ForWriting = 2, ForAppending = 8
        '使用系统缺省打开文件/以 Unicode 格式打开文件/以 ASCII 格式打开文件
        Const TristateUseDefault = -2, TristateTrue = -1, TristateFalse = 0
        'Dim fs, f, ts, s
        Set fs = CreateObject("Scripting.FileSystemObject")
        'FileSystemObject 对象提供对计算机文件系统的访问
        '下面FileSystemObject.CreateTextFile 返回一个 TextStream 对象,该对象是可读并可写的:
        On Error Resume Next  '如果文件存在,下个命令会出错!获得文件
        fs.CreateTextFile("test1.txt", False).WriteLine ("This is a test.") '创建一个文件,返回一个用于该文件读写的TextStream对象
        Set f = fs.GetFile("test1.txt")          '返回一个和指定路径中文件相对应的 File 对象
        '错误!f.WriteLine ("This is a test.")          '向创建的文本文件中写入一行文本,非TextStream对象,错误!!
        
        Set ts = f.OpenAsTextStream(ForAppending, TristateUseDefault) '打开一个指定的文件并返回一个 TextStream 对象
        'OpenAsTextStream 方法提供了和 FileSystemObject. 的 OpenTextFile 方法相同的功能/
        '此外,OpenAsTextStream 方法还可以用于对一个文件进行写操作。
        ts.Write "Hello World"
        ts.Close
        Set ts = f.OpenAsTextStream(ForReading, TristateUseDefault)
        Do While Not ts.AtEndOfStream
            s = ts.ReadLine
            MsgBox s
        Loop
        ts.Close
    End Sub


    附:自定义类模块——含多个文件处理函数

    定义FileOperation类

    Private objTS As TextStream  ' 定义TextStream对象
    
    Public Function OpenFile(strFileName As String, strMode As String)
        Dim objFSO As FileSystemObject ' 定义文件对象
    
        Set objFSO = New FileSystemObject
        Set objTS = Nothing
    
        If strMode = "R" Then
            ' 读取方式打开文件
            Set objTS = objFSO.OpenTextFile(strFileName, ForReading, True)
        End If
        If strMode = "W" Then
            ' 写入方式打开文件
            Set objTS = objFSO.OpenTextFile(strFileName, ForWriting, True)
        End If
    End Function
    
    Public Function CloseFile()
        ' 关闭文件
        objTS.Close
    End Function
    
    Public Function GetLine() As String
        ' 按行读取文件数据
        GetLine = objTS.ReadLine
    End Function
    
    Public Property Get AtEndOfFile() As Boolean
        ' 判断是否已到文件末尾
        AtEndOfFile = objTS.AtEndOfStream()
    End Property
    
    Public Function WriteLine(strData As String)
        ' 向文件写入一条数据
        objTS.WriteLine (strData)
    End Function
    
    Public Function SkipLines(intLines As Integer)
        Dim i As Integer
        ' 跳到指定数据行,如指定行超过总行数,则指定到末尾行
        ' 一般结合文件末尾判断函数以及读取函数使用
        For i = 1 To intLines
            If objTS.AtEndOfStream Then
                Exit For
            End If
            objTS.SkipLine
        Next i
    End Function

    测试

    Sub Run()
        Dim objTXTFO As FileOperation
        Set objTXTFO = New FileOperation
        objTXTFO.OpenFile "D:\dzh.txt", "R"
        Do While Not (objTXTFO.AtEndOfFile)
            MsgBox objTXTFO.GetLine
        Loop
        objTXTFO.CloseFile
    End Sub


    展开全文
  • VBA读写Excel文件报错Debug一、VBA简介二、VBA读写Excel文件参考文档 一、VBA简介 VBA(Visual Basic for Applications)是Visual Basic的一种宏语言,是在其桌面应用程序中执行通用的自动化(OLE)任务的编程语言。...
  • 自己写的VBA程序,基本覆盖了常用操作,还有进度条,数据库读写,格式定制
  • vba 读写文件,utf-8编码格式2010-07-28 22:33 780人阅读 评论(0) 收藏 举报这是一个转换UTF-8格式文本文件的示例,包括读取和写入,需要用到两个API函数:MultiByteToWideChar和WideCharToMultiByte。Public ...
  • VBA读写ini 配置文件

    千次阅读 2019-03-30 08:31:00
    Option Explicit 'read Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" _ (ByVal lpApplicationName As String, _ ...
  • 文件:Function readTextIntoExcel(path As String)  RowIndex = 11  Open path For Input As #1 '  Do While Not EOF(1) '  Line Input #1, currLine  rowDataArr = Split(currLine, Chr(9))  For i ...
  • VBA读写txt.xlsm

    2019-12-24 02:08:00
    VBA读写txt,在excel中可以实现读取更新修改,在excel中可以实现读取更新修改,在excel中可以实现读取更新修改
  • VBA读写UTF8文本文件

    千次阅读 2020-08-27 19:38:58
    As String With CreateObject("ADODB.Stream") .Type = 2 '读取文本文件 .Mode = 3 '读写 .Open '打开流 .LoadFromFile FileName '装载文本文件 .Charset = "UTF-8" '设定编码 .Position = 2 ReadUTF = .ReadText '...
  • VB.NET读写txt文件源码
  • VBA 读写ini文件

    千次阅读 2012-04-23 11:12:27
    VBA中必须通过调用Win32 API来实现Ini文件读写。 Option Explicit 'read Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" _ (ByVal lpApplicationNam
  • vba txt读写的几种方式

    2019-03-01 17:57:00
    四种方式写txt 1、这种写出来的是ANSI格式的txt  Dim TextExportFile As String TextExportFile = ThisWorkbook.Path &... Set fs = CreateObject("Scripting.FileSystemObject") ... Set ...
  • VBA读写文件

    2016-08-13 16:27:59
    处理文本文件  1、Open 语句 语法:Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength] 其中access、lock、reclength为可选参数,一般不用。 mode 指定打开文件的方式。有5种: ...
  • VBA打开TXT类文件读写相关操作代码

    千次阅读 2019-03-11 23:23:32
    Open 文件名 for 打开方式 as 文件编号 打开方式:Input :只能读,不能写Append:允许读也允许写,如果存在文件就追加记录,如果没有就新建文件Output:可以读,也可以写。但总会把原来的同名文件删除,再新建一个 ...
  • VBA、VBS读写INI文件

    2021-04-21 19:08:03
    最近要编写个vbs小程序,但vbs程序的调试很麻烦,所以考虑用Excel的VBA调试,毕竟vbs和vba还是很相似的。一个要实现的功能就是从ini文件中读取信息,网上找到了一些很好的代码,这里收藏了!功能实现函数如下Private...
  • VBA创建文本文件读写文本文件

    千次阅读 2013-11-07 09:41:17
    Private Sub CommandButton1_Click() Dim gPath As String Dim sFile As Object, Fso As Object gPath = Application.ActiveWorkbook.Path Set Fso = CreateObject("Scripting.FileSystemObjec
  • VB6超大文件读写,使用SetFilePointer定位,分段读写,解决VB6超大文件复制问题
  • VBA读取excel文件

    千次阅读 2020-09-23 21:18:43
    Option Explicit Sub 筛选并合并至新表格() Dim wb As Workbook Dim tongji As Workbook Dim shaixuan As Worksheet Set wb = Workbooks.Open("E:\福州项目\参数核查\输入输出表格\输入报表\基础参数\...
  • 文件读写专题vba

    2019-10-05 13:37:00
    Sub 使用openastextstream读写txt文件() path1 = "e:/vbatest" path2 = "e:/vbatest/1.txt" path3 = "e:/vbatest222" Set fso = CreateObject("scripting.filesystemobject") Set file = fso.getfile(path2) Set ts...
  • VBA读写XML文件

    2019-06-05 14:53:00
    'Write XML file Sub WriteXML(fpa$, fn$) Dim xmlfile As String xmlfile = ThisWorkbook.Path & ".\Export.xml" CreateXml xmlfile, fpa, fn ...Function CreateXml(xmlfile$, fpa...
  • EXCEL VBA 读取文本文件宏EXCEL VBA 读取文本文件宏EXCEL VBA 读取文本文件
  • excel简单vba读写TXT的交互

    万次阅读 2018-07-05 11:04:33
    1.读取excel写TXT(VBA)Sub 导出Erwin参数文件() ' ' 导出Erwin参数文件 宏 ' 'Filename = Application.GetSaveAsFilename(fileFilter:="Text Files (*.txt), *.txt") Filename = "logical_...

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 2,480
精华内容 992
关键字:

vba文件读写