VB中对象随窗体而改变大小的方法总结
L0ftFC
      前些时在做VB的编程研究时，发现一个问题：针对某一窗体（FORM），若它在运行过程中人为改变其大小（即Resize），如何让该窗体内的对象也随之改变呢？于是对此鄙人做了一下的一个方法小总结，仅供参考，如有遗漏，请见谅，如有高见，请不吝惜赐教。
      问题的核心是要等比缩放对象，所以关键应该在如何改变对象的大小上。而针对不同的对象，也有当然有其不同的方法，在此我暂将对象分为两类：1.固有对象；2.构造对象。
      1.固有对象：
      即VB本身提供的对象接口，它们是实体对象，且君有其固定的属性值，并且属性值只可修改而不能创造的这一类对象。例如：CommandButton , Textbox , Label，PictureBox 等。
      针对固有对象的特性，很自然想到用类来进行对象放缩，一下是我的一个操作方案：
      A.定义类（即比例尺）：
                  '定义一个类用于保存每个控件的放大比例
Type MyControl
                        mcTop       As Single
                        mcLeft       As Single
                        mcHeight    As Single
                        mcWidth     As Single
End Type
      定义这样一个类的目的，就是在窗体加载时记录下窗体内的对象和窗体初始时的比例尺。
B.初始化类（获取比例尺）：
'用于在form_load时初始化控件与窗体的初始比例，用于以后原始比例放大
Private Function InitMycont(Obj As Control, mcControl As MyControl)
             mcControl.mcLeft = Obj.Left / Form1.ScaleWidth
             mcControl.mcTop = Obj.Top / Form1.ScaleHeight
             mcControl.mcWidth = Obj.Width / Form1.ScaleWidth
             mcControl.mcHeight = Obj.Height / Form1.ScaleHeight
End Function
这样针对该类，我现在便有了一个初始化操作了。
      C.按类的记录改变对象的属性（按比例尺缩放）：
'用于在form_resize时对控件进行比例放大
Private Function ChangeMycont(Obj As Control, mcControl As MyControl)
            Obj.Left = mcControl.mcLeft * Form1.ScaleWidth
            Obj.Top = mcControl.mcTop * Form1.ScaleHeight
            Obj.Width = mcControl.mcWidth * Form1.ScaleWidth
            Obj.Height = mcControl.mcHeight * Form1.ScaleHeight
End Function
      经过以上三步后，我便有了一个完整的面向缩放对象的编程方式（包含类及其基本操作）了，但我们该如何使用这个类呢？没错，初始化一定是在窗体加载（Form_Load）时使用，而改变大小操作就放在窗体改变(Form_Resize)时操作啦!代码如下：
'调用InitMycont()函数初始化放大比例
Private Sub Form_Load()
                   a = InitMycont(Command1, mcControl(1))
                   b = InitMycont(Text1, mcControl(2))
End Sub
       
              '调用changMycont()函数进行按比例的放大
Private Sub Form_Resize()
                   a = ChangeMycont(Command1, mcControl(1))
                   b = ChangeMycont(Text1, mcControl(2))
End Sub
       以上便实现了固有对象的大小变化。
      2.构造对象
      即针对于VB中的图形编程而言的，特别是那些直接在窗体上所做的图形（因为倘若在PictureBox中做图，仍然属于固有对象的范畴）。对于固有对象，当窗体缩小以至于比固有对象还小时，固有对象仅仅是被遮盖了，当窗体放大后，对象仍然完整。但是对于图形等构造对象而言，即使窗体再放大，原来的图形一旦被遮盖，就无法像固有对象一样依旧完整了。
      当然，凡事有弊必有利。既然图形本身是可重构的，为何不在窗体改变时重新构造原有的图形呢？
      VB在做图形编程时，有两种方法：1.绝对坐标；2.自定义坐标。然而VB中的自定义坐标本身就是一个相对值集合，即无论窗体怎么变化，坐标的值是相对值，值是不变，那么我们在这样一个坐标下所做的图形本身就具有随窗体大小改变的能力。于是，我自创了如下方法：
      A.根据需求建立自定义坐标：
           e.g:        Scale (-1, 1)-(1, -1)             ‘建立了一个自定义坐标
   注：VB默认的x轴正方向是向右没问题，但是y轴正方向是向下的，所以想定义一个标准笛卡尔坐标系（即直角坐标系，y轴正方向向上），起始点与终止点的y坐标正好反过来了。
      B.利用图形工具（PSet,Circle,Line）作“持久图形”
           e.g:       AutoRedraw = True
                             Circle (x, y)               ‘画一个可持久的圆
      注：这里“可持久”并非真的持久不变，只是将图形的AutoRedraw打开了。这样该图形在每一次被加载时都会重画一次，再加上自定义坐标的相对性，于是每改变一次，图形都会根据当前坐标再做一次图，图形就能够缩放了。不过这里的AutoRedraw 属性只针对一个图形，假若有两个图形同时产生，想要它们均可重画，必须对每个图形定义前加上“AutoRedraw = True”
                 e.g:               AutoRedraw = True
    Circle (50, 50), 30                '一个实心圆（持久图形）
                                              AutoRedraw = False
                                              Circle (70, 70), 10                '一个实心圆（临时图形）
 

DataGridView在vb.net中的操作技巧  

目录： 




1、　取得或者修改当前单元格的内容 

2、 设定单元格只读 

3、　不显示最下面的新行 

4、　判断新增行 

5、　行的用户删除操作的自定义 

6、　行、列的隐藏和删除 

7、　禁止列或者行的Resize 

8、　列宽和行高以及列头的高度和行头的宽度的自动调整 

9、　冻结列或行 

10、　列顺序的调整 

11、　行头列头的单元格 

12、　剪切板的操作 

13、　单元格的ToolTip的设置 

14、　右键菜单（ContextMenuStrip）的设置 

15、　单元格的边框、 网格线样式的设定 

16、　单元格表示值的设定 

17、　用户输入时，单元格输入值的设定 

18、　设定新加行的默认值 


1、　DataGridView 取得或者修改当前单元格的内容： 


当前单元格指的是 DataGridView 焦点所在的单元格，它可以通过 DataGridView 对象的 CurrentCell 属性取得。如果当前单元格不存在的时候，返回Nothing(C#是null) 

[VB.NET] 

' 取得当前单元格内容   MessageBox.Show(DataGridView1.CurrentCell.Value) 

' 取得当前单元格的列 Index 

MessageBox.Show(DataGridView1.CurrentCell.ColumnIndex) 

' 取得当前单元格的行 Index 

MessageBox.Show(DataGridView1.CurrentCell.RowIndex) 


另外，使用 DataGridView.CurrentCellAddress 属性（而不是直接访问单元格）来确定单元格所在的行：DataGridView.CurrentCellAddress.Y 和列： DataGridView.CurrentCellAddress.X 。这对于避免取消共享行的共享非常有用。 


当前的单元格可以通过设定 DataGridView 对象的 CurrentCell 来改变。可以通过 CurrentCell 来设定 

DataGridView 的激活单元格。将 CurrentCell 设为 Nothing(null) 可以取消激活的单元格。 


[VB.NET] 

' 设定 (0, 0) 为当前单元格 

DataGridView1.CurrentCell = DataGridView1(0, 0) 



-------------------------------------------------------------------------------- 

2、　DataGridView 设定单元格只读： 


1） 使用 ReadOnly 属性 

　如果希望，DataGridView 内所有单元格都不可编辑， 那么只要： 

[VB.NET] 

' 设置 DataGridView1 为只读 

DataGridView1.ReadOnly = True 


　如果希望，DataGridView 内某个单元格不可编辑， 那么只要： 

[VB.NET] 

' 设置 DataGridView1 的第2列整列单元格为只读 

DataGridView1.Columns(1).ReadOnly = True 


' 设置 DataGridView1 的第3行整行单元格为只读 

DataGridView1.Rows(2).ReadOnly = True 


' 设置 DataGridView1 的[0，0]单元格为只读 

DataGridView1(0, 0).ReadOnly = True 


2） 使用 EditMode 属性 

DataGridView.EditMode 属性被设置为 DataGridViewEditMode.EditProgrammatically 时，用户就不能手动编辑单元格的内容了。但是可以通过程序，调用 DataGridView.BeginEdit 方法，使单元格进入编辑模式进行编辑。 

[VB.NET] 

DataGridView1.EditMode = DataGridViewEditMode.EditProgrammatically 


3） 根据条件设定单元格的不可编辑状态 

当一个一个的通过单元格坐标设定单元格 ReadOnly 属性的方法太麻烦的时候，你可以通过 CellBeginEdit 事件来取消单元格的编辑。 

[VB.NET] 

'CellBeginEdit 事件处理方法 

Private Sub DataGridView1_CellBeginEdit(ByVal sender As Object, _ 

ByVal e As DataGridViewCellCancelEventArgs) _ 

Handles DataGridView1.CellBeginEdit 

Dim dgv As DataGridView = CType(sender, DataGridView) 

' 是否可以进行编辑的条件检查 

If dgv.Columns(e.ColumnIndex).Name = "Column1" AndAlso _ 

Not CBool(dgv("Column2", e.RowIndex).Value) Then 

' 取消编辑 

e.Cancel = True 

End If 

End Sub 

-------------------------------------------------------------------------------- 

3、　DataGridView 不显示最下面的新行： 


通常 DataGridView 的最下面一行是用户新追加的行（行头显示 * ）。如果不想让用户新追加行即不想显示该新行，可以将 DataGridView 对象的 AllowUserToAddRows 属性设置为 False。 

[VB.NET] 

' 设置用户不能手动给 DataGridView1 添加新行 

DataGridView1.AllowUserToAddRows = False 


补足： 如果 DataGridView 的 DataSource 绑定的是 DataView, 还可以通过设置 DataView.AllowAdd 

属性为 False 来达到同样的效果。 



-------------------------------------------------------------------------------- 

4、　DataGridView 判断新增行： 


DataGridView的AllowUserToAddRows属性为True时也就是允许用户追加新行的场合下，DataGridView的最后一行就是新追加的行(*行)。使用 DataGridViewRow.IsNewRow 属性可以判断哪一行是新追加的行。另外，通过DataGridView.NewRowIndex 可以获取新行的行序列号。在没有新行的时候，NewRowIndex = -1。[VB.NET] 

If DataGridView1.CurrentRow.IsNewRow Then 

Console.WriteLine("当前行为新追加行。") 

Else 

Console.WriteLine("当前行不是新追加行。") 

End If 


-------------------------------------------------------------------------------- 

5、　DataGridView 行的用户删除操作的自定义： 


1） 无条件的限制行删除操作。 

默认时，DataGridView 是允许用户进行行的删除操作的。如果设置 DataGridView对象的AllowUserToDeleteRows属性为 False 时， 用户的行删除操作就被禁止了。 

[VB.NET] 

' 禁止DataGridView1的行删除操作。 

DataGridView1.AllowUserToDeleteRows = False 


但是，通过 DataGridViewRowCollection.Remove 还是可以进行行的删除。 

补足： 如果 DataGridView 绑定的是 DataView 的话，通过 DataView.AllowDelete 也可以控制行的删除。 


2） 行删除时的条件判断处理。 

用户在删除行的时候，将会引发 DataGridView.UserDeletingRow 事件。 在这个事件里，可以判断条件并取消删除操作。 

[VB.NET] 

' DataGridView1 的 UserDeletingRow 事件 

Private Sub DataGridView1_UserDeletingRow(ByVal sender As Object, _ 

ByVal e As DataGridViewRowCancelEventArgs) _ 

Handles DataGridView1.UserDeletingRow 

' 删除前的用户确认。 

If MessageBox.Show("确认要删除该行数据吗？", "删除确认", _ 

MessageBoxButtons.OKCancel, MessageBoxIcon.Question) <> _ 

Windows.Forms.DialogResult.OK Then 

' 如果不是 OK，则取消。 

e.Cancel = True 

End If 

End Sub 

-------------------------------------------------------------------------------- 

6、　DataGridView 行、列的隐藏和删除： 


1） 行、列的隐藏 

[VB.NET] 

' DataGridView1的第一列隐藏 

DataGridView1.Columns(0).Visible = False 

' DataGridView1的第一行隐藏 

DataGridView1.Rows(0).Visible = False 


2） 行头、列头的隐藏 

[VB.NET] 

' 列头隐藏 

DataGridView1.ColumnHeadersVisible = False 

' 行头隐藏 

DataGridView1.RowHeadersVisible = False 


3） 行和列的删除 

[VB.NET] 

' 删除名为"Column1"的列 

DataGridView1.Columns.Remove("Column1") 

' 删除第一列 

DataGridView1.Columns.RemoveAt(0) 

' 删除第一行 

DataGridView1.Rows.RemoveAt(0) 


4） 删除选中行 

[VB.NET] 

For Each r As DataGridViewRow In DataGridView1.SelectedRows 

If Not r.IsNewRow Then 

DataGridView1.Rows.Remove(r) 

End If 

Next 


-------------------------------------------------------------------------------- 

7、 DataGridView 禁止列或者行的Resize： 


1） 禁止所有的列或者行的Resize 

[VB.NET] 

' 禁止用户改变DataGridView1的所有列的列宽 

DataGridView1.AllowUserToResizeColumns = False 


'禁止用户改变DataGridView1の所有行的行高 

DataGridView1.AllowUserToResizeRows = False 



2） 禁止指定行或者列的Resize 

[VB.NET] 

' 禁止用户改变DataGridView1的第一列的列宽 

DataGridView1.Columns(0).Resizable = DataGridViewTriState.False 


' 禁止用户改变DataGridView1的第一列的行宽 

DataGridView1.Rows(0).Resizable = DataGridViewTriState.False 


关于 NoSet 


当 Resizable 属性设为 DataGridViewTriState.NotSet 时， 实际上会默认以 DataGridView 的 AllowUserToResizeColumns 和 AllowUserToResizeRows 的属性值进行设定。比如： DataGridView.AllowUserToResizeColumns = False 且 Resizable 是 NoSet 设定时，Resizable = False 。 



判断 Resizable 是否是继承设定了 DataGridView 的 AllowUserToResizeColumns 和 AllowUserToResizeRows 的属性值， 可以根据 State 属性判断。如果 State 属性含有 ResizableSet，那么说明没有继承设定。 



3） 列宽和行高的最小值的设定 

[VB.NET] 

' 第一列的最小列宽设定为 100 

DataGridView1.Columns(0).MinimumWidth = 100 


' 第一行的最小行高设定为 50 

DataGridView1.Rows(0).MinimumHeight = 50 


4) 禁止用户改变行头的宽度以及列头的高度 

[VB.NET] 

' 禁止用户改变列头的高度 

DataGridView1.ColumnHeadersHeightSizeMode = _ 

DataGridViewColumnHeadersHeightSizeMode.DisableResizing 


' 禁止用户改变行头的宽度 

DataGridView1.RowHeadersWidthSizeMode = _ 

DataGridViewRowHeadersWidthSizeMode.EnableResizing 


-------------------------------------------------------------------------------- 

8、 DataGridView 列宽和行高自动调整的设定： 


1) 设定行高和列宽自动调整 

[VB.NET] 

' 设定包括Header和所有单元格的列宽自动调整 

DataGridView1.AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.AllCells 


' 设定包括Header和所有单元格的行高自动调整 

DataGridView1.AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells 


2）指定列或行自动调整 

[VB.NET] 

' 第一列自动调整 

DataGridView1.Columns(0).AutoSizeMode = _ 

DataGridViewAutoSizeColumnMode.DisplayedCells 


3) 设定列头的高度和行头的宽度自动调整[VB.NET] 

' 设定列头的宽度可以自由调整 

DataGridView1.ColumnHeadersHeightSizeMode = _ 

DataGridViewColumnHeadersHeightSizeMode.AutoSize 


' 设定行头的宽度可以自由调整 

DataGridView1.RowHeadersWidthSizeMode = _ 

DataGridViewRowHeadersWidthSizeMode.AutoSizeToAllHeaders 


4） 随时自动调整 

a， 临时的，让列宽自动调整，这和指定AutoSizeColumnsMode属性一样。[VB.NET] 

' 让 DataGridView1 的所有列宽自动调整一下。 

DataGridView1.AutoResizeColumns(DataGridViewAutoSizeColumnsMode.AllCells) 


' 让 DataGridView1 的第一列的列宽自动调整一下。 

DataGridView1.AutoResizeColumn(0, DataGridViewAutoSizeColumnMode.AllCells) 


b，临时的，让行高自动调整 

[VB.NET] 

' 让 DataGridView1 的所有行高自动调整一下。 

DataGridView1.AutoResizeRows(DataGridViewAutoSizeRowsMode.AllCells) 


' 让 DataGridView1 的第一行的行高自动调整一下。 

DataGridView1.AutoResizeRow(0, DataGridViewAutoSizeRowMode.AllCells) 


c，临时的，让行头和列头自动调整 

[VB.NET] 

' 列头高度自动调整 

DataGridView1.AutoResizeColumnHeadersHeight() 


' 行头宽度自动调整 

DataGridView1.AutoResizeRowHeadersWidth( _ 

DataGridViewRowHeadersWidthSizeMode.AutoSizeToAllHeaders) 


关于性能： 

通过 AutoSizeColumnsMode 或者 AutoSizeRowsMode 属性所指定的单元格进行自动调整时，如果调整次数过于多那么将可能导致性能下降，尤其是在行和列数比较多的情况下。在这时用 DisplayedCells 代替 AllCells 能减少非所见的单元格的调整，从而提高性能。 


-------------------------------------------------------------------------------- 

9、 DataGridView 冻结列或行 


1） 列冻结 

DataGridViewColumn.Frozen 属性为 True 时， 该列左侧的所有列被固定， 横向滚动时固定列不随滚动条滚动而左右移动。这对于重要列固定显示很有用。 


[VB.NET] 

' DataGridView1的左侧2列固定 

DataGridView1.Columns(1).Frozen = True 


2） 行冻结 

DataGridViewRow.Frozen 属性为 True 时， 该行上面的所有行被固定， 纵向滚动时固定行不随滚动条滚动而上下移动。 

[VB.NET] 

' DataGridView1 的上3行固定 

DataGridView1.Rows(2).Frozen = True 


-------------------------------------------------------------------------------- 

10、 DataGridView 列顺序的调整 


设定 DataGridView 的 AllowUserToOrderColumns 为 True 的时候， 用户可以自由调整列的顺序。 

当用户改变列的顺序的时候，其本身的 Index 不会改变，但是 DisplayIndex 改变了。你也可以通过程序改变 DisplayIndex 来改变列的顺序。 列顺序发生改变时会引发 ColumnDisplayIndexChanged 事件： 

[VB.NET] 

' DataGridView1的ColumnDisplayIndexChanged事件处理方法 

Private Sub DataGridView1_ColumnDisplayIndexChanged(ByVal sender As Object, _ 

ByVal e As DataGridViewColumnEventArgs) _ 

Handles DataGridView1.ColumnDisplayIndexChanged 

Console.WriteLine("{0} 的位置改变到 {1} 。", _ 

e.Column.Name, e.Column.DisplayIndex) 

End Sub 


-------------------------------------------------------------------------------- 

11、 DataGridView 行头列头的单元格 


[VB.NET] 

' DataGridView1的第一列列头内容 

DataGridView1.Columns(0).HeaderCell.Value = "第一列" 


' DataGridView1的第一行行头内容 

DataGridView1.Rows(0).HeaderCell.Value = "第一行" 


' DataGridView1的左上头部单元内容 

DataGridView1.TopLeftHeaderCell.Value = "左上" 


[VB.NET] 

' 改变DataGridView1的第一列列头内容 

DataGridView1.Columns(0).HeaderText = "第一列" 


-------------------------------------------------------------------------------- 

12、 DataGridView 剪切板的操作 


DataGridView.ClipboardCopyMode 属性被设定为 DataGridViewClipboardCopyMode.Disable 以外的情况时，「Ctrl + C」 按下的时候，被选择的单元格的内容会拷贝到系统剪切板内。格式有： Text， UnicodeText，Html， CommaSeparatedValue。可以直接粘贴到 Excel 内。 


ClipboardCopyMode 还可以设定 Header部分是否拷贝： EnableAlwaysIncludeHeaderText 拷贝Header部分、EnableWithoutHeaderText 则不拷贝。默认是 EnableWithAutoHeaderText ， Header 如果选择了的话，就拷贝。 


1） 编程方式实现剪切板的拷贝 


Clipboard.SetDataObject(DataGridView1.GetClipboardContent()) 


2) DataGridView 的数据粘贴 


实现剪切板的拷贝比较容易，但是实现 DataGridView 的直接粘贴就比较难了。「Ctrl + V」按下进行粘贴时，DataGridView 没有提供方法，只能自己实现。 


以下，是粘贴时简单的事例代码，将拷贝数据粘贴到以选择单元格开始的区域内。 

[VB.NET] 

' 当前单元格是否选择的判断 

If DataGridView1.CurrentCell Is Nothing Then 

Return 

End If 

Dim insertRowIndex As Integer = DataGridView1.CurrentCell.RowIndex 


' 获取剪切板的内容，并按行分割 

Dim pasteText As String = Clipboard.GetText() 

If String.IsNullOrEmpty(pasteText) Then 

Return 

End If 

pasteText = pasteText.Replace(vbCrLf, vbLf) 

pasteText = pasteText.Replace(vbCr, vbLf) 

pasteText.TrimEnd(New Char() {vbLf}) 

Dim lines As String() = pasteText.Split(vbLf) 


Dim isHeader As Boolean = True 

For Each line As String In lines 

' 是否是列头 

If isHeader Then 

isHeader = False 

Else 

' 按 Tab 分割数据 

Dim vals As String() = line.Split(ControlChars.Tab) 

' 判断列数是否统一 

If vals.Length - 1 <> DataGridView1.ColumnCount Then 

Throw New ApplicationException("粘贴的列数不正确。") 

End If 

Dim row As DataGridViewRow = DataGridView1.Rows(insertRowIndex) 

' 行头设定 

row.HeaderCell.Value = vals(0) 

' 单元格内容设定 

Dim i As Integer 

For i = 0 To row.Cells.Count - 1 

row.Cells(i).Value = vals((i + 1)) 

Next i 


' DataGridView的行索引+1 

insertRowIndex += 1 

End If 

Next line 


-------------------------------------------------------------------------------- 

13、 DataGridView 单元格的ToolTip的设置 


DataGridView.ShowCellToolTips = True 的情况下， 单元格的 ToolTip 可以表示出来。对于单元格窄小，无法完全显示的单元格， ToolTip 可以显示必要的信息。 


1） 设定单元格的ToolTip内容 

[VB.NET] 

' 设定单元格的ToolTip内容 

DataGridView1(0, 0).ToolTipText = "该单元格的内容不能修改" 


' 设定列头的单元格的ToolTip内容 

DataGridView1.Columns(0).ToolTipText = "该列只能输入数字" 


' 设定行头的单元格的ToolTip内容 

DataGridView1.Rows(0).HeaderCell.ToolTipText = "该行单元格内容不能修改" 


2） CellToolTipTextNeeded 事件 

在批量的单元格的 ToolTip 设定的时候，一个一个指定那么设定的效率比较低， 这时候可以利用 CellToolTipTextNeeded 事件。当单元格的 ToolTipText 变化的时候也会引发该事件。但是，当DataGridView的DataSource被指定且VirualMode=True的时候，该事件不会被引发。 


[VB.NET] 

' CellToolTipTextNeeded事件处理方法 

Private Sub DataGridView1_CellToolTipTextNeeded(ByVal sender As Object, _ 

ByVal e As DataGridViewCellToolTipTextNeededEventArgs) _ 

Handles DataGridView1.CellToolTipTextNeeded 

e.ToolTipText = e.ColumnIndex.ToString() + ", " + e.RowIndex.ToString() 

End Sub 


-------------------------------------------------------------------------------- 

14、 DataGridView 的右键菜单（ContextMenuStrip） 


DataGridView, DataGridViewColumn, DataGridViewRow, DataGridViewCell 有 ContextMenuStrip 属性。可以通过设定 ContextMenuStrip 对象来控制 DataGridView 的右键菜单的显示。 DataGridViewColumn 的 ContextMenuStrip 属性设定了 除了列头以外的单元格的右键菜单。 DataGridViewRow 的 ContextMenuStrip 属性设定了除了行头以外的单元格的右键菜单。DataGridViewCell
 的 ContextMenuStrip 属性设定了指定单元格的右键菜单。 


[VB.NET] 

' DataGridView 的 ContextMenuStrip 设定 

DataGridView1.ContextMenuStrip = Me.ContextMenuStrip1 


' 列的 ContextMenuStrip 设定 

DataGridView1.Columns(0).ContextMenuStrip = Me.ContextMenuStrip2 

' 列头的 ContextMenuStrip 设定 

DataGridView1.Columns(0).HeaderCell.ContextMenuStrip = Me.ContextMenuStrip2 


' 行的 ContextMenuStrip 设定 

DataGridView1.Rows(0).ContextMenuStrip = Me.ContextMenuStrip3 


' 单元格的 ContextMenuStrip 设定 

DataGridView1(0, 0).ContextMenuStrip = Me.ContextMenuStrip4 



利用　CellContextMenuStripNeeded　事件可以设定单元格的右键菜单，尤其但需要右键菜单根据单元格值的变化而变化的时候。比起使用循环遍历，使用该事件来设定右键菜单的效率更高。但是，在DataGridView使用了DataSource绑定而且是VirtualMode的时候，该事件将不被引发。 



[VB.NET] 

'　CellContextMenuStripNeeded事件处理方法 

Private Sub DataGridView1_CellContextMenuStripNeeded( _ 

ByVal sender As Object, _ 

ByVal e As DataGridViewCellContextMenuStripNeededEventArgs) _ 

Handles DataGridView1.CellContextMenuStripNeeded 

Dim dgv As DataGridView = CType(sender, DataGridView) 

If e.RowIndex < 0 Then 

'　列头的ContextMenuStrip设定 

e.ContextMenuStrip = Me.ContextMenuStrip1 

ElseIf e.ColumnIndex < 0 Then 

'　行头的ContextMenuStrip设定 

e.ContextMenuStrip = Me.ContextMenuStrip2 

ElseIf TypeOf (dgv(e.ColumnIndex, e.RowIndex).Value) Is Integer Then 

'　如果单元格值是整数时 

e.ContextMenuStrip = Me.ContextMenuStrip3 

End If 

End Sub 


同样，可以通过　RowContextMenuStripNeeded　事件来设定行的右键菜单。 

[VB.NET] 

'　RowContextMenuStripNeeded事件处理方法 

Private Sub DataGridView1_RowContextMenuStripNeeded( _ 

ByVal sender As Object, _ 

ByVal e As DataGridViewRowContextMenuStripNeededEventArgs) _ 

Handles DataGridView1.RowContextMenuStripNeeded 

Dim dgv As DataGridView = CType(sender, DataGridView) 

'　当"Column1"列是Bool型且为True时、设定其的ContextMenuStrip 

Dim boolVal As Object = dgv("Column1", e.RowIndex).Value 

Console.WriteLine(boolVal) 

If TypeOf boolVal Is Boolean AndAlso CBool(boolVal) Then 

e.ContextMenuStrip = Me.ContextMenuStrip1 

End If 

End Sub 


CellContextMenuStripNeeded　事件处理方法的参数中、「e.ColumnIndex=-1」表示行头、「e.RowIndex=-1」表示列头。RowContextMenuStripNeeded则不存在「e.RowIndex=-1」的情况。 



-------------------------------------------------------------------------------- 

15、 DataGridView 的单元格的边框、 网格线样式的设定 


1) DataGridView 的边框线样式的设定 

DataGridView 的边框线的样式是通过 DataGridView.BorderStyle 属性来设定的。 BorderStyle 属性设定值是一个 

BorderStyle 枚举： FixedSingle（单线，默认）、Fixed3D、None。 


2) 单元格的边框线样式的设定 

单元格的边框线的样式是通过 DataGridView.CellBorderStyle 属性来设定的。 CellBorderStyle 属性设定值是 

DataGridViewCellBorderStyle 枚举。（详细参见 MSDN） 

另外，通过 DataGridView.ColumnHeadersBorderStyle 和 RowHeadersBorderStyle 属性可以修改 DataGridView 的头部的单元格边框线样式。 属性设定值是 DataGridViewHeaderBorderStyle 枚举。（详细参见 MSDN） 


3） 单元格的边框颜色的设定 

单元格的边框线的颜色可以通过 DataGridView.GridColor 属性来设定的。默认是 ControlDarkDark 。但是只有在 CellBorderStyle 被设定为 Single、SingleHorizontal、SingleVertical 的条件下才能改变其边框线的颜色。同样，ColumnHeadersBorderStyle 以及 RowHeadersBorderStyle 只有在被设定为 Single 时，才能改变颜色。 


4） 单元格的上下左右的边框线式样的单独设定 

CellBorderStyle只能设定单元格全部边框线的式样。要单独改变单元格某一边边框式样的话，需要用到DataGridView.AdvancedCellBorderStyle属性。如示例： 

[VB.NET] 

' 单元格的上边和左边线设为二重线 

' 单元格的下边和右边线设为单重线 

DataGridView1.AdvancedCellBorderStyle.Top = _ 

DataGridViewAdvancedCellBorderStyle.InsetDouble 

DataGridView1.AdvancedCellBorderStyle.Right = _ 

DataGridViewAdvancedCellBorderStyle.Inset 

DataGridView1.AdvancedCellBorderStyle.Bottom = _ 

DataGridViewAdvancedCellBorderStyle.Inset 

DataGridView1.AdvancedCellBorderStyle.Left = _ 

DataGridViewAdvancedCellBorderStyle.InsetDouble 

同样，设定行头单元格的属性是： AdvancedRowHeadersBorderStyle， 设定列头单元格属性是：AdvancedColumnHeadersBorderStyle。 



-------------------------------------------------------------------------------- 

16、 DataGridView 单元格表示值的自定义 


通过CellFormatting事件，可以自定义单元格的表示值。（比如：值为Error的时候，单元格被设定为红色） 

下面的示例：将“Colmn1”列的值改为大写。 

[VB.NET] 

'CellFormatting 事件处理方法 

Private Sub DataGridView1_CellFormatting(ByVal sender As Object, _ 

ByVal e As DataGridViewCellFormattingEventArgs) _ 

Handles DataGridView1.CellFormatting 

Dim dgv As DataGridView = CType(sender, DataGridView) 


' 如果单元格是“Column1”列的单元格 

If dgv.Columns(e.ColumnIndex).Name = "Column1" AndAlso _ 

TypeOf e.Value Is String Then 

' 将单元格值改为大写 

Dim str As String = e.Value.ToString() 

e.Value = str.ToUpper() 

' 应用该Format，Format完毕。 

e.FormattingApplied = True 

End If 

End Sub 


CellFormatting事件的DataGridViewCellFormattingEventArgs对象的Value属性一开始保存着未被格式化的值。当Value属性被设定表示用的文本之后，把FormattingApplied属性做为True，告知DataGridView文本已经格式化完毕。如果不这样做的话，DataGridView会根据已经设定的Format，NullValue，DataSourceNullValue，FormatProvider属性会将Value属性会被重新格式化一遍。 



-------------------------------------------------------------------------------- 

17、 DataGridView 用户输入时，单元格输入值的设定 


通过 DataGridView.CellParsing 事件可以设定用户输入的值。下面的示例：当输入英文文本内容的时候，立即被改变为大写。 

[VB.NET] 

'CellParsing 事件处理方法 

Private Sub DataGridView1_CellParsing(ByVal sender As Object, _ 

ByVal e As DataGridViewCellParsingEventArgs) _ 

Handles DataGridView1.CellParsing 

Dim dgv As DataGridView = CType(sender, DataGridView) 


' 单元格列为“Column1”时 

If dgv.Columns(e.ColumnIndex).Name = "Column1" AndAlso _ 

e.DesiredType Is GetType(String) Then 

' 将单元格值设为大写 

e.Value = e.Value.ToString().ToUpper() 

' 解析完毕 

e.ParsingApplied = True 

End If 

End Sub 


-------------------------------------------------------------------------------- 

18、 DataGridView 新加行的默认值的设定 


需要指定新加行的默认值的时候，可以在DataGridView.DefaultValuesNeeded事件里处理。在该事件中处理除了可以设定默认值以外，还可以指定某些特定的单元格的ReadOnly属性等。 

[VB.NET] 

' DefaultValuesNeeded 事件处理方法 

Private Sub DataGridView1_DefaultValuesNeeded(ByVal sender As Object, _ 

ByVal e As DataGridViewRowEventArgs) _ 

Handles DataGridView1.DefaultValuesNeeded 

' 设定单元格默认值 

e.Row.Cells("Column1").Value = 0 

e.Row.Cells("Column2").Value = "-" 

End Sub

1.在Form的Resize()方法中添加代码即可实现状态条随FORM变化
Private Sub MDIForm_Resize()
    Me.StatusBar1.Panels(1).Width = Me.Width / 3
    Me.StatusBar1.Panels(2).Width = Me.Width / 3
    Me.StatusBar1.Panels(3).Width = Me.Width / 3
End Sub
2.关于添加toolbar的设置.
先放一个imagelist 在它的右键属性里设置几个图标
然后放一个toolbar,右键toolbar属性设置,选择General-->imageList选择imagelist1
HotImageList选择imagelist1,然后到Buttons->image中选择imagelist中的图符1,2,3,4.

http://qian21h.bokee.com/viewdiary.15356105.html
Private Sub Form_Resize()
txt.Top = 200
txt.Height = Me.Height - 1500 - txt.Top
txt.Left = 400
txt.Width = Me.Width - 1000 - txt.Left
End Sub