查找函数
1 VLOOKUP函数							

= VLOOKUP ( 查找值 , 查找的区域 , 返回位置(列) , 查找方式 )							

精确查找																模糊查找			

=VLOOKUP(值,区域,返回列,false)	=VLOOKUP(值,区域,返回列,true)			

=VLOOKUP(值,区域,返回列,0)			=VLOOKUP(值,区域,返回列,1)			

=VLOOKUP(值,区域,返回列,)			=VLOOKUP(值,区域,返回列)			

注意：如果查找方式是为模糊查找，那么区域一定要为升序！否则会出错。	

2												

= HLOOKUP ( 查找的值 ， 查找的区域 ， 返回的行号 ， 查找方式 )	

其余和VIOOKUP函数一样
3	= LOOKUP ( lookup_value , lookup_vector , result_vector )						

第一参数：查找的数值。可以为数字、文本、逻辑值或包含数值的名称或引用。

第二参数：为只包含一行或一列的区域。

第三参数：可以为文本、数字或逻辑 ，只包含一行或一列的区域，其大小必须与 lookup_vector 相同。

注意：Lookup_vector 的数值必须按升序排序；否则，函数 LOOKUP 不能返回正确的结果。文本不区分大小写。
4= CHOOSE ( index_num , value1)														

第一参数：Index_num 必须为 1 到 29 之间的数字、或者是包含数字 1 到 29 的公式或单元格引用	

第二参数：函数 CHOOSE 基于 index_num，从中选择一个数值或执行相应的操作。参数可以为数字、单元格引用、已定义的名称、公式、函数或文本。
5 = MATCH ( lookup_value , lookup_array , match_type)
第一参数：为需要在数据表中查找的数值。可以为数值（数字、文本或逻辑值）或对数字、文本或逻辑值的单元格引用。可能包含所要查找的数值的连续单元格区域。

第二参数：Lookup_array 应为数组或数组引用为数字

第三参数：为 -1、0 或 1。Match-type 指明 Microsoft Excel 如何在 lookup_array 中查找 lookup_value。
6	= INDEX ( array , row_num , column_num )								

第一参数：为单元格区域或数组常量								

第二参数：数组中某行的行序号，函数从该行返回数值。如果省略 row_num，则必须有 column_num。								

第三参数：数组中某列的列序号，函数从该列返回数值。如果省略 column_num，则必须有 row_num。
7	=OFFSET ( reference , rows , cols , height , width)													以指定的引用为参照系，通过给定偏移量得到新的引用。返回的引用可以为一个单元格或单元格区域。并可以指定返回的行数或列数。													

第一参数：偏移量参照系的引用区域；

第二参数：行偏移量。

第三参数：列偏移量；

第四参数：高度，且必须为正数；

第五参数：宽度，也必须为正数。
8返回由文本字符串指定的引用。此函数立即对引用进行计算，并显示其内容。当需要更改公式中单元格的引用，而不更改公式本身，请使用函数 INDIRECT。														

= INDIRECT ( ref_text , a1 )
第一参数：此单元格可以包含 A1-样式的引用、R1C1-样式的引用、定义        为引用的名称或对文本字符串单元格的引用。不是合法的单元格的引用，函数 返回错误值。
第二参数：为一逻辑值，指明包含在单元格 ref_text 中的引用的类型。

一. 查找函数
1. vlookup函数
vlookup(lookup_value,table_array,col_index_num,[range_lookup])

lookup_value表示要查找的对象
table_array表示查找的表格区域
col_index_num表示要查找的数据在table_array区域中处于第几列的列号
range_lookup表示查找类型，其中1表示近似匹配，0表示精确匹配，一般我们用精确匹配的情况较多

A1:B7表示要在其中查找的区间，也就是公式中的table_array

D1到D4中表示我们要查找的对象，也就是公式中的lookup_value

现在我们要查找D1到D4分别对应的数值。



点击公式菜单栏——查找与引用——vlookup

在出现的vlookup界面中第一栏选中D1

第二栏选中A1：D7

第三栏输入2(表示引用的是A1:D7区域的第2列)

第四栏输入0(精确匹配)





与lookup和hlookup的区别：



HLOOKUP函数和VLOOKUP函数的差异是查询的方向不一样。

VLOOKUP函数是按列方向（向右）查找，HLOOKUP函数是按行方向（向下）查找。
2. match和index
MATCH(lookup-value,lookup-array,match-type)    (返回指定内容所在的位置）

lookup-value:表示要在区域或数组中查找的值，可以是直接输入的数组或单元格引用
lookup-array:表示可能包含所要查找的数值的连续单元格区域，应为数组或数组引用
match-type:表示查找方式，用于指定精确查找（查找区域无序排列）或模糊查找（查找区域升序排列）。取值为-1、1、0 。其中0为精确查找



INDEX(array,row-num,column-num)    （返回制定位置中的内容）
array:要返回值的单元格区域或数组
row-num:返回值所在的行号
column-num:返回值所在的列号



用match和index函数实现vlookup功能

选择G7单元格，在单元格中输入：=INDEX(B2:B13,MATCH(F7,A2:A13,0))，用MATCH函数返回F7单元格中的之所对应的行，再利用ATCH函数返回的行号用INDEX函数查询出月份对应的金额。



3. 双条件查找
3.1 vlookup函数。
如下图所示，根据班级和姓名该如何查找成绩呢？先放公式：

此公式为数组函数，输完公式后按下ctrl+shift+enter键计算结果。这个公式咋一看看挺长，不过不要担心，现在就为你详细地解释这个公式到底是什么意思。




3.2 index—match函数
如果实现与上面vlookup函数同样的查找结果运用index—match函数的公式为




二. 作业
1. 用vlookup函数 查找以下公司的 companyId
| companyFullName   | |:----| | 上海云贝网络科技有限公司   | | 携程计算机技术（上海）有限公司   | | 浙江康健绿线网络技术有限公司   | | 久亿财富（北京）投资有限公司   | | 杭州木瓜科技有限公司   | | 思特沃克软件技术（成都）有限公司   | | 北京金山云网络技术有限公司   |


2. 用match和index函数实现第一题的功能

3. 用match和index函数查找以下id对应的公司名称
注意id是横向排列的| companyId     | 127200   | 151079   | 22225   | |----|----|----|----|


4. 根据companyId和postionId两个条件查找对应的工资水平
| companyId   | positionId   | salary  |

| 62   				 | 938038   |

| 1575  			 | 1157620   |

| 157392  		 | 2574696   |



注意：在输入公式后，不是按Enter，而是按Ctrl+Shift+Enter。CTRL+SHIFT+ENTER在Excel中是用于计算数组公式使用的。数组公式运用前是要以数组的形式嵌入公式，要选定数组区间，这样才能执行数组计算，得出的结果才是正确的。（不要自己在两边输入{}，否则Excel认为输入的是一个正文标签。）
请思考，是否会存在相同的公司id和职位di对应多种工资水平，如果有请查找出来。 并思考，如果存在多种的情况，目前的公式还能不能用？



很明显是存在的，目前的公式还能用，但是只返回查找到的第一个值，假如第一行salary是2k-4k，则最终返回结果就是2k-4k。

<Vlookup函数>

用途：返回与查询值同行的返回列值。

用通俗的话就是根据现有条件查找到符合条件的值再黏贴过来。

语法：Vlookup（查询值，查询范围，返回列数，匹配方式)

①第1个参数：查找范围第一列的查找值。选中查找范围里的第一列的值必须是要查找的值。

②第2个参数：查找范围，可以理解为数据表。使用F4按钮灵活转换绝对引用和相对引用，使查找范围全部选中。

③第3个参数：返回值的列号。指定要返回查询区域中第几列的值。

③第4个参数：匹配方式是否为模糊匹配。模糊匹配为1，精确匹配为0，默认为模糊匹配。

 

用SQL来理解就容易很多了：

select ③

from ②

where ②的第一列=①

and 匹配方式=④是否模糊匹配（模糊匹配=1，精确匹配=0，默认是模糊匹配）

 

vlookup函数的实战用法

Vlookup函数用法1：常规查询

【案例1】根据第一张表，查询哪位销售员下了订单编号为“0001”的订单。



公式：=VLOOKUP(E3,$A$3:$C$12,3,0)

解读：这是vlookup函数最常规的一种用法。

Vlookup函数用法2：数据分组

【案例2】根据第二张表的阈值及分组，匹配出与销售额所在范围的分组情况。



公式：=VLOOKUP(B3,$E$2:$G$5,2,1)

解读：vlookup函数的第四个参数为1或省略时，则表示此时的vlookup函数使用模糊匹配。返回的值为小于查询值的最大值。在使用模糊匹配时，查询范围的首列的阈值必须从小到大排序。

Vlookup函数用法3：反向查询

【案例3】根据第一张表，查询出销售员徐四销售出去的商品编号。



公式：=VLOOKUP(E3,IF({1,0},C2:C12,B2:B12),2,0)

解读：if函数使用方式：if({1,0},查找关键字所在列,返回值所在列)

这个if函数使用起来可以把查找关键字所在列和返回值所在列这两列的顺序进行反向调整。

Vlookup函数用法4：模糊匹配

【案例4】根据第一张表，查询出姓“丁”的销售员姓名和销售额。



公式：=VLOOKUP(E3&"*",$B$2:$C$12,COLUMN(A1),0)

解读：返回值所在列使用通配符 * 可以替代任意多个字符；

使用column函数返回指定单元格的列数；

在单元格F9中使用该函数可以返回姓“丁”的销售员的全名，往右拉单元格可以得到该销售员的销售额。

Vlookup函数用法5：多条件查询

【案例5】根据第一张表，查询产品为“0001”，型号为“A001”的产品的产地。



公式：=VLOOKUP(E3&F3,IF({1,0},A3:A12&B3:B12,C3:C12),2,0)

解读：if函数使用方式：if({1,0},查找关键字所在列,返回值所在列)

当我们需要查询匹配多个条件时，需要用连接符号 & 把多个查询条件连接在一起，并且用连接符号 & 把多个查询范围连接在一起。

Vlookup函数用法6：多条件反向查询

【案例6】根据第一张表，查询产品为“0003”型号为“A003”的产品的产地。



公式：=VLOOKUP(E3&F3,IF({1,0},A3:A12&C3:C12,B3:B12),2,0)

解读：if函数使用方式：if({1,0},查找关键字所在列,返回值所在列)

当我们需要查询匹配多个条件时，需要用连接符号 & 把多个查询条件连接在一起，并且用连接符号 & 把多个查询范围连接在一起。

注意：在使用数组的公式后不能只按Enter，这时要使用快捷键Ctrl+Shift+Enter填充。

Vlookup函数用法7：批量查询

【案例7】根据第一张表，查询一系列订单编号的商品编号，销售额，销售员。



公式：=VLOOKUP($F3,$A$3:$D$12,MATCH(G$2,$F$2:$I$2,0),0)

解读：使用match函数可以返回指定值在数组中的位置，在vlookup函数第三个参数的查询列使用match函数，可以返回查询值对应的列数。

在每个参数里合理使用相对引用，绝对引用和混合引用，可以一次性填充进去。

Vlookup函数用法8：交叉查询

【案例8】根据第一张表，查询销售员张五和丁九第三季度的销售额。



公式：=VLOOKUP(G3,A3:$E$12,MATCH(H$2,$A$2:$E$2,0),0)

解读：使用match函数可以返回指定值在数组中的位置，在vlookup函数第三个参数的查询列使用match函数，可以返回查询值对应的列数。

Vlookup函数用法9：一对多查询

【案例9】根据第一张表，查询销售员韩一所有的订单编号。

①一对多查询（纵向排列）

第一种方法：



公式：=(E3=$G$3)+A2



公式：=IFERROR(VLOOKUP(ROW(A1),$A$2:$B$12,2,0),"")

解读：第一步：先添加辅助列。

在单元格A3中输入公式=(E3=$G$3)+A2，可以计算出E列中销售员“韩一”每出现一次就会在相应的A列加1。

第二步：结合使用iferror函数，row函数和vlookup函数匹配得到第一个符合查询条件的数据，然后下拉返回所有符合查询条件的数据。

第二种方法：



公式：=COUNTIF(O$3:O3,O3)



公式：=IFERROR(VLOOKUP($Q$3&ROW(A1),IF({1,0},O3:O12&K3:K12,L3:L12),2,0),"")

解读：第一步：先添加辅助列。

使用countif函数统计了销售员“韩一”在对应区域出现了多少次。

第二步：结合使用iferror函数，row函数和vlookup函数，并使用快捷键Ctrl+Shift+Enter填充得到所有符合条件的值。

注意：在使用数组的公式后不能只按Enter，这时要使用快捷键Ctrl+Shift+Enter填充。

②一对多查询（横向排列）



公式：=(E20=$G$3)+A19



公式：=IFERROR(VLOOKUP(COLUMN(A18),$A$2:$B$12,2,0),"")

解读：第一步：先添加辅助列。

在单元格A20中输入公式=(E20=$G$3)+A19，可以计算出E列中销售员“韩一”每出现一次就会在相应的A列加1。

第二步：结合使用iferror函数，row函数和vlookup函数匹配得到第一个符合查询条件的数据，然后右拉返回所有符合查询条件的数据。

Vlookup函数用法10：合并同类项

【案例10】根据第一张表，把按照组别分类的销售员姓名合并在一行。



重点公式：=B3&IFERROR("、"&VLOOKUP(A3,A4:$C$13,3,0),"")



公式：=VLOOKUP(E3,$A$2:$C$12,3,0)

解读：第一步：先添加辅助列。

公式=B3&IFERROR("、"&VLOOKUP(A3,A4:$C$13,3,0),"")中，由于已经使用&把第一个数据放在单元格最开始，而vlookup函数第四个参数为0时，返回第一个符合条件的数据，所以vlookup函数的查询范围必须是从下一行开始进行匹配。这样，我们就可以依次返回查询值，最终在每一个组别的第一行会返回符合条件的全部数据。

第二步：使用vlookup函数匹配进行常规查询，返回符合条件的从上往下的第一个数据。

Vlookup函数用法11：多工作表查询

【案例11】前三张表是每个组中每个销售员的订单编号，根据前三张表，查询不按照组别分组的部分销售员下的订单编号。



公式：=IFERROR(VLOOKUP(J3,A:B,2,0),IFERROR(VLOOKUP(J3,D:E,2,0),IFERROR(VLOOKUP(J3,G:H,2,0),"暂无订单")))

解读：vlookup函数与iferror函数结合使用，可以查找匹配多张工作表或者多张工作薄。

 

以上为vlookup函数的11种用法。

 

参考链接：https://zhuanlan.zhihu.com/p/148544332

 

 

vlookup函数、hlookup函数 分别按列查找同行数据、按行查找同列数据

vlookup中的v、hlookup中的h分别代表什么单词的意思？

一般凡是这种V和H相对应的都表示垂直（vertical）与水平（horizontal）

VLOOKUP中的V，它指的是Vertical，纵向的意思，如VLOOKUP，指在指定的范围内纵向查找目标内容。

数据可以用第一行列出字段，也可以用第一列列出字段，一般用行列出，而不是用列列出，类似于数据库的表，所以vlookup函数用得比较多。

 

 

 

 

Vlookup可以说是Excel必备函数中最常用的，今天对Excel中的查找函数vlookup进行一次简单的示范

 

1、普通查找

查找人员的身高

=VLOOKUP(H:H,B:E,2,0)





VLOOKUP(value,array,index,0)

VLOOKUP(value:需要匹配的值,array:需要查找的数据区域(首列与value一致),index:要查找的数据在array中的列序列,0:精准匹配)

2、交叉查找

根据多参数查找

=VLOOKUP(H:H,B:E,MATCH(I2,B1:E1,0),0)





MATCH(value,array,0):返回value在array数组中的位置

MATCH(value:需要查找的值,array:需要查找的数组,0:精准匹配)

3、区间查找

根据身高从下面的配置表中查找称谓。

=LOOKUP(A2,$D$2:$E$5)





今天的内容就这样，后续会继续更新excel函数，谢谢大家。

喜欢我可以扫描下面这个萌萌的二维码关注我哦~