最近在做一个基于MC1496的小板子，需要进行仿真验证功能，然而这个芯片的库文件和代码在网上资源很少，找到了两份可以用的，贴出来供大家分享和参考。

第一份是确保可以使用的，也是我目前在用的，来源记不清楚了，如果作者看到了可以联系我，我对出处进行标记。

* Mixer Subcircuit
* See figure 23 of data sheet with following modification to 
* reflect Metal Can instead of DIP package
* Pin # fig23   subckt
*        9       12
*        8       10
*        7       8
*        10      14
.SUBCKT MC1496_1 1 2 3 4 5 6 8 10 12 14
* Tail current Source
Q1 3  5  19 Q2n3904
Q2 2  5  13 Q2n3904
* Input transistors
Q3 7  4  3  Q2n3904
Q4 9  1  2  Q2n3904
*LO quad switching Transistors
Q5 6  8  7  Q2n3904
Q6 6  10 9  Q2n3904
Q7 12 10 7  Q2n3904
Q8 12 8  9  Q2n3904
* Emitter degeneration resistors
RE1 19 14 500
RE2 13 14 500
*
* Current Mirror
Q9 5  5 15 Q2n3904
Rd  15 14 500 
.ENDS

第二份是在NI的论坛上找到的，这个代码没有映射四个N/Cpin，在仿真软件是无法工作的，有能力的可以自己映射一下，这个代码应该是更全面的，我也在学习如何映射，如果有成果之后会发上来，欢迎有能力的伙伴讨论。

来源：已解决: Looking for MC1496 - any custom part library? - NI Community

源代码地址：www.doe.carleton.ca/~cp/telecom/mixer.txt

* EE455 Lab #2 - Mixer Circuit
*
*------------------Subcircuit description-------------------
* Mixer Subcircuit
* See figure 23 of data sheet with following modification to 
* reflect Metal Can instead of DIP package
* Pin # fig23   subckt
*        9       12
*        8       10
*        7       8
*        10      14
.subckt MC1496 1 2 3 4 5 6 8 10 12 14
* Tail current Source
Q1 3  5  19 Q2n3904
Q2 2  5  13 Q2n3904
* Input transistors
Q3 7  4  3  Q2n3904
Q4 9  1  2  Q2n3904
*LO quad switching Transistors
Q5 6  8  7  Q2n3904
Q6 6  10 9  Q2n3904
Q7 12 10 7  Q2n3904
Q8 12 8  9  Q2n3904
* Emitter degeneration resistors
RE1 19 14 500
RE2 13 14 500
*
* Current Mirror
Q9 5  5 15 Q2n3904
Rd  15 14 500 
.ENDS
*-------------------------Ends Subcircuit-------------------
*
* ---------------------Main Circuit Description-------------
* Power supply
Vcc 9 0 dc 15v
*
* Subcircuit Call
X1 1 2 3 4 5 6 8 10 12 0 MC1496
*
* Biasing Resistors
R1  9  8  1.2k
R2  8  7  820
R3  7  0  1k
R4  9  12 3.3k
R5  9  6  3.3k
R6  9  5  10k 
R7  7  1  100 
R8  7  4  100 
R9  8  10 47
* Carrier Null Resistors - Adjust as required (see below in .param 
* statement)
*R10 1  0  {Ra1}
*R11 4  0  {Ra2}
R10 1  0  15k
R11 4  0  15k
*
* Emitter Degeneration
Re  2  3  1k
*
*Output Load
Rout Out 0 1MEG
*
* AC Coupling Caps
C1 10 In_C 0.1uF
C2 1  In_M 0.1uF
C7 6  Out  0.1uF
*
* Bypass Caps
C3 8  0  4.7uF
C4 8  0  0.1uF
C5 4  0  0.1uF
C6 9  0  0.1uF
*
* Carrier Source
Vc  V_C 0  SIN(0 85mV 1MEGHz)
RsC V_C In_C 50
*
* Modulating Signal
Vm  V_M 0  SIN(0 300mV 60kHz)
RsM V_M In_M 50
*---------------------End Circuit description------------------
*
*----------------------------Models----------------------------
.MODEL Q2N3904 NPN
+ISS=0		XTF=1		NS=1
+CJS=0		VJS=0.5		PTF=0
+MJS=0		EG=1.1		AF=1
+ITF=0.5	VTF=1		BF=280.92203
+BR=20		IS=2.3673E-15	VAF=130.20848
+VAR=11.074004	IKF=0.23419	ISE=3.0707E-16
+NE=1.19409	IKR=7.80101	ISC=3.5223E-12
+NC=1.33867	IRB=1.8864E-4	NF=0.97302
+NR=0.97623	RBM=1E-2	RB=69.94226
+RC=3E-02	RE=0.2569	MJE=0.36064
+MJC=0.29228	VJE=0.81795	VJC=0.45460
+TF=5E-10	TR=6.2636E-09	CJE=6.7441E-12
+CJC=3.4247E-12	FC=0.95		XCJC=0.95425

.MODEL D1N914   D(Is=168.1E-21 N=1 Rs=.1 Ikf=0 Xti=3 Eg=1.11 
+               Cjo=4p M=.3333 Vj=.75 Fc=.5 Isr=100p Nr=2 Bv=100 
+               Ibv=100u Tt=11.54n)
*--------------------------End Models----------------------------

*----------------------------Simulations-------------------------
* Parameter statement to simulate adjustable resistor
*.PARAM Ra1=15k Ra2={30k-Ra1}

* Transient sweep
*.TRAN <print step value> <final time value> [no-print value 
* [step ceiling value]][SKIPBP]
* Note - Need step ceiling value otherwise default step time too large
.TRAN 10n 100u 0 10n

*Parametric sweep for nulling carrier set RF input to zero for this
*This does work with evaluation copy of PSPICE
*.STEP LIN PARAM Ra1  14.5k 15.5K 500
*
* Miscellaneous
.OPTIONS NOMOD 
.PROBE
.OP
.END

如何添加器件可以参考这个链接：在NI Multisim中创建自定义组件 - National Instruments

如果你用Tina或者是Microcap，也可以参考各家的教程，这个是比较简单的。