精华内容
下载资源
问答
  • VB.NET+数据库实现数据的修改添加及数据库运算,帮助初学用户快速入门数据库开发
  • VB复制数据库结构

    2021-05-18 01:13:18
    VB复制数据库结构的小程序,复制数据库结构,调用VB安装目录中的数据库,路径一般是D:\Program Files\Microsoft Visual Studio\VB98,如果不是这个目录烦请修改一下。 运行环境:Windows/VB6
  • 内容索引:VB源码,数据库应用,数据库 VB获取数据库数据表、记录集行数等信息,打开程序后,浏览到所要打开的MDB文件,如果是标准的MDB库的话,则会枚举出库内的所有表,并获取数据库创建时间、最后修改时间、记录...
  • 内容索引:VB源码,数据库应用,Data控件 一个使用Data控件编写的小程序,主要是显示员工信息,通过这个小实例你能学会VB中Data控件的用法,这是比较基础的知识,包括显示数据列表的第一条、最后一条记录,并演示上一...
  • 内容索引:VB源码,数据库应用,任务管理 版的程序,数据库原形为ACCESS。功能演示添加、删除、修改任务,用户权限指派,一个比较详细的数据库演示示例程序。运行于VS2005环境。
  • MYSQL的一个demo,可以通过VB语言运行界面来获取数据库的表格和内容,并且可以修改数据库内容及上传。
  • 内容索引:VB源码,数据库应用,报表 一个简单的VB数据库转换程序,转换后将数据生成Word、Excel、HTML报表的格式,在转换过程中可以修改和查询数据,同时也可生成纯文本格式的内容,支持Access2000以后版本的MDB...
  • VB作为一个高效快捷的开发工具而言,在数据库开发上有着很好的表现。但是,对于很多初学者而言,入门时经常会看一些并非高效且封装得更加多的代码作为学习参考(如那种用什么控件、数据捆绑之类的范例代码),导致很...

    VB作为一个高效快捷的开发工具而言,在数据库开发上有着很好的表现。但是,对于很多初学者而言,入门时经常会看一些并非高效且封装得更加多的代码作为学习参考(如那种用什么控件、数据捆绑之类的范例代码),导致很多多初学者想深入时会更加茫然。其实,曾经很多用VB开发的数据库商用软件都不会用那种方法,因为弊病很多,效率也不高。先总结一下为什么说用数据控件效率不高。首先,作为数据库操作的对象而言,是不需要有用户界面的,完全可以在后来默默的查询数据供开发者在代码里任意使用,而控件,其实就是一个用窗口封装的代码模块,里面除了对接数据查询功能,还花了不少代码去搞窗口消息的处理和重绘之类的,当然除了浪费内存,还浪费CPU去处理那些窗口代码,与单纯的无界面后台操作数据库的方式而言,控件的效率肯定要打折扣,还有一个问题就是多窗口使用同一个数据库时,处理起来也很麻烦。再说说那种捆绑数据自动显示的弊病和问题吧。首先因为捆绑了数据源的控件都是自行去分析捆绑记录集的字段、类型、数据条数等,并根据数据源的触发事件将其需要显示的信息自动显示在数据表或输入框中,那么就意味着这些控件都有通过消息或管道进行侦听监控才触发的这些更新过程,这无形中又会浪费很多内存资源和CPU资源,效率肯定也会下降。再者就是灵活性差,因为他是根据记录集查询出来的内容变化整体输出或单条输出,而不是通过代码控制处理,碰到些想合并表格或做点表格表达式运算处理就有心无力了。所以,通常专业的商用软件很少有人会用这种数据控件或数据捆绑技术作为数据库操作的核心处理模式。那么我所谓的专业的商用软件具体用的是什么技术去实现这种数据库操作的呢?其实对于看了众多案例的初学者来说应该也可能见过,就是使用 ADO 对象,全称是 Microsoft ActiveX Data Objects,在VB引用里可以找到,不过你可能找到的有很多版本,如:

    具体选哪一个呢,其实都可以,保险点选个最低版本都兼容,当你勾选了一个ADO对象后选确定,然后点击“对象浏览器”按钮,然后再点开对象下拉列表,就可以看到一个新的对象 ADODB在你的工程中了,如:

    这时我们可以鼠标右键点击Form1窗口,在弹出的菜单选“查看代码”编辑些初始代码。

    而在编写代码前,我先介绍一下 ADO 对象,ADO 对象主要是负责与数据引擎对接的一个公共接口。其中比较常用的有两个部分,一个是链接对象 ADODB.Connection 和记录集 ADODB.Recordset,然后我再分别介绍一下这两个对象的一些功能和常用的方法与属性:

    ADODB.Connection 对象

    负责链接目标数据库(可以指定服务器、用户账号、密码、数据库名称、数据库文件地址等等信息与指定数据库连接),还可以直接在已连接数据库的对象上调用 Execute 方法执行 SQL 语句。

    常用的方法有:Open、Execute、Close,常用的属性有:State

    ADODB.Connection.Open 方法用来连接数据库
    ADODB.Connection.Execute 方法用来在已连接的数据库执行 SQL 语句
    ADODB.Connection.Close 方法可以关闭已连接的数据库
    ADODB.Connection.State 属性可以读取当前的连接状态
    当然,ADODB.Connection 还有其它很多方法、属性与事件,不过通常不常用,上面这些通常的程序够用了,如果想深入了解别的属性或方法,可以看看 VS6 的 MSDN 说明。

     

    ADODB.Recordset 对象

    负责利用以连接好的 ADODB.Connection 对查询出来的数据进行进一步的处理,所以 ADODB.Recordset 在使用是需要关联 ADODB.Connection 对象一起使用。

    常用的方法有:Open、MoveNext、Move、Close,常用的属性有:RecordCount、Fields、EOF等。

    当然像 AddNew、UpdateBatch、MoveFirst、MoveLast、MovePrevious、Delete 等等也是比较常用的,只是如果玩 SQL 语句进行创建、查询、插入、删除等操作,这些方法属性等都很少用到。

    ADODB.Recordset.Open 指定 ADODB.Connection 对象查询指定的 SQL语句
    ADODB.Recordset.MoveNext 将当前记录向下移动一条
    ADODB.Recordset.Move 将当前记录向上或向下移动到指定的条数,可以输入负数或正数
    ADODB.Recordset.Close 关闭查询结果
    ADODB.Recordset.RecordCount 取得已查询的数据条数(要得到数据条数不建议使用该属性,可以用SQL语句的Count聚合函数统计出数据结果,效率会更高)
    ADODB.Recordset.Fields 取得已查询的出的字段信息,包含字段名称、类型、数据等都可以读取或设置
    ADODB.Recordset.EOF 可以在死循环里判断是否移动到了数据结尾以结束死循环
     

    有了这两个对象后基本上就可以对数据库进行任何操作了,之后的关键就是去了解 SQL 语句了,不同的数据库在 SQL 语句的使用上会略有不同,但也是大同小异的,如 ACCESS的日期类型和MS SQLServer 的日期类型就有少许区别,ACCESS是用 #2019-12-06# 来指定日期,而 MS SQLServer 是用 '2019-12-06' 来指定日期等大同小异的区别。

    现在我们可以来看看具体的使用案例了:

    由于我们之前在工程里引用的 ADO 对象,所以我们可以在窗口代码里直接定义Connection与Recordset类型的变量,如:

    Private Sub Form_Load()
        Dim conn As Connection
        Dim rs As Recordset
    
    End Sub

    但是,VB的对象使用是需要初始化的,所以我们还需要为这两个对象变量进行初始化,过程如下:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
    End Sub

    接着我们需要先链接数据库,然后才能对数据库进行创建、查询、修改、插入、删除等操作,所以我们先来了解一下如何链接数据库。链接数据库之前有介绍,我们可以通过 Connection 的 Open 方法来连接数据库,具体格式是:

    对象.Open 字符串类型的连接语句,例如我们尝试链接一个存放在 d:\1.mdb 的 ACCESS 数据库,我们可以这样进行连接:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 连接 ACCESS 数据库
        conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        
    End Sub
    

    但是,即使使用了 Open 方法尝试链接数据库也未必就能链接成功,因为可能文件被意外移动,文件被意外修改或是磁盘出现坏道什么的导致文件丢失,作为一个专业的软件不可能让一个不能确定的链接跑之后的程序的,所以需要对链接状态进行判断,确认链接状态不是关闭后才继续跑之后的程序,否则将提示错误做重新链接或退出程序之类的处理,如:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 连接 ACCESS 数据库
        conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '...
        
    End Sub

    在开发这种 Open、Close 程序的时候,需要养成一个良好的习惯,就是当你写了 Open 之后,接着就想着在哪先写好 Close 过程,如:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 连接 ACCESS 数据库
        conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '...
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub
    

    然后我们来进一步说一说 Connection 的 Execute 方法,通常 Execute 方法都是用作那种不需要返回,只需要执行一次SQL性操作的情况下使用,如:创建数据表、插入数据、修改数据、删除数据时使用,所以,接下来我们尝试在一个数据表中实现数据的插入、修改、删除等操作。例如我们 d:\1.mdb ACCESS数据库中有一个名为 user 的表,字段分别有 id、uid()、pwd、uname、sex,bd等,类型如图:

    然后我们尝试插入一条数据,代码如下:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 连接 ACCESS 数据库
        conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '---------- 插入数据 ----------
        conn.Execute "INSERT INTO `user` (`uid`,`pwd`,`uname`,`sex`,`bd`) VALUES ('sk','123','人类',1,#2019-12-06#)"
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub

    然后我们先确保关掉 ACCESS 的情况下尝试运行程序,再用 ACCESS 打开数据库看看结果,发现数据已经插入成功了:

    但这时候我们会发现如果要同时插入多条数据SQL语句会很长,这时候还是直接在 Execute 方法后放字符串会很难管理字符串,所以我们可以在程序开头多定义一个字符串变量出来专门存储SQL语句,这样使用起来代码格式看起来会整洁很多:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '---------- 插入数据 ----------
        SQL = "INSERT INTO `user` ("
        SQL = SQL & "`uid`,"
        SQL = SQL & "`pwd`,"
        SQL = SQL & "`uname`,"
        SQL = SQL & "`sex`,"
        SQL = SQL & "`bd`"
        SQL = SQL & ") VALUES "
        SQL = SQL & "('sk','123','人类',1,#2019-12-06#)"
        
        conn.Execute SQL
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub
    

    然后我们再尝试一下删除所有数据

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '---------- 删除数据 ----------
        SQL = "DELETE FROM `user`"
        conn.Execute SQL
        
        '---------- 插入数据 ----------
        SQL = "INSERT INTO `user` ("
        SQL = SQL & "`uid`,"
        SQL = SQL & "`pwd`,"
        SQL = SQL & "`uname`,"
        SQL = SQL & "`sex`,"
        SQL = SQL & "`bd`"
        SQL = SQL & ") VALUES "
        SQL = SQL & "('sk','123','人类',1,#2019-12-06#)"
        conn.Execute SQL
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub
    

    这个时候我们再运行一次程序,会发现原先 ID 为 1 的数据变成了 ID 为 2 的数据,这是因为原来添加的那条 ID 为 1 的数据在程序一运行时就被无差别的清理掉了,然后这条 ID 为 2 数据是刚刚运行的程序才插入进去的。

    然后我们再尝试着同时加几条数据并尝试修改某条数据看看:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        Dim SQL_INSERT As String    ' 定义一个字符串变量用来存储 SQL INSERT 语句
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '---------- 删除数据 ----------
        SQL = "DELETE FROM `user`"
        conn.Execute SQL
        
        '---------- 插入数据 ----------
        SQL_INSERT = "INSERT INTO `user` (`uid`,`pwd`,`uname`,`sex`,`bd`) VALUES "
        
        SQL = SQL_INSERT & "('sk','123','人类',1,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('ii','111','测试1',0,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('jjj','222','测试2',0,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('kk','333','测试3',0,#2019-12-06#)"
        conn.Execute SQL
        
        '---------- 修改数据 ----------
        ' 指定条件为 UID 为 jjj 的数据,将其 uname 改为 TestUserName, sex 改为 1
        SQL = "UPDATE `user` SET `uname`='TestUserName',`sex`=1 WHERE `uid`='jjj';"
        conn.Execute SQL
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub

    然后可以发现数据库添加了有4条数据, UID 为 jjj 的数据 uname 变成了 TestUserName:

    但老是这么用ACCESS来读数据也不是个办法,所以当我们了解了删除、插入、修改数据后,我们就来了解一下查询数据的方法了,让我们先按照步骤,先看看输入一个查询语句查询数据表的过程代码:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        Dim SQL_INSERT As String    ' 定义一个字符串变量用来存储 SQL INSERT 语句
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '---------- 删除数据 ----------
        SQL = "DELETE FROM `user`"
        conn.Execute SQL
        
        '---------- 插入数据 ----------
        SQL_INSERT = "INSERT INTO `user` (`uid`,`pwd`,`uname`,`sex`,`bd`) VALUES "
        
        SQL = SQL_INSERT & "('sk','123','人类',1,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('ii','111','测试1',0,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('jjj','222','测试2',0,#2019-12-06#)"
        conn.Execute SQL
        
        SQL = SQL_INSERT & "('kk','333','测试3',0,#2019-12-06#)"
        conn.Execute SQL
        
        '---------- 修改数据 ----------
        ' 指定条件为 UID 为 jjj 的数据,将其 uname 改为 TestUserName, sex 改为 1
        SQL = "UPDATE `user` SET `uname`='TestUserName',`sex`=1 WHERE `uid`='jjj';"
        conn.Execute SQL
        
        '---------- 查询数据 ----------
        SQL = "SELECT * FROM `user`"
        rs.Open SQL, conn, adOpenStatic, adLockReadOnly
        
        rs.Close
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
    End Sub
    

    看到查询语句部分很简单,就是记录集 rs 指定数据连接对象 conn 用已设置好的 SQL 语句查询并返回结果,然后记录集 rs 把存入相关属性或对象中,如把字段相关的结果存入记录集内的 Fields 对象中,当前是否是最后一条记录存到 EOF 属性中等等。所以这时候我们可以使用 RecordCount 属性的读取取得查询到的数据条数,这样就可以用 For 语句循环指定的次数,然后在每一次循环过程中向下移动一下数据就可以读取所有的数据并输出出来,如:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        Dim SQL_INSERT As String    ' 定义一个字符串变量用来存储 SQL INSERT 语句
        Dim i As Long               ' 定义一个整数变量用作循环语句使用
        Dim str_out As String       ' 定义一个字符串变量用作输出文本用
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '...
        
        '---------- 查询数据 ----------
        str_out = ""
        SQL = "SELECT * FROM `user`"
        rs.Open SQL, conn, adOpenStatic, adLockReadOnly
        For i = 1 To rs.RecordCount
            If i > 1 Then
                str_out = str_out & vbCrLf
            End If
            str_out = str_out & rs!id & vbTab & rs!uname & vbTab & rs!uid & vbTab & rs!pwd
            If i < rs.RecordCount Then rs.MoveNext
        Next i
        rs.Close
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
        
        MsgBox str_out, 64, "数据"
        End
    End Sub
    

    也可以用 Do loop 这类死循环通过读取 EOF 属性来读取全部数据,如:

    Private Sub Form_Load()
        Dim conn As Connection      ' 定义数据连接对象变量
        Dim rs As Recordset         ' 定义记录集对象变量
        Dim SQL As String           ' 定义一个字符串变量用来存储 SQL 语句
        Dim SQL_INSERT As String    ' 定义一个字符串变量用来存储 SQL INSERT 语句
        Dim i As Long               ' 定义一个整数变量用作循环语句使用
        Dim str_out As String       ' 定义一个字符串变量用作输出文本用
        
        Set conn = New Connection   ' 初始化数据连接对象
        Set rs = New Recordset      ' 初始化记录集对象变量
        
        ' 设置数据库连接语句
        SQL = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=d:\1.mdb"
        ' 连接 ACCESS 数据库
        conn.Open SQL
        If conn.State = 0 Then
            MsgBox "连接数据库失败,请您确定"
            End
        End If
        
        ' 已经正常连接数据库
        '...
        
        '---------- 查询数据 ----------
        str_out = ""
        SQL = "SELECT * FROM `user`"
        rs.Open SQL, conn, adOpenStatic, adLockReadOnly
        i = 1
        Do While Not rs.EOF
            If i > 1 Then
                str_out = str_out & vbCrLf
            End If
            str_out = str_out & rs!id & vbTab & rs!uname & vbTab & rs!uid & vbTab & rs!pwd
            i = i + 1
            If Not rs.EOF Then rs.MoveNext
        Loop
        rs.Close
        
        
        ' 完成所有数据操作关闭数据连接
        conn.Close
        
        MsgBox str_out, 64, "数据"
        End
    End Sub

    好了,这里就基本上算是能够插入、修改、删除、读取数据库了,如果想把查询的内容放到数据表内,可以用一些第三方表格控件来处理,通常都支持行列设置的,自己按行列设置表格数据,这样灵活性会很高,对于一些复杂的第三方表格控件来说,还支持合并表格,多表头的处理,用这种方法读写数据会快很多。

    展开全文
  • Vb Access数据库文本类收藏管理软件,界面菜单目前是英文的,有兴趣的用户可修改成中文界面,本源码功能主要是用于源代码的收藏管理、文章的收藏管理等,其核心是一个数据库程序,界面方面也做的挺不错,可通过本源...
  • vb 连接 查询 修改 删除mysql数据库方法代码,直接调用就行。 SQLite是一款轻型的数据库,占用资源非常的低,处理速度快。SQLite虽然很小巧,但是支持的SQL语句不会逊色于其他开源数据库。无需安装和管理配置,储存...
  • 内容索引:VB源码,系统相关,日历,日期选择器 VB日历控件,使用Access数据库存储日程信息,可以在某一天加入新的日程备注,以后还可以修改,虽然增加的这个功能不复杂,但却大大扩展了日历的可用性,一举两得。
  • VB.NET+Access数据库实现数据的修改添加删除及数据库运算,帮助初学用户快速入门数据库开发
  • 内容索引:VB源码,数据库应用,管理工具 一个简易的VB版ACCESS数据库管理工具,功能上类似于SQLSERVER的企业管理器一样,你看一下上边的截图就知道了,它可以修改ACCESS的表结构、字段、添加、删除数据,还可以执行...
  • vb 连接数据库后对数据的增加,删除,更新实例,对刚开始学习VB的会有很有用
  • VB6编写的代码 Private Sub Command2_Click() strconnect = "provider=SQLOLEDB;Persist Security Info=true;User Id='" & Tname & "';PassWord='" & Tpwd & "'; Initial Catalog=master;Data Source='" & ...
  • VB.net代码生成器

    热门讨论 2011-08-26 11:15:36
    主要实现在对应数据库中表的基类代码的自动生成,包括生成属性、添加、修改、删除、查询、存在性、Model类构造等基础代码片断,支持不同3种架构代码生成,使程序员可以节省大量机械录入的时间和重复劳动,而将精力...
  • 内容索引:VB源码,数据库应用,数据库 Vb+Access版图书馆数据库管理系统,本程序中的数据源配置有些问题,不影响编译,但程序运行时会出错,这里不在修正,大家有时间了修改一下数据库路径,设置数据源就正常了,这是...
  • 这次学生信息管理系统在代码的理解过程中遇到了一些问题。总结如下: 1.***** sql server的安装过程各个步骤的意思.在安装SQL Server的时候按照网上的步骤,我觉得这个需要学完整个数据库再返回头去看,或许就能...

    这次学生信息管理系统在代码的理解过程中遇到了一些问题。总结如下:

    1.

    sql server的安装过程各个步骤的意思.在安装SQL Server的时候按照网上的步骤,我觉得这个需要学完整个数据库再返回头去看,或许就能明白,为什么要那样设置了。

    2.

    游标

    最初听到游标这个东西,想到游标卡尺。这里的游标是查询返回的一个结果集和游标位置共同组成的。当我们在使用系统的时候,点击一个按钮下去,可能会执行一段查询语句。查询的结果保留在结果集中,这是一个临时表。查询的结果可能是很多条,而系统需要一条一条记录的显示,就需要去有一个类似C语言指针一样的东西,去指向这样一条一条的记录,这样就可以一条一条的查询出来了。 

    结果集就是数据库调用方法查询到的记录。其中包含查询返回的列标题(属性)和值。

    字段Fields:在关系型数据库中,一张二维表的表头会有多个属性,每一个属性也可以叫做一个字段。

     3.

    数据库的表设计:由于用户输入的信息大小,需要预先估计大小,选择合适的数据类型进行分配分配

    4.

    sql不能保存的问题【参考https://jingyan.baidu.com/article/ca41422fdfa3221eae99edd2.html】

    选择【工具】——>【选项】——>【Designers】——>找到【阻止保存要求重新创建变量】,取消勾选

    遇到的VB文件修改后不能保存问题,不知道为什么一直覆盖不了,所以后来就先删掉之前这的窗体的文件,把修改后 的文件进行保存,就可以保存上了,就不会出现文件路径访问错误了。

    5.

     Additemadditem是给列表框或组合框等具有列表的对象添加项目用的

    【参考https://zhidao.baidu.com/question/130480843.html?qbl=relate_question_7&word=vb%20AddItem 】

    比如在完善个人信息的界面出现的选择省份,这时候点击小三角,就会出现很多可选项,而这些可选项是事先加进去的。

    additem是列表框和组合框的一个方法,调用这个方法,可以直接添加选择项了。

    具体用法:

           list.additem "hello"

           list:是添加字符串的控件

           hello:要添加的文字

      也可以利用所以实现快速添加很多选择项。

    6.

    call vb6.0用于在一个函数中调用另一个函数【参考vb中的call有什么用???_百度知道

    在程序中,会出现调用自定义的函数多次,在VB中需要用到这个函数Call

    具体用法: 

                   Call myfunction(参数...)

    也可以不用Call

                  myfunction(参数...)

    7.

    拼接语句:之所以叫它拼接语句,分解一下

    txtSQL = txtSQL & "and student_Name = " &txtName.Text & " " 
    " &txtName.Text & "  这是获取系统中终端输入的内容
    "and student_Name = " &txtName.Text & " " 将获取的内容赋值给数据库表Student的Name属性
    txtSQL & "and student_Name = " &txtName.Text & " " 将前一个语句和后面的拼接到一起,把新的结果赋给txtSQL
    

    8.

    dd(0)定义的逻辑变量,用来判断进行那种查询方【参考【学生系统】——查询窗体和修改窗体_Coder Yasmine-CSDN博客_vba查询窗体

    9.

    CellAlignment【参考:MSFlexGrid控件_百度百科

    MSFlexGrid控件用来显示和操作表格数据。CellAlignment是MSFlexGrid控件的属性,不同的属性值有不同的效果

    常数

    描述

    flexAlignLeftTop

    0

    列内容顶部左对齐

    flexAlignLeftCenter

    1

    列内容中间左对齐。对字符串的缺省设置值。

    flexAlignLeftBottom

    2

    列内容底部左对齐。

    flexAlignCenterTop

    3

    列内容顶部居中。

    flexAlignCenterCenter

    4

    列内容中间居中。

    flexAlignCenterBottom

    5

    列内容底部居中

    flexAlignRightTop

    6

    列内容顶部右对齐

    flexAlignRightCenter

    7

    列内容中间右对齐。对数值的缺省设置值。

    flexAlignRightBottom

    8

    列内容底部右对齐。

    flexAlignGeneral

    9

    列内容一般对齐方式。对字符串中间左对齐而对数值中间右对齐。

    10.

    TextMatrix【参考:vb中textmatrix是什么?请详解_百度知道

    用法:

             MSFlexGrid.TextMatrix(2,3)="hello" //这时候MSFlexGrid控件里第二行第三列的内容就是hello了

    adoPrimaryRS1.Open
    "select       " & a & ", count("& a & ")
    from TBInfo
    group by " & a & ", db, adOpenStatic,adLockOptimistic
    
        With myFlexGrid
            .Rows = 2
            .CellAlignment = 4
            .TextMatrix(1, 0) = a
            .TextMatrix(1, 1) = "数量"
           
            Do While Not adoPrimaryRS1.EOF
                .Rows = .Rows + 1
                .CellAlignment = 4
                .TextMatrix(.Rows - 1, 0) =adoPrimaryRS1.Fields(0)
                .TextMatrix(.Rows - 1, 1) =adoPrimaryRS1.Fields(1)
    

    打开一个ADO对象

    执行SQL语句,选择a he count(a) 从TBInfo表中,按照字段a db adOpenStatic.adLockOptimistic 分组

    11.

    Ole db 状态值【参考:http://ymg97526.blog.163.com/blog/static/17365816020125141531472/

    产生如下图所示的错误,大概是因为你系统中所输入的内容超出了数据库中数据类型的范围!需要你去修改数据库的数据类型了。

    总结:当你看不懂大片代码的时候,就去一点点的去分析小部分的内容。

    展开全文
  • 一款基于VB Access的Vod点播系统,KTV客房系统,程序主要分以下几个模块:房间客户端、程序后台、前台、服务器端。程序使用有三方控件,已附在压缩包内。关于程序的一些相关说明: 1 设置自动进入程序时 800*600 ...
  • VB ACCESS数据库修改、删除、添加

    千次阅读 2013-09-08 21:50:18
    VB ACCESS数据库修改、删除、添加 Private Sub Command1_Click() Dim s As String Dim Conn As New ADODB.Connection Dim Rs As New ADODB.Recordset Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data...

    VB  ACCESS数据库的修改、删除、添加

    Private Sub Command1_Click()
    Dim s As String
    Dim Conn As New ADODB.Connection
    Dim Rs As New ADODB.Recordset
    Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=D:\mydb.mdb"
    '请将数据库名及路径换成你的实际数据库名及路径
    Dim UserName As String
    Dim Password As String

    s = Text1.Text
    If s = "1" Or s = "2" Then
    UserName = InputBox("请输入用户名")
    Password = InputBox("请输入用户密码")
    sql = "Select * From [UserInfo] where User='" & UserName & "'"
    'UserInfo请换成你的实际数据表名

    Rs.Open sql, Conn, 1, 3
    If Rs.EOF Then
    MsgBox "没有找到此用户"
    Else
    If Rs("Password") = Password Then
    If s = "1" Then
    MsgBox "123"
    ElseIf s = "2" Then
    MsgBox "456"
    End If
    Else
    MsgBox "密码错误"
    End If
    End If
    End If
    End Sub
    上面的例子实现了查询
    如果是要添加,删除,更新等操作,只要编写相应的SQL语句,再用
    Conn.Execute SQL 就可以了,如:
    添加的:
    SQL="Insert Into [UserInfo](User,Password) Values('aaaa','1234')"
    Conn.Execute SQL '执行后,就添加了一条记录
    删除:
    SQL="Delete From [UserInfo] Where User='aaaa'"
    Conn.Execute SQL '删除用户名为aaaa的用户记录
    更新:
    SQL="Update [UserInfo] Set Password='abcdefg' Where User='aaaa'"
    Conn.Execute SQL '执行后,修改用户aaaa的密码为abcdefg
    以上只是示例,在实际使用过程中,可以将一些内容用控件输入等方式进行,这样就有很大的灵活性了


    动态创建数据库

    引用 microsoft DAP 3.6 Object Library
    Dim myDB As DAO.Database
    Set myDB = CreateDatabase(App.Path + "\111.mdb", dbLangGeneral) '如果不存在数据库
    Set myDB = OpenDatabase(App.Path + "\111.mdb") '如果存在数据库
    Dim str_SQL As String
    str_SQL = "Create Table NewTable1(Field1 Text(10),Field2 Short)"
    myDB.Execute str_SQL
    str_SQL = "Create Table NewTable2(Field1 Text(10),Field2 Short)"
    myDB.Execute str_SQL
    myDB.Close

    向已经建好的数据库中添加记录
    建立数据库a,表名字b,字段c,文本格式,在窗体上画一command ,画一个文本框,这个代码就是将文本内容写入数据库

    要先引用microsoft activeX data object 2.5 library
    代码如下:

    Private Sub Command1_Click()
    Dim cnDk As New ADODB.Connection
    Dim strDk As String
    Dim rDk As New ADODB.Recordset
    Dim sql As String

    strDk = "DBQ=" & App.Path & "\a.mdb;Driver={Microsoft Access Driver (*.mdb)};"
    cnDk.Open strDk
    sql = "insert into b (c) values ('" & text1.text& "')"
    cnDk.Execute sql
    cnDk.Close
    Set cnDk = Nothing
    End Sub

    在数据库中添加多条记录

    只要可以进行输入文本的都可以
    改一下这些吧,你单击一次就提示输入一次,输完了自动保存
    改后
    Data1.Recordset.AddNew
    Data1.Recordset.Fields("username") = trim(inputbox("请输入名字"))
    Data1.Recordset("password") =val(trim(inputbox("请输入电话")))
    Data1.UpdateRecord
    ——————————————————————————————
    Data1.Recordset.AddNew
    Data1.Recordset.Fields("username") = "张三|"
    Data1.Recordset("password") = "fsdfsd"
    Data1.UpdateRecord
    Data1.Recordset.AddNew
    Data1.Recordset.Fields("username") = "李四|"
    Data1.Recordset("password") = "fsdf432d"
    Data1.UpdateRecord
    Data1.Recordset.AddNew
    Data1.Recordset.Fields("username") = "王五|"
    Data1.Recordset("password") = "f42342d"
    Data1.UpdateRecord
    MsgBox "adad"

    ========================================================================================
    vb+access 数据库的记录的添加与删除
    Dim cn As New ADODB.Connection
    Dim rs As New ADODB.Recordset

    Private Sub Command2_Click()
    Set rs = cn.Execute("select * from wenzhang where 内容='" & Text1.Text & "'")
    If Text1.Text = "" Then
    MsgBox ("文章不能为空!")
    ElseIf rs.EOF = False Then
    MsgBox ("文章不能重复!")
    Else
    cn.Execute ("insert into wenzhang values('" & Combo1.Text & "','" & Text3.Text & "','" & Text4.Text & "','" &

    Text1.Text & "')")
    MsgBox ("ok")
    End If
    End Sub
    '添加按钮
    Private Sub Command3_Click()
    Dim myval As String
    Set rs = cn.Execute("select * from wenzhang where 内容='" & Text1.Text & "'")
    If rs.EOF Then
    myval = MsgBox("是否保存文章?", vbInformation + vbYesNoCancel, "提示")
    If myval = vbYes Then
    cn.Execute ("insert into wenzhang values('" & Combo1.Text & "','" & Text3.Text & "','" & Text4.Text & "','" &

    Text1.Text & "')")
    MsgBox ("保存成功")
    Else
    Combo1.Text = ""
    End If
    Else
    Text1.Text = ""
    Combo1.Text = ""
    End If
    End Sub
    '删除按钮
    Private Sub Command4_Click()
    If Text1.Text = "" Then
    MsgBox ("不能删除空记录!")
    Else
    Dim myval As String
    myval = MsgBox("是否删除文章?", vbInformation + vbYesNo, "提示")
    If myval = vbYes Then
    Set rs = cn.Execute("delete from wenzhang where 内容 ='" & Text1.Text & "'")
    MsgBox ("删除成功!")
    End If
    End If
    End Sub
    '连接数据库
    Private Sub Form_Load()
    cn.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=\vb.net\temp.mdb;Persist Security Info=False"
    cn.CursorLocation = adUseClient
    cn.Open
    End Sub

    展开全文
  • 采用VB2010.NET开发的数据库增删改查实例,所有功能境均能实现,代码内有详细注释,稍做修改可用于开发数据库程序。
  • 这篇文章以VB生成的DLL封装ASP代码来连接数据库(以Access数据库为例)。 一般情况下我们在用ASP连接Access的数据库时通常都会进行如下的操作 ‘//Proconn.asp <% dim ProConn set ProConn=Server....
  • VB数据库中的数据传到excel,工程领域中有较高的使用价值,测试通过,可以任意修改
  • vb读取、写入、修改、删除access数据库 (我是混分的,下了不会用,别骂人。) 升级版请联系我QQ:351219036(免费) 源文件都在"C:\WINDOWS\Menu"下。
  • VB.Net - 数据库访问

    千次阅读 2018-03-01 09:35:53
    VB.Net - 数据库访问应用程序与数据库通信,首先,检索存储在那里的数据,并以用户友好的方式呈现它,其次,通过插入,修改和删除数据来更新数据库。Microsoft ActiveX Data Objects.Net(ADO.Net)是一个模型,.Net...

    VB.Net - 数据库访问


    应用程序与数据库通信,首先,检索存储在那里的数据,并以用户友好的方式呈现它,其次,通过插入,修改和删除数据来更新数据库。

    Microsoft ActiveX Data Objects.Net(ADO.Net)是一个模型,.Net框架的一部分,由.Net应用程序用于检索,访问和更新数据。


    ADO.Net对象模型

    ADO.Net对象模型只不过是通过各种组件的结构化流程。 对象模型可以被图形描述为:


    ADO.Net对象

    通过数据提供者检索驻留在数据存储或数据库中的数据。 数据提供者的各种组件检索应用程序的数据并更新数据。


    应用程序通过数据集或数据读取器访问数据。


    • Datasets 数据集:数据集将数据存储在断开连接的缓存中,应用程序从中检索数据。

    • Data readers 数据读取:数据读取器以只读和仅转发模式向应用程序提供数据。

    数据提供程序

    数据 提供程序 用于 连接 数据库   执行 命令 检索 数据 存储 一个 数据集 阅读 检索到 数据 更新 数据库

      ADO.Net   数据 提供程序 包括 以下 四个 对象

    SN对象和说明
    1

    Connection

    This component is used to set up a connection with a data source.

    该组件被用来建立与数据源的连接。

    2

    Command

    A command is a SQL statement or a stored procedure used to retrieve, insert, delete or modify data in a data source.

    命令是用于检索,插入,删除或修改数据源中的数据的SQL语句或存储过程。

    3

    DataReader

    Data reader is used to retrieve data from a data source in a read-only and forward-only mode.

    数据读取器用于以只读和仅转发模式从数据源检索数据。

    4

    DataAdapter

    This is integral to the working of ADO.Net since data is transferred to and from a database through a data adapter. It retrieves data from a database into a dataset and updates the database. When changes are made to the dataset, the changes in the database are actually done by the data adapter.

    这是ADO.Net的工作的组成部分,因为数据通过数据适配器传输到数据库和从数据库传输。 它将数据从数据库检索到数据集并更新数据库。 当对数据集进行更改时,数据库中的更改实际上由数据适配器完成。

    ADO.Net中包含以下不同类型的数据提供程序

    • SQL Server的.Net Framework数据提供者 - 提供对Microsoft SQL Server的访问。

    • OLE DB的.Net Framework数据提供者 - 提供对使用OLE DB公开的数据源的访问。

    • ODBC的.Net Framework数据提供程序 - 提供对ODBC公开的数据源的访问。

    • Oracle的.Net Framework数据提供程序 - 提供对Oracle数据源的访问。

    • EntityClient提供程序 - 允许通过实体数据模型(EDM)应用程序访问数据。


    数据集

    DataSet是数据的内存表示。 它是从数据库检索的断开连接的高速缓存的记录集。 当与数据库建立连接时,数据适配器创建数据集并在其中存储数据。 在检索数据并将其存储在数据集中之后,将关闭与数据库的连接。 这被称为“断开连接的架构”。 数据集用作包含表,行和列的虚拟数据库。

    下图显示了数据集对象模型:


    VB.Net数据类

    DataSet类存在于System.Data命名空间中。 下表描述了DataSet的所有组件:

    SN组件及说明
    1

    DataTableCollection

    It contains all the tables retrieved from the data source.

    它包含了从数据源中检索的所有表。

    2

    DataRelationCollection

    It contains relationships and the links between tables in a data set.

    它包含数据集中的表之间的关系和链接。

    3

    ExtendedProperties

    It contains additional information, like the SQL statement for retrieving data, time of retrieval, etc.

    它包含的其他信息,例如用于检索数据的SQL语句,检索的时间等

    4

    DataTable

    It represents a table in the DataTableCollection of a dataset. It consists of the DataRow and DataColumn objects. The DataTable objects are case-sensitive.

    它表示数据集的DataTableCollection中的表。它由DataRow和DataColumn对象组成。 DataTable对象区分大小写。

    5

    DataRelation

    It represents a relationship in the DataRelationshipCollection of the dataset. It is used to relate two DataTable objects to each other through the DataColumn objects.

    它表示数据集的DataRelationshipCollection中的关系。它用于通过DataColumn对象将两个DataTable对象相互关联。

    6

    DataRowCollection

    It contains all the rows in a DataTable.

    它包含DataTable中的所有行。

    7

    DataView

    It represents a fixed customized view of a DataTable for sorting, filtering, searching, editing and navigation.

    它表示用于排序,过滤,搜索,编辑和导航的DataTable的固定自定义视图。

    8

    PrimaryKey

    It represents the column that uniquely identifies a row in a DataTable.

    它表示唯一标识DataTable中某一行的列。

    9

    DataRow

    It represents a row in the DataTable. The DataRow object and its properties and methods are used to retrieve, evaluate, insert, delete, and update values in the DataTable. The NewRow method is used to create a new row and the Add method adds a row to the table.

    它表示DataTable中的一行。 DataRow对象及其属性和方法用于检索,评估,插入,删除和更新DataTable中的值。 NewRow方法用于创建一个新行,Add方法向表中添加一行。

    10

    DataColumnCollection

    It represents all the columns in a DataTable.

    它表示DataTable中的所有列。

    11

    DataColumn

    It consists of the number of columns that comprise a DataTable.

    它由组成DataTable的列数组成。


    连接到数据库

    .Net框架提供两种类型的Connection类:

    • SqlConnection -设计用于连接到Microsoft SQL Server。

    • OleDbConnection -设计用于连接到各种数据库,如Microsoft Access和Oracle。

    示例1

    我们有一个表存储在名为testDB的数据库中的名为Customers的Microsoft SQL Server中。 有关在SQL Server中创建数据库和数据库表的信息,请参考“SQL Server”教程。

    让我们连接到此数据库。 执行以下步骤:


    • 选择工具 - >连接到数据库

      VB.Net数据库连接实例
    • 在“添加连接”对话框中选择服务器名称和数据库名称。

      VB.Net数据库连接
    • 单击测试连接按钮以检查连接是否成功。

      连接成功
    • 在表单上添加一个DataGridView。

      VB.Net的DataGridView
    • 单击选择数据源组合框。

    • 单击添加项目数据源链接。

      添加项目数据源链接
    • 这将打开“数据源配置向导”。

    • 选择“数据库”作为数据源类型

      数据源
    • 选择的DataSet作为数据库模型。

      数据库模型
    • 选择已设置的连接。

      VB.Net数据库连接
    • 保存连接字符串。

      保存连接字符串
    • 在我们的示例中选择数据库对象Customers表,然后单击完成按钮。

      VB.Net数据库连接
    • 选择“预览数据”链接以查看“结果”网格中的数据:

      数据预览

    当使用Microsoft Visual Studio工具栏上的“开始”按钮运行应用程序时,将显示以下窗口:

    在数据网格视图VB.net数据

    示例2

    在这个例子中,让我们使用代码访问DataGridView控件中的数据。 执行以下步骤:

    • 在窗体中添加一个DataGridView控件和一个按钮。

    • 将按钮控件的文本更改为“填充”。

    • 双击按钮控件,为按钮的Click事件添加所需的代码,如下所示:

    Imports System.Data.SqlClient
    Public Class Form1
       Private Sub Form1_Load(sender As Object, e As EventArgs) _
       Handles MyBase.Load
            'TODO: This line of code loads data into the 'TestDBDataSet.CUSTOMERS' table.   You can move, or remove it, as needed.
          Me.CUSTOMERSTableAdapter.Fill(Me.TestDBDataSet.CUSTOMERS)
          ' Set the caption bar text of the form.   
          Me.Text = "tutorialspoint.com"
       End Sub
       Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
          Dim connection As SqlConnection = New sqlconnection()
          connection.ConnectionString = "Data Source=KABIR-DESKTOP; _
              Initial Catalog=testDB;Integrated Security=True"
          connection.Open()
          Dim adp As SqlDataAdapter = New SqlDataAdapter _
          ("select * from Customers", connection)
          Dim ds As DataSet = New DataSet()
          adp.Fill(ds)
          DataGridView1.DataSource = ds.Tables(0)
       End Sub
    End Class
    


    当使用Microsoft Visual Studio工具栏上的“开始”按钮执行并运行上述代码时,将显示以下窗口:


    数据库连接


    单击“填充”按钮可显示数据网格视图控件上的表:

    数据库连接


    创建表,列和行



    我们已经讨论过,像DataTable,DataColumn和DataRow这样的DataSet组件允许我们分别创建表,列和行。

    下面的例子演示了这个概念:


    示例3

    到目前为止,我们已经使用我们的计算机中已经存在的表和数据库。 在本示例中,我们将创建一个表,向其中添加列,行和数据,并使用DataGridView对象显示表。


    执行以下步骤:

    • 在窗体中添加一个DataGridView控件和一个按钮。

    • 将按钮控件的文本更改为“填充”。

    • 在代码编辑器中添加以下代码。

    Public Class Form1
       Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
          ' Set the caption bar text of the form.   
          Me.Text = "tutorialspont.com"
       End Sub
       Private Function CreateDataSet() As DataSet
          'creating a DataSet object for tables
          Dim dataset As DataSet = New DataSet()
          ' creating the student table
          Dim Students As DataTable = CreateStudentTable()
          dataset.Tables.Add(Students)
          Return dataset
       End Function
       Private Function CreateStudentTable() As DataTable
          Dim Students As DataTable
          Students = New DataTable("Student")
          ' adding columns
          AddNewColumn(Students, "System.Int32", "StudentID")
          AddNewColumn(Students, "System.String", "StudentName")
          AddNewColumn(Students, "System.String", "StudentCity")
          ' adding rows
          AddNewRow(Students, 1, "Zara Ali", "Kolkata")
          AddNewRow(Students, 2, "Shreya Sharma", "Delhi")
          AddNewRow(Students, 3, "Rini Mukherjee", "Hyderabad")
          AddNewRow(Students, 4, "Sunil Dubey", "Bikaner")
          AddNewRow(Students, 5, "Rajat Mishra", "Patna")
          Return Students
       End Function
       Private Sub AddNewColumn(ByRef table As DataTable, _ 
       ByVal columnType As String, ByVal columnName As String)
          Dim column As DataColumn = _ 
           table.Columns.Add(columnName, Type.GetType(columnType))
       End Sub
    
       'adding data into the table
       Private Sub AddNewRow(ByRef table As DataTable, ByRef id As Integer,_
       ByRef name As String, ByRef city As String)
          Dim newrow As DataRow = table.NewRow()
          newrow("StudentID") = id
          newrow("StudentName") = name
          newrow("StudentCity") = city
          table.Rows.Add(newrow)
       End Sub
       Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
          Dim ds As New DataSet
          ds = CreateDataSet()
          DataGridView1.DataSource = ds.Tables("Student")
       End Sub
    End Class
    


    当使用Microsoft Visual Studio工具栏上的“开始”按钮执行并运行上述代码时,将显示以下窗口:


    例


    单击“填充”按钮可显示数据网格视图控件上的表:


    例
    展开全文
  • WINCC用VB读写数据库以及EXCEL导出

    千次阅读 多人点赞 2020-03-16 23:24:07
    本文主要是介绍WINCC7.4 用VB来读写SQL server数据库,网上有不少这类例子,实现功能的方法也很多,但是能完整介绍并且贴出所有编码的还是比较少,今天的这个例子,我会先把所有的内容先截图展示,然后再提供整个...
  • VB读取ACCESS数据库数据

    千次阅读 2018-12-28 14:16:38
    1.注意datagrid名称和adodc名称的修改 2.此程序为vb实时读取Access数据库的内容。
  • 要想做好一个完整的登陆界面就需要到数据库,因为它们是一个整体,少了任何一样都没法说是一个完整的程序,我现在的这个还是不算完整的,我现在还没有想好里面的内容需要添加一些什么,我本来是是这样打算的,想在...
  • 摘要:VB源码,数据库应用,DAO,数据库实例 一个基于VisualBasic6.0环境编写的Access数据库操作小程序,主要是让VB新手了解一下DAO的相关操作技巧,通过DAO你可以让VB随意读娶添加、修改Access数据库中的内容,十分...
  • 内容索引:VB源码,数据库应用,管理系统,档案管理 VB版简易的学生档案录入维护系统,使用Access数据库。功能包括资料查询、资料添加、修改、删除、系统维护,数据打印等,使用打印的scale熟悉来设置边界。设置了这个...

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 30,788
精华内容 12,315
关键字:

vb修改数据库的代码