精华内容
下载资源
问答
  • Internet拥塞控制系统双重模型中Hopf分叉的混合控制
  • 其次,根据该模型实现手语的动作,利用该方法实现手语动作的关键技术,包括手及手臂旋转变换的变换矩阵、有向拓扑结构描述骨骼模型、表现运动的皮肤模型的拓扑不变性、以及骨骼模型实现运动和皮肤模型表现运动的方法...
  • 我们在两个希格斯双峰模型类的框架中分析了各种变味过程,例如thu,hc,hé,e,Ï以及强子衰变hbs,bd。 在树级别改变了风味的中性标量电流。 这些模型的显着特征是这些违反口味的耦合完全由CKM和PMNS矩阵以及tanβ...
  • DID双重差分模型Day1

    2021-01-20 11:36:12
    1985年普林斯顿大学的Ashenfelter和Card的一篇论文中,第一次引入了DID模型;2001年哈佛大学公共卫生学院学者使用DID模型对中国海南省的医疗报销付费制度改革进行了分析;2001年杜克大学学者对美国保险制度对于妇幼...
  • 双重生成式对抗网络(DGANS)模型对深度学习框架应用于图像隐写时,针对小幅度几何变换攻击进行了优化设计,从而提高模型的稳健性。DGANS由2个串联的生成式对抗网络构成,可将灰度图像隐藏到相同大小的彩色或灰度...
  • 通过建立双重差分模型,研究大秦线、侯月线、神黄线3条亿吨级铁路运煤专线开通对地区经济增长的影响,得出以下结论:我国亿吨级铁路运煤专线的开通改变了煤炭资源的空间配置格局和地区能源禀赋,提高了地区间的交通...
  • 具有双重积分器模型的多智能体系统中的共识问题
  • 按储层特征和渗流特征,将缝洞双重介质模型分为三类,从数学角度简化成两类模型,即裂缝-基岩型和裂缝-孔洞型。前者采用Woren-Root等常规双重介质模型,后者需要建立缝洞系统的窜流公式才能进行数值模拟计算。根据...
  • 双重差分模型了解一下?

    万次阅读 2019-08-31 09:55:43
    总第163篇/张俊红今天给大家介绍一种比较常用分析方法。叫做双重差分法。啥叫个双重差分法呢?我们先不管这个什么法,我们直接来看例子。假如现在市场同学做了一场促销活动,然后...

    总第163篇/张俊红

    今天给大家介绍一种比较常用分析方法。叫做双重差分法。啥叫个双重差分法呢?我们先不管这个什么法,我们直接来看例子。

    假如现在市场同学做了一场促销活动,然后让你评估一下这场活动的效果怎么样,假设你们事先已经明确了活动的目标就是提高销量。那要看活动效果怎么样,其实就是看一下活动前后的销量有没有变化。通过对比活动前后的数据,你发现活动前后销量增加了10%,可是你能说明这10%全是活动带来的吗?很显然不太能。

    为什么不能呢?是因为如果没有活动,不同时间段的销量本来就会发生变化。知道了原因了,现在我们需要去排除原因。那怎么排除呢?我们可以找一部分与活动区域相似的区域(注意,这里要相似的区域),然后给这些区域不上活动,看不上活动的区域,在两个时间段内销量的变化情况。如果你现在通过数据发现,不上活动的区域在两段时间内销量变化了4%。

    通过上活动与不上活动两部分区域在两段时间内的比较,我们就可以得出活动带来的效果是:
    总增量-自然增量=10%-4%=6%。

    我们把前面只对活动前后的数据比较叫做一重差分法。对上活动区域前后效果与不上活动区域前后效果的比较称为双重差分,简称DID(difference in difference)。

    再次强调一下,用双重拆分法有一个很强的假设条件,就是上活动区域与不上活动区域如果在没有活动的情况下,两部分区域的变化趋势应该是一样的。

    有的时候可能因为各种原因的限制,没办法找一部分相似的城市去做对照,这个时候怎么办呢,可以找类似时间段内没有活动时的销量增长幅度来和有活动以后的增长活动做对比。

    这个分析模型的核心,其实就是告诉我们,影响数据变化的因素有很多,我们不能单纯地只看一个总包的效果,要尽可能的去拆分到具体每一种的影响效果是如何的。只有这样才能更加精准的定位到问题。

    你还可以看:

    一种分析框架

    展开全文
  • 双重轮廓演化曲线的图像分割水平集模型在LBF模型的基础上引入了目标内外两条轮廓曲线,很好地克服了LBF模型对于初始轮廓的敏感性,对于灰度不均的单张图像分割效果较好。受此启发,本文提出了基于双重轮廓演化曲线...
  • 双重差分模型DID学习笔记

    万次阅读 多人点赞 2020-06-22 20:17:50
    双重差分模型 (Difference-Differences, DID)是政策评估的非实验方法中最为常用的一种方法,其中交互项是DID的灵魂。 交互项形式拥有各种形式,包括(1)传统DID;(2)经典DID;(3)异时DID;(4)广义DID;以及...

    1.DID介绍

    1.1 特点

    双重差分模型 (Difference-Differences, DID)是政策评估的非实验方法中最为常用的一种方法,其中交互项是DID的灵魂
    交互项形式拥有各种形式,包括(1)传统DID;(2)经典DID;(3)异时DID;(4)广义DID;以及(5)异质性DID。下面分别介绍这几种。

    1.2 传统DID

    双重差分法是研究“处理效应”(treatment effects)的流行方法。一般来说,DID的使用场景为,在面板数据中,个体可分为两类,即受到政策冲击的“处理组”(treatment group)与未受政策影响的“控制组”(control group)。重点落在政策冲击和是否受到政策冲击,通过引入虚拟变量来实现。即:
    政策冲击前后(pre-post)设为0和1,是否受到政策冲击(control-treat)设为0和1.
    在这里插入图片描述
    在这里插入图片描述
    因而,模型常设计为
    在这里插入图片描述
    处理组虚拟变量 beta 捕捉了处理组的组别效应(处理组与控制组的固有差别),处理期虚拟变量lambda控制了处理期的时间效应(处理期前后的固有时间趋势), X为其他控制变量,而交互项xigema 则代表了处理组在处理期的真正效应(受到政策冲击的效应),这正是我们关心的处理效应。然后进行OLS估计即可。

    1.3 经典DID

    经典DID是在传统DID模型上控制了个体固定效应(individual fixed effects)和时间固定效应(time fixed effects),并去除单独变量。模型如下:
    在这里插入图片描述
    模型解释如下:
    (1)u 为个体固定效应。加入个体固定效应之后,就不必再放入处理组虚拟变量(treat i),否则会引起多重共线性问题。因为前者包含比后者更多的信息(前者控制到个体层面,而后者仅控制到组别层面)。
    (2)入 为时间固定效应。同理,加入时间固定效应就不用再加处理期虚拟变量(post t)。否则,将导致严格多重共线性,因为前者包含比后者更多的信息(前者控制了每一期的时间效应,而后者仅控制处理期前后的时间效应)
    (3)注意:估计方法依然是OLS,但须使用“聚类稳健标准误”(cluster-robust standard errors)。

    1.4 异时DID

    在传统与经典DID的模型设定中,一个隐含假设是,处理组的所有个体开始受到政策冲击的时间均完全相同。但有时也会遇到每位个体的处理期不完全一致的情形(heterogeneous timing);比如,某项试点政策在不同城市分批推出。此时,可使用“异时DID”(heterogeneous timing DID)。
    异时DID的关键在于,既然每位个体的处理期不完全一致,则处理期虚拟变量也因个体而异,故应写为post(i,t),既依赖于个体 i,也依赖于时间 t。模型设定为如下任意一种形式:

    在这里插入图片描述
    在这里插入图片描述
    举一个5期面板数据在stata的应用:
    1)定义变量:定义因个体而异的处理期虚拟变量post(i,t);
    2)识别受影响:post1(i,t) = (0,0,1,1,1)代表第1位个体从第3期开始受到政策处理;post2(i,t) = (0,0,0,1,1)代表第2位个体从第4期开始受到政策处理;post3(i,t) = (0,0,0,0,0)代表从未受到政策冲击(属于控制组)。

    1.5 广义DID

    以上各种DID方法均假设存在处理组与控制组的区别,但有时某项政策在全国统一铺开,此时只有处理组,并没有控制组,是否还能使用DID呢?答案是“能”,可以尝试“广义DID”(generalized DID)。
    使用广义DID的重要前提是,虽然所有个体均同时受到政策冲击,但政策对于每位个体的影响力度并不相同,不妨以 intensity(i) 来表示。
    在这里插入图片描述
    在这里插入图片描述
    其中,交互项系数为我们关注的对象。此外对于广义DID,文献中也有门槛区分组别的方法,即人为地设定一个门槛值 c,根据 变量是否超过此门槛值来定义处理组与控制组。因为将连续变量压缩为二分变量损失了不少信息,故在实践中已不多见。
    在这里插入图片描述

    1.6 异质性DID

    传统的处理效应模型一般假设“同质性处理效应”(homogeneous treatment effects),即所有个体的处理效应都相同。显然,此假定太苛刻,在实践中难以成立。更为合理的假定则为“异质性处理效应”(heterogeneous treatment effects),即允许每位个体的处理效应不尽相同。具体而言:
    1)在DID的框架下,引入异质性处理效应,即在于对交互项(treatpost)的调整,即引入在组别上的交互项(treatpost*group)。
    2)模型建立上,在经典DID的模型中,再引入三重交互项 ,构建异质性DID模型。
    在这里插入图片描述
    由上式可知,对于group=0 那类处理组个体,其处理效应为 s。而对于 group=1那类处理组个体,其处理效应为(s+t) 。因而其处理效应是异质的(只要三重交互项的系数显著)。
    3)推广到多雷,只要将将所有个体分为 M 类,设立 (M -1) 个类别虚拟变量。

    2. DID 平行趋势检验

    注意,DID应用的前提是未受到政策冲击时,treat组和control组的变化趋势是平行的,因而进行平行趋势检验是绝对必要的。
    从文献来看,最为常见的展示是否符合平行趋势假设的检验方法有两个:
    其一,对比不同组别因变量均值的时间趋势;其二,回归中加入各时点虚拟变量与政策变量的交互项,若政策或称为处理发生前的交互项系数不显著,则表明的确有着平行趋势。

    • 第一种的方法(图片来源于stata连享会)为:
      在这里插入图片描述
    • 第二种方式分为:代码操作和图形输出

    安装命令:安装 coefplot
    生成各时点虚拟变量与政策变量的交互项的交互项
    进行回归
    输出图形
    例子学习于:多期DID:平行趋势检验图示
    详见学习链接

    3 实践举例

    3.1 所有个体开始受到政策冲击的时间均完全相同

    例子参考学习自:
    连享会-倍分法DID详解 (一):传统 DID

    /* 模拟数据的生成 */
    ///设定60个观测值,设定随机数种子
    clear all
    set obs 60
    set seed 10101
    gen id = _n
    // 每一个数值的数量扩大11倍,再减去前六十个观测值,即60*11-60 = 600,为60个体10年的面板数据
    expand 11
    drop in 1/60
    count
    ///id分组生成时间标识
    bysort id : gen time = _n + 1999
    xtset id time
    ///生成协变量x1, x2
    gen x1 = rnormal(1,7)
    gen x2 = rnormal(2,5)
    ///生成个体固定效应和时间固定效应
    sort time id
    by time : gen ind = _n
    sort id time
    by id : gen T = _n
    ///生成treat和post变量,以2005年为接受政策干预的时点,id30-60的个体为处理组,其余为控制组
    gen D = 0
    replace D = 1 if id > 29
    gen post = 0
    replace post = 1 if time >= 2005
    ///将基础数据结构保存成dta文件,命名为DID_Basic_Simu.dta,默认保存在当前的 working directory 路径下
    save "DID_Basic_Simu.dta",replace
    

    3.1.1 政策效果不随时间而变DID

    ///调用本文第二部分生成的基础数据结构
    use "DID_Basic_Simu.dta",clear
    ///生成两种潜在结果,并且合成最终的结果变量,令政策的真实效果为10
    bysort id : gen y0 = 10 + 5*x1 + 3*x2 + T +ind + rnormal()
    bysort id : gen y1 = 10 + 5*x1 + 3*x2 + T +ind + rnormal() if time < 2005
    bysort id : replace y1 = 10 + 5*x1 + 3*x2 + 10 + T +ind + rnormal() if time >= 2005
    gen y = y0 + D*(y1-y0)
    ///去除协变量和个体效应对y的影响,画出剩余残差的图像
    xtreg y x1 x2,fe r
    predict e, ue
    binscatter e time, line(connect) by(D)
    ///输出生成的图片,令格式为800*600
    graph export "article1_1.png",as(png) replace width(800) height(600)
    ///多种回归形式
    reg y c.D#c.post x1 x2 i.time i.id,robust
    eststo reg
    xtreg y c.D#c.post x1 x2 i.time,absorb(id) robust
    eststo areg
    reghdfe y y c.D#c.post x1 x2, absorb(id time) vce(robust)
    estout *, title("The Comparison of Actual Paramerer Values") ///
    		 cells(b(star fmt(%9.3f)) se(par)) ///
    		 stats(N N_g, fmt(%9.0f %9.0g) label(N Groups)) ///
    		 legend collabels(none) varlabels(_cons Constant) keep(x1 x2 c.D#c.post)
    ///ESA及图示法
    ///预先生成年度虚拟变量
    tab time,gen(year)
    reg y i.D#i.time x1 x2, vce(robust)
    reghdfe y c.D#(c.year2-year10) x1 x2, absorb(id time) vce(robust)
    coefplot, ///
       keep(c.D#c.year2 c.D#c.year3 c.D#c.year4 c.D#c.year5 c.D#c.year6 c.D#c.year7 c.D#c.year8 c.D#c.year9 c.D#c.year10)  ///
       coeflabels(c.D#c.year2 = "-4"   ///
       c.D#c.year3 = "-3"           ///
       c.D#c.year4 = "-2"           ///
       c.D#c.year5 = "-1"           ///
       c.D#c.year6  = "0"             ///
       c.D#c.year7  = "1"              ///
       c.D#c.year8  = "2"              ///
       c.D#c.year9  = "3"              ///
       c.D#c.year10 = "4")            ///
       vertical                             ///
       yline(0)                             ///
       ytitle("Coef")                 ///
       xtitle("Time passage relative to year of adoption of implied contract exception") ///
       addplot(line @b @at)                 ///
       ciopts(recast(rcap))                 ///
       scheme(s1mono)
    ///输出生成的图片,令格式为800*600
    graph export "article1_3.png", as(png) replace width(800) height(600)
    

    3.1.2 政策效果随时间而变DID

    ///调用本文第二部分生成的基础数据结构
    use "DID_Basic_Simu.dta",clear
    ///生成两种潜在结果,并且合成最终的结果变量,令政策的真实效果随时间发生变化,即(5*T-T),由于从2005年开始接受干预,因此,每年的政策效果应为2428323640.
    bysort id: gen y0 = 10  + 5 * x1 + 3 * x2 + T + ind  + rnormal()
    bysort id: gen y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + rnormal() if time < 2005
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 + 10 + T + ind  + rnormal() if time >= 2005
    gen y = y0 + D * (y1 - y0)
    ///去除协变量和个体效应对y的影响,画出剩余残差的图像
    xtreg y x1 x2 , fe r
    predict e,ue
    binscatter e time, line(connect) by(D)
    ///输出生成的图片,令格式为800*600
    graph export "article1_1.png",as(png) replace width(800) height(600)
    ///多种回归形式
    reg y c.D#c.post x1 x2 i.time i.id,	r
    eststo reg
    xtreg y c.D#c.post x1 x2 i.time, r fe
    eststo xtreg_fe
    areg y c.D#c.post x1 x2 i.time, absorb(id) robust
    eststo areg
    reghdfe y c.D#c.post x1 x2, absorb(id time) vce(robust)
    eststo reghdfe
    estout *, title("The Comparison of Actual Paramerer Values") ///
    		 cells(b(star fmt(%9.3f)) se(par)) ///
    		 stats(N N_g, fmt(%9.0f %9.0g) label(N Groups)) ///
    		 legend collabels(none) varlabels(_cons Constant) keep(x1 x2 c.D#c.post)
    ///ESA及图示法
    ///预先生成年度虚拟变量
    tab time, gen(year)
    reghdfe y i.D#i.time x1 x2, vce(robust) absorb(id time)
    reghdfe y c.D#(c.year2-year10) x1 x2, absorb(id time) vce(robust)
    coefplot, ///
       keep(c.D#c.year2 c.D#c.year3 c.D#c.year4 c.D#c.year5 c.D#c.year6 c.D#c.year7 c.D#c.year8 c.D#c.year9 c.D#c.year10)  ///
       coeflabels(c.D#c.year2 = "-4"   ///
       c.D#c.year3 = "-3"           ///
       c.D#c.year4 = "-2"           ///
       c.D#c.year5 = "-1"           ///
       c.D#c.year6  = "0"             ///
       c.D#c.year7  = "1"              ///
       c.D#c.year8  = "2"              ///
       c.D#c.year9  = "3"              ///
       c.D#c.year10 = "4")            ///
       vertical                             ///
       yline(0)                             ///
       ytitle("Coef")                 ///
       xtitle("Time passage relative to year of adoption of implied contract exception") ///
       addplot(line @b @at)                 ///
       ciopts(recast(rcap))                 ///
       scheme(s1mono)
     ///输出生成的图片,令格式为800*600
     graph export "article1_4.png",as(png) replace width(800) height(600)		 
    
    

    3.2 个体受到政策冲击的时间不相同

    倍分法DID详解 (二):多时点 DID (渐进DID)
    所有个体开始受到政策冲击的时间均完全相同:Standard DID
    在这里插入图片描述
    个体开始受到政策冲击的时间不相同:Time-varying DID
    在这里插入图片描述

     /* 模拟数据的生成 */
     ///设定60个观测值,设定随机数种子
    clear all
    set obs 60 
    set seed 10101
    gen id =_n
    /// 每一个数值的数量扩大11倍,再减去前六十个观测值,即60*11-60 = 600,为60个体10年的面板数据
    expand 11
    drop in 1/60
    count
    ///id分组生成时间标识
    bysort id: gen time = _n+1999
    xtset id time
    ///生成协变量以及个体和时间效应
    gen x1 = rnormal(1,7)
    gen x2 = rnormal(2,5)
    sort time id
    by time: gen ind = _n
    sort id time
    by id: gen T = _n
    gen y = 0
    ///生成处理变量,此时D为Dit,设定1-202004年接受冲击,21-402006年,36-602008年
    gen D = 0
    gen birth_date = 0
    forvalues i = 1/20{
    	replace D = 1 if id  == `i' & time >= 2004
    	replace birth_date = 2004 if id == `i'
    }
    forvalues i = 21/40{
    	replace D = 1 if id  == `i' & time >= 2006
    	replace birth_date = 2006 if id == `i'
    }
    forvalues i = 41/60{
    	replace D = 1 if id  == `i' & time >= 2008
    	replace birth_date = 2008 if id == `i'
    }
    ///将基础数据结构保存成dta文件,命名为DID_Basic_Simu.dta,默认保存在当前的 working directory 路径下
    save "DID_Basic_Simu_1.dta", replace
    

    3.2.1 政策效果不随时间而变DID

    /* 政策效果不随时间而变DID */
    ///调用生成的基础数据文件
    use "DID_Basic_Simu_1.dta",clear
    ///Y的生成,使得接受冲击的个体的政策真实效果为10
    bysort id: gen y0 = 10  + 5 * x1 + 3 * x2 + T + ind  + rnormal()
    bysort id: gen y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + 10 + rnormal() if time >= 2004 & id >= 1 & id <= 20
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + 10 + rnormal() if time >= 2006 & id >= 21 & id <= 40
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + 10 + rnormal() if time >= 2008 & id >= 41 & id <= 60
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + rnormal() if y1 == .
    replace y = y0 + D * (y1 - y0)
    ///去除个体效应和协变量对Y的影响,得到残差并画图
    xtreg y x1 x2 , fe r
    predict e, ue
    binscatter e time, line(connect) by(D)
    ///输出生成的图片,令格式为800*600
    graph export "article2_1.png",as(png) replace width(800) height(600)
    ///保存并输出多个命令的结果
    reg y c.D x1 x2 i.time i.id, r
    eststo reg
    xtreg y c.D x1 x2 i.time, r fe
    eststo xtreg_fe
    areg y c.D x1 x2 i.time, absorb(id) robust
    eststo areg
    reghdfe y c.D x1 x2, absorb(id time) vce(robust)
    eststo reghdfe
    estout *, title("The Comparison of Actual Parameter Values") ///
    		 cells(b(star fmt(%9.3f)) se(par)) ///
    		 stats(N N_g, fmt(%9.0f %9.0g) label(N Groups)) ///
    		 legend collabels(none) varlabels(_cons Constant) keep(x1 x2 D)
    ///ESA及图示法   Time-varying DID 和 Event Study Approach 的结合
    ///用当前年份减去个体接受处理的年份,得到相对的时间值event,将 -4 期之前的时间归并到第 -4 期,由于部分个体没有多于 -4 期的时间
    ///然后生成相对时间值的虚拟变量,eventt,并将首期设定为基准对照组
    gen event = time - birth_date
    replace event = -4 if event <= -4
    tab event, gen(eventt)
    drop eventt1
    xtreg y eventt* x1 x2 i.time, r fe
    coefplot, ///
       keep(eventt*)  ///
       coeflabels(eventt2 = "-3"   ///
       eventt3 = "-2"             ///
       eventt4 = "-1"             ///
       eventt5 = "0"              ///
       eventt6  = "1"             ///
       eventt7  = "2"             ///
       eventt8  = "3"             ///
       eventt9  = "4"             ///
       eventt10 = "5")           ///
       vertical                       ///
       yline(0)                       ///
       ytitle("Coef")               ///
       xtitle("Time passage relative to year of adoption of implied contract exception") ///
       addplot(line @b @at)                 ///
       ciopts(recast(rcap))                 ///
       scheme(s1mono)
    ///输出生成的图片,令格式为800*600
    graph export "article2_2.png",as(png) replace width(800) height(600)
    

    3.2.2 政策效果随时间而变DID

    /*政策效果随时间而变DID*/
    ///调用生成的基础数据文件
    use "DID_Basic_Simu_1.dta",clear
    ///Y的生成,设定真实的政策效果为当年为3,并且每年增加3
    bysort id: gen y0 = 10  + 5 * x1 + 3 * x2 + T + ind + rnormal()
    bysort id: gen y1 = 10  + 5 * x1 + 3 * x2 + T + ind  + (time - birth + 1 ) * 3 + rnormal() if time >= 2004 & id >= 1 & id <= 20
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 +  T + ind  + (time - birth + 1 ) * 3  + rnormal() if time >= 2006 & id >= 21 & id <= 40
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 +  T + ind  + (time - birth + 1 ) * 3  + rnormal() if time >= 2008 & id >= 41 & id <= 60
    bysort id: replace y1 = 10  + 5 * x1 + 3 * x2 +  T + ind  + rnormal() if y1 == .
    replace y = y0 + D * (y1 - y0)
    ///去除个体效应和协变量对Y的影响,得到残差并画图
    xtreg y x1 x2 , fe r
    predict e, ue
    binscatter e time, line(connect) by(D)
    ///输出生成的图片,令格式为800*600
    graph export "article2_3.png",as(png) replace width(800) height(600)
    ///保存并输出多个命令的结果
    reg y c.D x1 x2 i.time i.id, r
    eststo reg
    xtreg y c.D x1 x2 i.time, r fe
    eststo xtreg_fe
    areg y c.D x1 x2 i.time, absorb(id) robust
    eststo areg
    reghdfe y c.D x1 x2, absorb(id time) vce(robust)
    eststo reghdfe
    estout *, title("The Comparison of Actual Parameter Values") ///
    		 cells(b(star fmt(%9.3f)) se(par)) ///
    		 stats(N N_g, fmt(%9.0f %9.0g) label(N Groups)) ///
    		 legend collabels(none) varlabels(_cons Constant) keep(x1 x2 D)
    ///ESA及图示法   Time-varying DID 和 Event Study Approach 的结合
    ///用当前年份减去个体接受处理的年份,得到相对的时间值event,将 -4 期之前的时间归并到第 -4 期,由于部分个体没有多于 -4 期的时间
    ///然后生成相对时间值的虚拟变量,eventt,并将首期设定为基准对照组
    gen event = time - birth_date
    replace event = -4 if event <= -4
    tab event, gen(eventt)
    drop eventt1
    xtreg y eventt* x1 x2 i.time, r fe
    coefplot, ///
       keep(eventt*)  ///
       coeflabels(eventt2 = "-3"   ///
       eventt3 = "-2"           ///
       eventt4 = "-1"           ///
       eventt5 = "0"           ///
       eventt6  = "1"             ///
       eventt7  = "2"              ///
       eventt8  = "3"              ///
       eventt9  = "4"              ///
       eventt10 = "5")            ///
       vertical                             ///
       yline(0)                             ///
       ytitle("Coef")                 ///
       xtitle("Time passage relative to year of adoption of implied contract exception") ///
       addplot(line @b @at)                 ///
       ciopts(recast(rcap))                 ///
       scheme(s1mono)
    ///输出生成的图片,令格式为800*600
    graph export "article2_2.png",as(png) replace width(800) height(600)
    

    本文学习总结的文章分别如下:
    开学礼包:如何使用双重差分法的交叉项(迄今最全攻略)
    多期DID:平行趋势检验图示
    连享会-倍分法DID详解 (一):传统 DID
    倍分法DID详解 (二):多时点 DID (渐进DID)

    展开全文
  • 在带有对称性的两希格斯和三希格斯双重模型的所有示例中,人们都观察到以下有趣的特性:如果G至少在中性希格斯部分阻止显式CP违反(CPV),那么它也可以防止自发CPV, 如果G允许显式CPV,则它允许自发CPV。...
  • 在分析了一类配送中心选址问题的基础上,建立了该配送中心选址问题的数学模型。提出一种具有双重信息的遗传算法编码方案,并结合相应的遗传操作进行求寻优求解,最后通过实验证明了该方法的可行性和有效性。
  • DID-双重差分模型

    千次阅读 2020-04-12 20:19:38
    DID-双重差分模型 DID(difference-in-differences model)也叫双重差分模型。 现在要修一条铁路,铁路是条线,所以必然会有穿过的城市和没有被穿过的城市。记Di=1 如果城市i被穿过,Di=0 如果城市i没有被穿过。 ...

    DID-双重差分模型

    DID(difference-in-differences model)也叫双重差分模型。

    现在要修一条铁路,铁路是条线,所以必然会有穿过的城市和没有被穿过的城市。记Di=1 如果城市i被穿过,Di=0 如果城市i没有被穿过。
    现在我们比较好奇铁路修好以后,被铁路穿过的城市是不是经济增长更快了?我们该怎么做呢?

    一开始的想法是,我们把Di=1的城市的GDP加总,减去Di=0的城市的GDP加总,然后两者一减,即E(Yi|Di=1)-E(Yi|Di=0),这样我们就算出了两类城市的GDP的平均之差。

    这样做不用说肯定有问题。万一被铁路穿过的城市在建铁路之前GDP就高呢?为了解决这个问题,我们需要观察到至少两期,第一期是建铁路之前,第二期是建铁路之后。我们先把两类城市的GDP做两期之差,即:

    公式1

    这是第一次差分,经过这一步,我们实际上算出了每个城市GDP的增长(率,如果取log之后),也就是GDP的趋势。完了之后,计算:

    公式2
    这是第二次差分。这一步就把两类城市在修建铁路之前和之后的GDP增长率的差异给算出来了,这就是我们要的处理效应,即修建铁路之后对城市经济的促进作用。这个东西你还可以换一个写法。记T=1 如果时间为建铁路之后,T=0如果时间为建铁路之前,那么我们可以得到一个表:

    表格1
    Treated代表在某一期,某一类城市是不是建了铁路。第零期肯定没有建铁路,第一期只有Di=1的城市建了铁路。所以Treated=Di*T。因此我们把方程写成:
    公式3
    对时间差分,得到:

    公式4
    再次差分,取期望:

    公式5
    可见,gamma就是我们想要估计的处理效应。所以实际做的时候,可以直接跑。
    公式6
    这个式子的回归,得到的交叉项的系数就是所要估计的处理效应。

    用一个图表示就是:
    图片1
    所以看清楚了,这里DID最关键的假设是common trend,也就是两个组别在不处理的情况下,y的趋势是一样的。那么你会说了,铁路穿过的城市可能本身GDP也高,而GDP高的城市按照理论GDP增长率可能更高可能更低,所以common trend的假设可能是不对的,那怎么办?如果这个问题存在,我们可以进一步假设在控制了某些外生变量之后,common trend是对的,比如上个问题,我们可以控制城市在t=0期的GDP level。当我们控制其他变量之后,自然不能直接减两次了,我们需要用上面说的回归式子,即run the following OLS:

    公式7

    参考资料:
    https://www.zhihu.com/question/24322044/answer/27534813

    展开全文
  • 双重增强自校正(DESC)模型是锂离子电池的等效电路模型,也可用于其他类型的电池。 可以在这里访问DESC的相关文章 DESC是Gregor Plett的增强自校正(ESC)模型的增强派生。 因此,可以将ESC模型和DESC模型文章的...
  • 分形复合双重介质油藏不稳定渗流理论模型研究,郭晶晶,张烈辉,以Warren-Root模型为基础,针对裂缝系统和基质岩块分别引入了描述分形特征的分形维数和分形指数,建立了考虑井储和表皮效应的分形复�
  • 084-基于双重Logit模型的地铁站台车门选择模型.pdf
  • 论文研究-基于双重成本控制标准作用的委托-代理模型.pdf, 按照泰勒控制标准理论设立的成本控制标准具有单层次特征, 不利于提高企业成本控制效度. 人的理性、情感和认知...
  • Sommer(2015),《双重扩散的最小模型及其在基伍,尼奥斯和鲍威尔湖的应用》,J。Geophys。 Res。 海洋,120,doi:10.1002 / 2015JC010970 -说明-该代码是用Matlab编写的。 文件“ main.m”是脚本,该脚本调用其他...
  • 我们探索了费米离子暗物质模型,并可能将粒子物理学的标准模型扩展为两个希格斯双峰模型。 希格斯二重态通过不可重归一化的耦合与单重态铁离子暗物质耦合,从而提供了新的物理尺度。 我们探索了这种暗物质候选物的...
  • 树级别的变味中性电流(FCNC)问题是标准模型(SM)的两个希格斯二重态扩展的一个非常关键的缺陷。 在本文中,将演示其中根本不存在此类缺陷的两希格斯双峰模型(2HDM)。 提出了可以通过相同的transformation变换...
  • 为了从多粒度、多层次的角度有效处理名义型属性和数值型属性并存的混合数据, 首先基于不同的属性集序列和不同的邻域半径构建双重粒化准则, 建立基于双重粒化准则的邻域多粒度粗糙集模型; 然后给出该模型的相关性质, ...
  • 针对移动机器人基于超声波传感器的地图创建,提出了一种双重环境模型。该模型同时包涵以直线段表示的几何模型和以概率形式表示的栅格模型,结合了几何模型与栅格模型的优点。给出了该模型的建立及更新算法,并基于该...
  • 基于2008-2018年相关数据,利用双重差分(DID)模型,考察去产能政策对我国产业结构产生的影响。结果表明,煤炭去产能政策对我国产业结构调整产生较为明显的正向促进效应。一方面, 煤炭去产能政策通过提高煤炭企业...
  • 为了在可视语音合成中获得更具有真实感的口型动画,提出了一种基于双重学习模型的合成方法。通过隐马尔可夫模型和遗传算法相结合的方法,可以更好地学习出语音特征与可视特征间的映射关系。该模型能去除传统语音识别...
  • 通过双重分区模型进行的免费骑行情节放映
  • 一种改进的双重过滤模型算法一种改进的一种改进的双重过滤模型算法双重过滤模型算法
  • 因此,可靠且经过验证的数学模型对于在制造之前优化各种设计参数至关重要。 本研究的目的是根据其预测精度,局限性和计算要求来评估广泛采用的空气动力学模型。 对双多流管模型进行了详细讨论,并通过三叶片H-...
  • #资源达人分享计划#

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 34,903
精华内容 13,961
关键字:

双重模型