精华内容
下载资源
问答
  • Visual BASIC语言程序设计教学课件.rar
  • Visual Basic 6.0

    2015-12-24 18:25:42
    Visual Basic 6.0中文企业版拥有图形用户界面(GUI)和快速应用程序开发(RAD)系统,可以轻易的使用DAO、RDO、ADO连接数据库,或者轻松的创建ActiveX控件。 vb6.0简体中文企业版下载激活: 序列号: e5kr-jg48a-ab3a3...
  • Visual Basic 语言参考-函数速查 〖2002年第1版〗
  • Visual Basic快捷教程——Visual Basic 2017 破冰

    万次阅读 多人点赞 2017-05-20 17:26:06
    Visual BASIC,顾名思义,就是可视化的BASIC。它是美国微软公司推出的一种针对Windows操作系统的应用程序开发工具。作为当今世界上使用最广泛的编程语言之一,它也被公认为是编程效率最高的一种编程方法。无论是开发...

    一、初识Visual BASIC


    Visual BASIC是美国微软公司推出的一种针对Windows操作系统的应用程序开发工具。作为当今世界上使用最广泛的编程语言之一,它也被公认为是编程效率最高的一种编程方法。无论是开发功能强大、性能可靠的商业应用软件,还是编写用于处理具体问题的实用小程序,Visual BASIC都是最快速、最简便的开发工具。


    Visual BASIC顾名思义,就是可视化的BASIC。其中,BASIC指的是BASIC语言,因为

    展开全文
  • 汇编语言中的用PC内部8253控制扬声器发出音乐的代码
  • 查看dxf文件的原代码...........
  • 1.设计电子钟功能,启,停,设置,修改等;2.编制程序,在点阵液晶显示器上显示开始时间并在显示器上显示;3.编制程序,在字符LED上准确显示器上准确显示实时时钟;
  • 第一部分主要阐述和讨论了80X86汇编语言程序设计的基础知识。如;数据格式及其转换,8086CPU中寄存器的结构及使用,存储器的分段,指令和操作数的寻址方式,80X86的指令系统,汇编语言程序格式及伪指令,汇编语言...
  • 用中断程序写,能实现时、分、秒,并且时和分都能加1.
  • 这是微软官方的技术文档,随Visual Studio 2010发行,是学习 Visual Basic 语言的必备资料!
  • 重要的汇编语言代码文件,对数据采集有很大的帮助,与大家同享
  • 芭蕾舞蹈.robonova_II汇编语言为robobaisc
  • Visual Basic 2010入门经典(第6版)》内容简介:visual basic 2010是一种非常流行的编程语言,它的高效和易用经常使之成为编程新手的第一选择,经验丰富的程序员也常常迫切地希望了解visual basic的最新技术。...
  • 这个软件对函数的查找更加方便快捷,软件里的内容全部收集自网络及Visual Basic软件本身的相关内容,对内容作了修改,增加了相应范例代码。
  • Visual Basic快速入门

    万次阅读 多人点赞 2018-01-05 18:26:53
    Basic语言的全名是Beginner’s All-purpose Symbolic Instruction Code(初学者通用的符号指令代码),是几十年前流行过的一门语言。我高中时候一门数学选修课中使用的也是Basic语言。我还记得当时我为了使用Basic...

    Basic语言的全名是Beginner’s All-purpose Symbolic Instruction Code(初学者通用的符号指令代码),是几十年前流行过的一门语言。我高中时候一门数学选修课中使用的也是Basic语言。我还记得当时我为了使用Basic语言,还从网上下了一个简陋的QBasic工具。当时第一次接触编程的我对编程语言充满了兴趣。当然在现在,Basic语言已经基本没什么用了。现在还在使用的Basic语言大概就是微软的Visual Basic了。今天就来介绍一下Visual Basic语言。需要注意的是,VB语言运行在微软的CLR上,所以如果你对C#比较熟悉的话,学习VB就很简单了。

    HelloWorld

    照例,第一个项目自然应该是HelloWorld。打开Visuall Studio,创建一个VB项目,然后就会出现如下图所示的代码。

    HelloWorld

    来解释一下HelloWorld的代码。首先第一行是导入类库,和C#、java的import语句是一个道理。然后下面定义了一个Program模块,其中定义了Main函数,在函数中输出Hello World。在VB中,不使用大括号作为块分隔符,而是使用End语句来结束块作用域。

    Imports System
    
    Module Program
        Sub Main(args As String())
            Console.WriteLine("Hello World!")
        End Sub
    End Module

    基本数据类型

    由于VB和C#都是运行在CLR上的语言,所以其实它们的基本类型是一样的,都有有/无符号的各种长度整数、单精度双精度浮点数、布尔类型、字符和字符串等类型。下面的代码仅列出几个常用的。

    Public Class DataType
        Sub DataType()
            Dim b As Byte
            Dim i As Integer
            Dim s As Single
            Dim d As Double
            Dim c As Char
            Dim str As String
            Dim bool As Boolean
    
            b = 100
            i = 1000
            s = 1.5
            d = 3.1415926
            c = "c"c
            str = "abc"
            bool = True
        End Sub
    End Class

    变量和常量

    VB的变量定义也和C系语言不同,使用的是Dim 变量名 As 变量类型的语法进行定义。变量必须先定义才能使用。如果想同时定义多个变量,可以这么写。

    Dim i, j As Integer

    如果想在定义变量的同时初始化,可以这样。

    Dim bool As Boolean = True

    如果要定义常量,可以变量类似,只不过使用Const关键字。

    Const cs As Integer = 1000

    运算符

    先来看看算术运算符。

    运算符用途例子
    ^幂运算符3 ^ 2 = 9
    +加法
    -减法
    *乘法
    /小数除法3 / 2 = 1.5
    \整除3 \ 2 = 1
    MOD取模6 MOD 4 = 2

    然后是比较运算符。这里需要注意的就是VB的相等和不等和其他语言的可能不太一样。

    运算符用途
    =相等
    <>不等
    <小于
    >大于
    <=不大于
    =
    不小于

    然后是逻辑运算符。

    运算符用途
    And与运算符,不短路求值
    Or或运算符,不短路求值
    Not非运算符
    Xor异或运算符
    AndAlso与运算符,短路求值
    OrElse或运算符,短路求值
    IsTrue是否为真
    IsFalse是否为假

    条件语句

    If语句

    先来看看VB中的If语句,其基本结构是If 条件 Then 执行体 Else 执行体 End If

            Dim num As Integer = 5
            If num\2 = 0 Then
                Console.WriteLine($"{num} is even")
            Else
                Console.WriteLine($"{num} is odd")
            End If

    如果需要多重If语句,可以添加ElseIf语句块。

            If num = 1 Then
                Console.WriteLine($"{num} is 1")
            ElseIf num = 2
                Console.WriteLine($"{num} is 2")
            Else
                Console.WriteLine($"{num} is other")
            End If

    Select语句

    Select语句相当于其他语言中的switch语句,如果没有匹配项,会执行Case Else语句块。

            Dim c As Char = "c"c
            Select c
                Case "a"c
                    Console.WriteLine("a")
                Case "b"c, "c"c
                    Console.WriteLine("b or c")
                Case Else
                    Console.WriteLine("others")
    
            End Select

    循环语句

    Do语句循环

    Do语句循环有两种结构,第一种是循环条件在前。先来看看Do-While语句,当满足循环条件的时候会继续循环,不满足条件时跳出循环。这里顺便提一下,VB中没有块注释,只有单行注释,以单引号开头,直到句末。

            'Do While语句
            Dim i = 0
            Do While i < 5
                If i = 3 Then
                    Exit Do
                End If
                Console.Write(i)
                i += 1
            Loop

    再来看看Do-Until语句,和Do-While相反,在不满足条件的时候会执行循环,满足条件时跳出循环。

            'Do Until语句
            i = 0
            Do Until i > 5
                If i < 3 Then
                    i += 2
                    Continue Do
                End If
                Console.Write(i)
                i += 1
            Loop

    Do循环的第二种形式就是先执行循环体,然后进行判断,同样有While和Until两种。

            i = 0
            Do
                Console.Write(i)
                i += 1
            Loop While i < 5
            Console.WriteLine

    While循环

    还有就是传统的While循环。

            'While循环
            i = 0
            While i < 5
                Console.Write(i)
                i += 1
            End While

    For循环

    下面是For循环的例子,在For循环中可以使用Step指定步长。

            For counter As Integer = 1 To 9 Step 1
                Console.Write(counter)
            Next

    Foreach循环

    Foreach循环用于迭代一个列表中的每一项。

            Dim array() as Integer = {1, 2, 3, 4, 5, 6, 7}
            For Each item As Integer In array
                Console.Write(item)
            Next

    With语句

    With语句其实不算循环语句,不过我看的这个VB教程把With语句放到这里说,那我也放到这里好了。With语句在有些语言中也有,主要用途是节省代码数量。比方说有下面这个Person类。

    Public Class Person
        Public Property Name As String
        Public Property Age As Integer
    End Class

    假如有一个person对象多次出现的话,就可以使用With语句,在With语句中,点访问符默认指向的就是With语句指定的对象。

            Dim person As Person = New Person
            With person
                .Name = "yitian"
                .Age = 25
                Console.WriteLine($"Person(Name:{.Name}, Age:{.Age})")
            End With

    跳转语句

    Exit语句

    Exit语句用于结束某个代码块,它的形式如下。想用Exit退出哪个代码块,就写哪个代码块的类型。

    Exit { Do | For | Function | Property | Select | Sub | Try | While }

    Continue语句

    Continue语句用于结束当前循环,直接进行下一次循环。它的形式如下,后面跟要继续的代码块类型。

    Continue { Do | For | While }

    Goto语句

    最后就是Goto语句,它会直接跳转到指定的标签处。

            'Goto语句
            GoTo Ending
            Console.WriteLine("Print something")
            Ending:
            Console.WriteLine("This is end.")

    数组

    先来看看数组定义。VB中的数组比较特殊,定义一个Dim a1(3),其实是下标0-4长度为四的一维数组,这一点要非常注意。

            '下标0-9的十个元素的数组
            Dim array1(9) As Integer
            '11X11的二维数组
            Dim array2(2, 2) As Integer
            '定义并初始化数组
            Dim array3() = {1, 2, 3, 4, 5}
            '锯齿数组,也就是数组的数组
            Dim array4 As Integer()() = New Integer(1)() {}
            array4(0) = New Integer() {1, 2}
            array4(1) = New Integer() {3, 4}

    访问数组元素需要使用圆括号,而不是一般语言的方括号。

            '初始化一维数组
            For i As Integer = 0 To 9
                array1(i) = i
            Next
    
            '初始化二维数组
            For i = 0 To 2
                For j = 0 To 2
                    array2(i, j) = (i + 1)*(j + 1)
                Next
            Next

    最后就是遍历数组了,可以使用For循环迭代下标,或者用Foreach循环直接遍历元素。

            '显示数组
            For Each e In array1
                Console.Write(e)
            Next
            Console.WriteLine
    
            For i As Integer = 0 To 2
                For j = 0 To 2
                    Console.Write(array2(i, j))
                Next
                Console.WriteLine
            Next
    
            For Each e In array3
                Console.Write(e)
            Next
            Console.WriteLine
            For i As Integer = 0 To 1
                For j = 0 To 1
                    Console.Write(array4(i)(j))
                Next
                Console.WriteLine
            Next

    函数

    Sub函数

    回头来看看前面的HelloWorld,其中就有一个Main函数,它是一个Sub函数,也就是没有返回值的函数。

    Imports System
    
    Module Program
        Sub Main(args As String())
            Console.WriteLine("Hello World!")
        End Sub
    End Module

    函数可以按值传参,也可以按引用传参,默认情况下是按值传参。

        Function GetParam(ByVal a As Integer, ByRef b As Integer)
            a = 10
            b = 10
            Console.WriteLine("Param changed")
        End Function

    Function函数

    Function函数就是有返回值的函数。在函数中,如果要返回值,可以有两种办法,第一种是使用Return语句,第二种是在函数体中向函数名赋值。

        '函数返回值可以用Return语句
        Function Return1() As Integer
            Return 1
        End Function
    
        '也可以向函数名赋值
        Function Return2() As Integer
            Return2 = 2
        End Function

    可变参数列表

    可变参数列表使用ParamArray声明。

        Function PrintIntegers(ParamArray integers As Integer())
            For Each i In integers
                Console.Write(i)
            Next
            Console.WriteLine
        End Function

    面向对象编程

    VB的类和C#的类非常相似,同样有字段、属性等概念。构造函数使用New声明,不需要返回值。析构函数使用Finalize声明,也不需要返回值。

    Class Contact
        ' 字段
        Private _name As String
        Private _tel As String
    
        '构造函数
        Public Sub New(name As String, tel As String)
            _name = name
            _tel = tel
        End Sub
    
        '析构函数
        Protected Overrides Sub Finalize()
        End Sub
    
        '属性
        Public Property Tel As String
            Get
                Return _tel
            End Get
            Set
                _tel = value
            End Set
        End Property
    
        Public Property Name As String
            Get
                Return _name
            End Get
            Set(value As String)
                _name = value
            End Set
        End Property
    
        '重写方法
        Public Overrides Function ToString() As String
            Return $"Contact(Name:{Name}, Tel:{Tel})"
        End Function
    End Class

    抽象类和接口

    如果一个类的方法含有MustOverride修饰符,那么这个方法就是一个抽象方法。含有抽象方法的类就是抽象类,需要使用MustInherit关键字修饰。

    MustInherit Class Shape
        MustOverride Function GetArea() As Double
    End Class
    
    Interface Color
        Function GetColor() As String
    End Interface

    继承

    继承基类和实现接口的声明必须写在类实现的前面。如果一个方法重写了基类的版本,那么这个方法应该使用Overrides关键字修饰。如果不希望类被其他类继承,可以使用NotInheritable修饰,类似于Java的final关键字或者C#的sealed关键字。如果子类需要调用基类的方法,可以使用MyBase关键字代表基类。

    Class Circle
        Inherits Shape
        Protected radius As Double
    
        Public Sub New(r As Double)
            radius = r
        End Sub
    
        Public Overrides Function GetArea() As Double
            Return Math.PI*radius*radius
        End Function
    End Class
    
    NotInheritable Class RedCircle
        Inherits Circle
        Implements Color
    
        Public Sub New(r As Double)
            MyBase.New(r)
        End Sub
    
        Public Function Color_GetColor() As String Implements Color.GetColor
            Return "Red"
        End Function
    End Class

    静态成员

    静态成员和静态函数使用Shared关键字声明,对于每个类来说Shared成员只会存在一个。

    Class MyMath
        Public Shared PI As Double = 3.1415926
    
        Public Shared Function GetPI As Double
            Return PI
        End Function
    End Class

    模块

    Module类似于Class,不同之处在于Module不需要实例化,其中的函数可以直接调用,就像静态函数一样。

    Module Program
        Sub Main(args As String())
            Console.WriteLine("Hello World!")
        End Sub
    End Module

    异常处理

    VB的异常处理和C#的一样,都有Try、Catch、Finally部分。

    Public Module ExceptionHandling
        Sub HandleException()
            Try
                Throw New ArithmeticException("除数不能为零")
            Catch ex As ArithmeticException
                Console.WriteLine($"捕获了数学计算异常:{ex.Message}")
            Catch ex As Exception
                Console.WriteLine($"捕获了异常:{ex.Message}")
            Finally
    
                Console.WriteLine("终结代码")
            End Try
        End Sub
    End Module

    以上就是VB语言的一些介绍了,希望对大家能有所帮助。

    展开全文
  • [第3讲]Visual Basic语言基础ppt,Visual Basic是在BASIC、GW-BASIC、Quick BASIC等语言的基础上发展起来的,它保留了原来BASIC版本中的数据类型和语法,对其中的某些语句和函数的功能作了修改或扩展,并根据语言的...
  • Visual Basic 6.0.rar

    2020-02-10 15:53:33
    Visual Basic(简称VB)是Microsoft公司开发的一种通用的基于对象的程序设计语言,为结构化的、模块化的、面向对象的、包含协助开发环境的事件驱动为机制的可视化程序设计语言。是一种可用于微软自家产品开发的语言...
  • vb6.0 visual basic 6.0

    2019-01-01 20:03:32
    它的基础是编程语言BasicVisual Basic 简单点来说就是微软为了更好的让人们学习编程,应用上 Basic 开发语言的一套工具,简称就是 VB。VB 的面世使原本极其复杂困难的编程、软件开发的工作变得简单。最初的编程...
  • 汇编语言指令集
  • 中英文资料 中英文资料外文翻译文献 译文 Visual Basic 语言与算法 1991 年美国微软公司推出了Visual Basic(可简称VB目前的最新版本是VB 2008 Beta2(VB9)中文版 Visual 意即可视的可见的指的是开发像 windows 操作...
  • Visual Basic 概述

    千次阅读 2021-01-30 16:50:09
     Visual Basic(简称VB)是Microsoft公司开发的一种通用的基于对象的程序设计语言。    “Visual” 指的是开发图形用户界面 (GUI) 的发方法——不需编写大量代码去描述界面元素的外观和位置,而只要把预先建立的...

    1.Visual Basic是什么
      
      Visual Basic(简称VB)是Microsoft公司开发的一种通用的基于对象的程序设计语言。
      
      “Visual” 指的是开发图形用户界面 (GUI) 的发方法——不需编写大量代码去描述界面元素的外观和位置,而只要把预先建立的对象add到屏幕上的一点即可。 发
      
      “Basic”指的是 BASIC (Beginners All-Purpose Symbolic Instruction Code) 语言,一种在计算技术发展历史上应用得最为广泛的语言。Visual Basic 在原有 BASIC 语言的基础上进一步发展,至今包含了数百条语句、函数及关键词,其中很多和 Windows GUI 有直接关系。专业人员可以用 Visual Basic 实现其它任何 Windows 编程语言的功能,而初学者只要掌握几个关键词就可以建立实用的应用程序。Visual Basic Scripting Edition (VBScript) 是广泛使用的脚本语言,它是 Visual Basic 语言的子集,可嵌入HTML语言中,用于网页设计,如ASP(Active Server Page)文件。
      
      VB简单易学,通用性强,用途广泛。

    2.VB的功能
      
      VB可以用于可以开发多媒体、数据库、网络、图形等方面的应用程序。
       
      数据访问特性允许对包括 Microsoft SQL Server 和其它企业数据库在内的大部分数据库格式建立数据库和前端应用程序,以及可调整的服务器端部件。
       
      有了 ActiveX™ 技术就可使用其它应用程序提供的功能,例如 Microsoft Word 字处理器,Microsoft Excel 电子数据表及其它 Windows 应用程序。
       
      Internet 能力强大,很容易在应用程序内通过 Internet 或 intranet访问文档和应用程序,或者创建 Internet 服务器应用程序。
       
      已完成的应用程序是使用Visual Basic 虚拟机真正 .exe 文件,可以自由发布。

    3.VB的发展
      
      VB是伴随Windows操作系统而发展的,在中国使用较广的版本有VB4.0、VB5.0、VB6.0。
        
      VB4.0是为配合WIN95的问世于1995年推出的,既可用于编写WIN3.X平台的16位应用程序也可编写WIN95平台的32位应用程序;VB5.0主要用于编写WIN95平台的32位应用程序,较之VB4.0主要扩展了数据库、ActiveX和Internet方面的功能;VB6.0是与WIN98配合于1998年推出的,进一步加强了数据库、Internet和创建控件方面的功能。

    4.VB中的几个常用术语
      
      工程(Project):是指用于创建一个应用程序的文件的集合。
      对象(object):可控制的某个东西,VB中主要有两类对象:窗体和控件。
      窗体(form):应用程序的用户界面,即windows。
      控件(control):指的是各种按扭、标签、文本框等。
      属性(property):是指对象的特性,如大小、标题或颜色。
      
      ActiveX:ActiveX是基于component object model(com)的可视化控件结构的商标名称.它是一种封装技术,提供封装COM组件并将其置入应用程序(如WEB浏览器)的一种方法.

    Components Object Model (COM): 是软件组件互相通讯的一种方式。它是一种二进制和网络标准,允许任意两个组件互相通讯,而不管它们是在什么计算机上运行(只要计算机是相连的),不管各计算机运行的是什么操作系统(只要该操作系统支持 COM),也不管该组件是用什么语言编写的。

    5.VB的系统特性
      
      (1)工程限制
        
      1)代码限制:         
      可被加载到窗体、类或标准模块的代码总数限于 65,534 行。一行代码限于 1023 个字节。在一行中的实际文本之前最多只能有 256 个空格的前导,在一个逻辑行中最多只能有 25 个续行符 ( _)。
        
      2)过程、类型和变量       
      对每个模块的过程数没有限制。每个过程可包含至多 64K 的代码。如果过程或模块超过这一限制,Visual Basic 便产生编译时间错误。如果遇到这种错误,可将特别大的过程分割成若干个较小的过程,或将模块级声明移到另一模块,来避免此类错误发生。    
      Visual Basic 用表来保存代码中的标识符名(变量、过程、常量等)。每个表限于 64K。
       
      3)动态链接库声明表     
      每个窗体和代码模块使用一个描述动态链接库入口点的结构的表。每个结构约 40 个字节,表的大小限于 64K,形成每个模块大约有 1500 个声明。
       
      4)工程名表     
      整个应用程序用一张包含所有名称的表。这些名称包括: 常量名 、 变量名 、 自定义的类型定义名、 模块名、 DLL 过程声明名。对工程名表总大小没有限制,但是区分大小写的条目不得超过 32K。如果超过了 32K 的限制,可以在不同的模块中重新使用 private 标识符以限制区分大小写的条目数到达 32K。
     
      5)输入表     
      在不同的模块中每引用一个标识符,便在输入表中创建一个条目。每一个这样的入口最小是 24 字节,但限于 64K,这样每个模块大约可以有 2000 个引用。
      
      6)模块条目表   
      该表中每个模块最多达 125 个字节,但有 64K 的总限制,这样每个工程大约可以产生 400 个模块。VB 中的变量名不多于 255 个字符,而窗体、控件、模块和类名不多于 40 个字符。
      
      (2)工程文件格式
      
      VB 在创建和编译工程时要产生许多文件,分为:设计时文件、杂项开发文件和运行时文件。
      设计时文件是工程的建造块,例如基本模块 (.bas) 和窗体模块 (.frm)。
      杂项文件是由 Visual Basic 开发环境中的各种不同的进程和函数产生的,例如打包和展开向导从属文件 (.dep)。

    展开全文
  • Visual Basic编程语言

    2009-10-24 10:29:24
    Visual Basic从1991年诞生以来,现在已经18年了。BASIC是微软的起家产品,微软当然不忘了这位功臣。随着每一次微软技术的浪潮,Visual Basic都会随之获得新生。可以预见,将来无论微软又发明了什么技术或平台,...
  • Visual Basic 语言参考

    2009-09-02 19:00:57
    Visual Basic 语言参考 Visual Basic 语言参考
  • C#和Visual Basic语言功能建议 如果您想建议C#或Visual Basic语言的新功能,请转到此处: 用于C#特定问题 用于VB特定功能 用于影响两种语言的功能 有助于! 做出贡献的一些最佳方法是尝试解决问题,归档错误并...
  • 这是BASICVisual Basic编程的上一页,我们正在处理中,将那里的所有书籍都转换为新页面。 请每天检查此页面!!!
  • 本书提供了使用Visual Basic开发应用程序各个方面的动手介绍。 在使用Visual Basic开发基于Windows的客户端/服务器生产业务应用程序的上下文中涵盖了每个组件。
  • Microsoft Visual Basic 6.0 中文版语言参考手册Microsoft Visual Basic 6.0 中文版语言参考手册Microsoft Visual Basic 6.0 中文版语言参考手册Microsoft Visual Basic 6.0 中文版语言参考手册
  • VisualBasic语言基础.pdf

    2021-09-27 12:30:15
    VisualBasic语言基础.pdf

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 56,998
精华内容 22,799
关键字:

basic语言属于visual

c语言 订阅