精华内容
下载资源
问答
  • 这是一个VB小程序,可以用来进行打开一个文件出现的对话框,可以对文件夹进行选择,欢迎大家下载。
  • 1.本程序的对话框和OpenFileDialog对话框一样,可以输入路径, ...3.也可以选择选择文件,同时选择多个文件。 应用代码非常简单。 再也不用FolderBrowserDialog这个老土的对话框选文件夹了!!!
  • VB文件浏览对话框代码,就是打开文件的对话框,在VB中默认有这个功能,不过本代码所演示的是另外一种方法,而且要更漂亮一些,代码也是简单的那种,VB初学者也容易看懂。
  • 程序自己编的,工程打开就用,实现的功能是:点击按钮,打开commondialog对话框,同时选取多个文件,文件名全路径会保存到数组。也有注释,便于学习,加载多个文件的代码我写成了函数,直接拷贝调用即可!相当方便!
  • 摘要:VB源码,界面编程,对话框 Vb调用Windows颜色和文件对话框,比较初级的小技巧,本程序是VB简明教程第八章中的一个窗体小例子,希望刚学VB的朋友们参考学习。
  • 一个增强型VB文件浏览对话框窗口,增强对话框,支持左端自定义图片、支持自定义窗口顶端图片,支持声音预览、常规对话框(默认不使用回调),测试时,您可选择一个对话框样式,单击[打开]按钮。示例中还演示了调用打开...
  • 打开系统的“浏览文件对话框,很多人都用控件,这固然很好,但如果用VB自身编程去实现岂不是更好,这个源码就是用VB中的API...
  • VB API打开“浏览文件对话框的例子,使用自带的API来实现,在平时的软件开发中使用相当普遍的。  打开“浏览文件对话框,很多人都用控件实现,虽然省事,不过用VB自身编程去实现会让你的软件更绿色,更适合...
  • 内容索引:VB源码,界面编程,对话框 很漂亮的VB浏览文件对话框编程实例源码,用上这个,会使你的程序更美观,也更省事了。
  • 内容索引:VB源码,文件操作,文件属性,对话框 VB直接调用文件的属性对话框代码,点击窗口中的“Show Properites”按钮,会显示路径中指定文件的属性信息,功能类似于在文件上点击右键——>属性相似,有时候编写程序的...
  • 转自:http://blog.163.com/headmaster_01/blog/static/475568612011517376117/  VB6.0 浏览文件夹对话框 选择文件保存路径  2011-06-17 15:07:06| 分类: 文件选择对话框 |
    转自:
    http://blog.163.com/headmaster_01/blog/static/475568612011517376117/  
    

    VB6.0 浏览文件夹对话框 选择文件保存路径  

    2011-06-17 15:07:06|  分类: 文件选择对话框 |  标签: |字号 订阅

    第一步新建一个Modules,假设为Modulas1.bas
    把下面的复制到Module.bas中

    Public Const BIF_RETURNONLYFSDIRS = 1
    Public Const BIF_DONTGOBELOWDOMAIN = 2
    Public Declare Function SHBrowseForFolder Lib "shell32.dll" Alias "SHBrowseForFolderA" (LpBrowseInfo As BROWSEINFO) As Long
    Public Declare Function SHGetPathFromIDlist Lib "shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long
    Public Type BROWSEINFO
    hOwner As Long
    pidlroot As Long
    pszDisplayName As String
    lpszTitle As String
    ulFlags As Long
    lpfn As Long
    lparam As Long
    iImage As Long
    End Type
    Public Function GetFolder(ByVal hWnd As Long, Optional Title As String) As String
        Dim bi As BROWSEINFO
        Dim pidl As Long
        Dim folder As String
        folder = Space(255)
    With bi
       If IsNumeric(hWnd) Then .hOwner = hWnd
       .ulFlags = BIF_RETURNONLYFSDIRS
       .pidlroot = 0
       If Title <> "" Then
          .lpszTitle = Title & Chr$(0)
       Else
          .lpszTitle = "选择目录" & Chr$(0)
        End If
    End With

    pidl = SHBrowseForFolder(bi)
    If SHGetPathFromIDlist(ByVal pidl, ByVal folder) Then
        GetFolder = Left(folder, InStr(folder, Chr$(0)) - 1)
    Else
        GetFolder = ""
    End If
    End Function

    第二步:然后在你的窗体Form1中添加Command1的单击事件了
    Private Sub Command1_Click()
        Dim str
        str = GetFolder(Me.hWnd, "浏览文件夹")
        If str <> "" Then
            Combo1.Text = str
            Combo1.AddItem (str)
        End If
    End Sub

    GetFolder函数返回文件夹的路径,比如你选择了System32文件夹,单击确定后,返回"c:\System32"
    这样就实现了选择文件存储路径的问题了~

    展开全文
  • Vb2010 弹出对话框选择文件夹路径

    千次阅读 2012-12-31 11:12:19
    众所周知,在vb中如果是打开某一个文件的话,非常简单,使用CommonDialog组件即可轻松完成,但是他只能选择文件,之后或许选取的文件路径,而如果想要浏览文件夹,就没这么方便了。 这里介绍3个办法来实现文件夹...
    众所周知,在vb中如果是打开某一个文件的话,非常简单,使用CommonDialog组件即可轻松完成,但是他只能选择文件,之后或许选取的文件路径,而如果想要浏览文件夹,就没这么方便了。
    

    这里介绍3个办法来实现文件夹浏览。

    第一个非常简单,利用Shell对象
    程序代码 程序代码
    '引用Microsoft Shell Controls And Automation
    Dim ShellA As New Shell
    Private Sub Command1_Click()    '建立一个按钮对象                                                     
    Dim Shellb As Folder
    Set Shellb = ShellA.BrowseForFolder(0, "选择文件夹", 0)
    ShellA.Open b
    End Sub


    记得一定要引用Microsoft Shell Controls And Automation

    第二种方法,我们同样利用shell对象,但是加几个函数
    程序代码 程序代码
    '引用Microsoft Shell Controls And Automation
    Private shlShell As Shell32.Shell
    Private shlFolder As Shell32.Folder
    Private Const BIF_RETURNONLYFSDIRS = &H1
    Private Sub Command1_Click() '
        If shlShell Is Nothing Then
           Set shlShell = New Shell32.Shell
        End If
        Set shlFolder = shlShell.BrowseForFolder(Me.hWnd, "请选择文件夹", BIF_RETURNONLYFSDIRS)
        If Not shlFolder Is Nothing Then
           MsgBox shlFolder.Items.Item.Path  '测试
        End If
    End Sub


    上面2个方法的结果如图:
    点击放大图片

    第三个方法,是利用API来操作。
    程序代码 程序代码
    Private Const BIF_RETURNONLYFSDIRS = 1
    Private Const BIF_DONTGOBELOWDOMAIN = 2
    Private Const MAX_PATH = 260

    Private Declare Function SHBrowseForFolder Lib "Shell32" (lpbi As BrowseInfo) As Long
    Private Declare Function SHGetPathFromIDList Lib "Shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
    Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
    Private Type BrowseInfo
         hWndOwner As Long
         pIDLRoot As Long
         pszDisplayName As Long
         lpszTitle As Long
         ulFlags    As Long
         lpfnCallback     As Long
         lParam     As Long
         iImage     As Long
    End Type
    Private Sub Command1_Click()
         Dim lpIDList As Long
         Dim sBuffer As String
         Dim szTitle As String
         Dim tBrowseInfo As BrowseInfo
         szTitle = App.Path
         With tBrowseInfo
              .hWndOwner = Me.hWnd
              .lpszTitle = lstrcat(szTitle, "")
              .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN
         End With

         lpIDList = SHBrowseForFolder(tBrowseInfo)
         If (lpIDList) Then
              sBuffer = Space(MAX_PATH)
              SHGetPathFromIDList lpIDList, sBuffer
              sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
              MsgBox sBuffer
         End If
    End Sub


    如果希望对话框中有“新建文件夹”,那么就给.ulFlags 加上BIF_USENEWUI属性,BIF_RETURNONLYFSDIRS 的意思是仅仅返回文件夹。
    效果如图:
    点击放大图片

    同时我也打包2个完整的利用此API的代码,有意者请自己学习了。


    第4个方法。
    其实是第三个方法的改进,就是打开对话框后,自动定位到当前文件夹位置 。

    程序代码 程序代码
    'Objects:   Form1、Command1、Module1   
      'Form1:   
      Option   Explicit   
      Private   Const   BIF_RETURNONLYFSDIRS   =   1   
      Private   Const   BIF_DONTGOBELOWDOMAIN   =   2   
      Private   Const   MAX_PATH   =   260   
      Private   Declare   Function   SHBrowseForFolder   Lib   "shell32"   (lpbi   As   BrowseInfo)   As   Long   
      Private   Declare   Function   SHGetPathFromIDList   Lib   "shell32"   (ByVal   pidList   As   Long,   ByVal   lpBuffer   As   String)   As   Long   
      Private   Declare   Function   lstrcat   Lib   "kernel32"   Alias   "lstrcatA"   (ByVal   lpString1   As   String,   ByVal   lpString2   As   String)   As   Long   
      Private   Declare   Function   LocalAlloc   Lib   "kernel32"   (ByVal   uFlags   As   Long,   ByVal   uBytes   As   Long)   As   Long   
      Private   Declare   Sub   CopyMemory   Lib   "kernel32"   Alias   "RtlMoveMemory"   (pDest   As   Any,   pSource   As   Any,   ByVal   dwLength   As   Long)   
      Private   Const   LPTR   =   (&H0   or   &H40)   
      Private   Type   BrowseInfo   
                      hWndOwner             As   Long   
                      pIDLRoot             As   Long   
                      pszDisplayName   As   Long   
                      lpszTitle             As   Long   
                      ulFlags                 As   Long   
                      lpfnCallback     As   Long   
                      lParam                 As   Long   
                      iImage                 As   Long   
      End   Type   
      Private   Function   MyAddressOf(AddressOfX   As   Long)   As   Long   
      MyAddressOf   =   AddressOfX   
      End   Function   
        
      Private   Sub   Command1_Click()   
      Dim   lpIDList   As   Long   
      Dim   sBuffer   As   String   
      Dim   szTitle   As   String   
      Dim   tBrowseInfo   As   BrowseInfo   
      Dim   Ret   As   Long   
      szTitle   =   "This   is   the   title"   
      Dim   sPath   As   String   
      sPath   =   VBA.InputBox("初始路径:",   ,   "C:\program   files")   
      With   tBrowseInfo   
              .hWndOwner   =   Me.hWnd   
              .lpszTitle   =   lstrcat(szTitle,   "")   
              .ulFlags   =   BIF_RETURNONLYFSDIRS   +   BIF_DONTGOBELOWDOMAIN   
              .lpfnCallback   =   MyAddressOf(AddressOf   BrowseForFolders_CallbackProc)   
              Ret   =   LocalAlloc(LPTR,   VBA.Len(sPath)   +   1)   
              CopyMemory   ByVal   Ret,   ByVal   sPath,   VBA.Len(sPath)   +   1   
              .lParam   =   Ret   
      End   With   
      lpIDList   =   SHBrowseForFolder(tBrowseInfo)   
      If   (lpIDList)   Then   
          sBuffer   =   VBA.Space(MAX_PATH)   
          SHGetPathFromIDList   lpIDList,   sBuffer   
          sBuffer   =   VBA.Left(sBuffer,   VBA.InStr(sBuffer,   vbNullChar)   -   1)   
          MsgBox   sBuffer   
          End   If   
      End   Sub   
        
      'Module1:   
      Option   Explicit   
      Private   Declare   Function   SendMessage   Lib   "user32"   Alias   "SendMessageA"   (ByVal   hWnd   As   Long,   ByVal   wMsg   As   Long,   ByVal   wParam   As   Long,   lParam   As   Any)   As   Long   
      Private   Const   WM_USER   =   &H400   
      Private   Const   BFFM_SETSelectIONA   As   Long   =   (WM_USER   +   102)   
      Private   Const   BFFM_SETSelectIONW   As   Long   =   (WM_USER   +   103)   
      Private   Const   BFFM_INITIALIZED   As   Long   =   1   
      Public   Function   BrowseForFolders_CallbackProc(ByVal   hWnd   As   Long,   ByVal   uMsg   As   Long,   ByVal   lParam   As   Long,   ByVal   lpData   As   Long)   As   Long   
      If   uMsg   =   BFFM_INITIALIZED   Then   
          SendMessage   hWnd,   BFFM_SETSelectIONA,   True,   ByVal   lpData   
      End   If   
      End   Function


    效果如图:

    点击放大图片  

    看了这个代码后,你会发现它确实定位到了当前文件夹,但是他有一个问题就是,没有选定当前文件夹。咱们继续看方法5.

    第5个方法。
    他同样是第3个方法的加强版,不过这个方法应当是最为完美的方法,不仅定位到当前文件夹,而且选定它。
    建立一个模块文件

    程序代码 程序代码
    'form1
    ''Module1:   
    Option Explicit
    Private Const BIF_STATUSTEXT = &H4&
    Private Const BIF_RETURNONLYFSDIRS = 1
    Private Const BIF_DONTGOBELOWDOMAIN = 2
    Private Const MAX_PATH = 260

    Private Const WM_USER = &H400
    Private Const BFFM_INITIALIZED = 1
    Private Const BFFM_SELCHANGED = 2
    Private Const BFFM_SETSTATUSTEXT = (WM_USER + 100)
    Private Const BFFM_SETSelectION = (WM_USER + 102)

    Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
    Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
    Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
    Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long

    Private Type BrowseInfo
      hWndOwner      As Long
      pIDLRoot       As Long
      pszDisplayName As Long
      lpszTitle      As Long
      ulFlags        As Long
      lpfnCallback   As Long
      lParam         As Long
      iImage         As Long
    End Type

    Private m_CurrentDirectory As String   'The current directory
    Public Function BrowseForFolder(owner As Form, Title As String, StartDir As String) As String
      Dim lpIDList As Long
      Dim szTitle As String
      Dim sBuffer As String
      Dim tBrowseInfo As BrowseInfo
      m_CurrentDirectory = StartDir & vbNullChar

      szTitle = Title
      With tBrowseInfo
        .hWndOwner = owner.hWnd
        .lpszTitle = lstrcat(szTitle, "")
        .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN + BIF_STATUSTEXT
        .lpfnCallback = GetAddressofFunction(AddressOf BrowseCallbackProc)  'get address of function.
      End With

      lpIDList = SHBrowseForFolder(tBrowseInfo)
      If (lpIDList) Then
        sBuffer = Space(MAX_PATH)
        SHGetPathFromIDList lpIDList, sBuffer
        sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
        BrowseForFolder = sBuffer
      Else
        BrowseForFolder = ""
      End If
      
    End Function

    Private Function BrowseCallbackProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal lp As Long, ByVal pData As Long) As Long
        Dim lpIDList As Long
      Dim ret As Long
      Dim sBuffer As String  
      On Error Resume Next       
      Select Case uMsg  
        Case BFFM_INITIALIZED
          Call SendMessage(hWnd, BFFM_SETSelectION, 1, m_CurrentDirectory)      
        Case BFFM_SELCHANGED
          sBuffer = Space(MAX_PATH)
          
          ret = SHGetPathFromIDList(lp, sBuffer)
          If ret = 1 Then
            Call SendMessage(hWnd, BFFM_SETSTATUSTEXT, 0, sBuffer)
          End If      
      End Select  
      BrowseCallbackProc = 0  
    End Function
    Private Function GetAddressofFunction(add As Long) As Long
      GetAddressofFunction = add
    End Function


    建立一个窗口和一个按钮
    程序代码 程序代码
    Option Explicit
    Private getdir As String
    Private Sub Command1_Click()    
        getdir = BrowseForFolder(Me, "Select A Directory", Text1.Text)
        If Len(getdir) = 0 Then Exit Sub     Text1.Text = getdir    
    End Sub
    Private Sub Form_Load()
      Text1.Text = CurDir
    End Sub

    最终结果如图:
    点击放大图片

    上面是对vb中调用文件夹对话框的一个总结,个人认为第5个方法是最为完美的,这也是从国外坛子淘到的
    展开全文
  • VBS选择文件对话框

    2012-01-30 00:04:54
    VBS实现选择文件对话框。Set objDialog = CreateObject("UserAccounts.CommonDialog") objDialog.Filter = "All Files|*.*" objDialog.InitialDir = "C:\" intResult = objDialog.ShowOpen If intResult = 0 Then...
  • vb纯代码实现文件对话框,不再需要添加引用CommonDialog等
  • 免控件利用API获取选择的文件夹路径 以方便获取该文件夹下的文件处理
  • VB6.0 自定义对话框,自定义Dialog...成功之后你会发现,打开文件,文件夹对话框的控件 ,有新建文件夹按钮,还有其他的一些附加功能。里面用到了自定义的VB类库。代码中的注释是英文的,本对话框运行效果如图所示。
  • vb.net制作的简单的保存文件对话框,可以把自己想保存的东西保存到已制作的项目里面。
  • VC6.0要实现在对话框拖动不是很方便,先参考网络资料,实现文件拖动示例。 实现步骤详见压缩包中文档。附赠有相关代码制作的的文本文件分割合并工具。
  • VB打开浏览文件夹对话框 实现文件夹选取
  • 3.在VB中可以建立 菜单和 菜单...为了把通用对话框控件加到工具箱中应在工程菜单中选择部件命令弹出部件对话框在部件对话框的控件选项卡中选择 2.建立打开文件保存文件颜色字体和打印对话框所使用的方法分别为 Showopen
  • 弹出式文件夹浏览对话框。 一个模块,一个函数就可调用。
  • 文件选择对话框 | 标签: |字号大中小 订阅 第一步:新建一个Modules,假设为Modulas1.bas 把下面的复制到Module.bas中 Public Const BIF_RETURNONLYFSDIRS = 1 Public Const BIF_DONTGOBELOWDOMAIN = 2...

     

    2011-06-17 15:07:06|  分类: 文件选择对话框 |  标签: |字号大中小 订阅

    第一步新建一个Modules,假设为Modulas1.bas
    把下面的复制到Module.bas中

    Public Const BIF_RETURNONLYFSDIRS = 1
    Public Const BIF_DONTGOBELOWDOMAIN = 2
    Public Declare Function SHBrowseForFolder Lib "shell32.dll" Alias "SHBrowseForFolderA" (LpBrowseInfo As BROWSEINFO) As Long
    Public Declare Function SHGetPathFromIDlist Lib "shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long
    Public Type BROWSEINFO
    hOwner As Long
    pidlroot As Long
    pszDisplayName As String
    lpszTitle As String
    ulFlags As Long
    lpfn As Long
    lparam As Long
    iImage As Long
    End Type
    Public Function GetFolder(ByVal hWnd As Long, Optional Title As String) As String
        Dim bi As BROWSEINFO
        Dim pidl As Long
        Dim folder As String
        folder = Space(255)
    With bi
       If IsNumeric(hWnd) Then .hOwner = hWnd
       .ulFlags = BIF_RETURNONLYFSDIRS
       .pidlroot = 0
       If Title <> "" Then
          .lpszTitle = Title & Chr$(0)
       Else
          .lpszTitle = "选择目录" & Chr$(0)
        End If
    End With

    pidl = SHBrowseForFolder(bi)
    If SHGetPathFromIDlist(ByVal pidl, ByVal folder) Then
        GetFolder = Left(folder, InStr(folder, Chr$(0)) - 1)
    Else
        GetFolder = ""
    End If
    End Function

    第二步:然后在你的窗体Form1中添加Command1的单击事件了
    Private Sub Command1_Click()
        Dim str
        str = GetFolder(Me.hWnd, "浏览文件夹")
        If str <> "" Then
            Combo1.Text = str
            Combo1.AddItem (str)
        End If
    End Sub

    GetFolder函数返回文件夹的路径,比如你选择了System32文件夹,单击确定后,返回"c:\System32"
    这样就实现了选择文件存储路径的问题了~

     

     

     

    vb保存excel

    vb中另存为是这个:objWorkBook.SaveAs ("c:\001.xls")
    想每次保存都自动重命名,如下次是002.xls,而不是覆盖以前的,
    或者弹出一个重命名对话框也可以,我看了半天不会,希望高手解决!
    代码说的详细点,少了我看不懂,哈哈
     
    答:
    我这个保证你测试通过。你按我的做:新建一个Excel,保存他到桌面(当然只需要保存这一次,以后就是自动的啦),文件名就是1.xls,在这个文件里,建一个按钮,叫做CommandButton1。他的代码是:
    Private Sub CommandButton1_Click()
    ActiveWorkbook.SaveAs ActiveWorkbook.Path & "\" & CStr(Val(Replace(ActiveWorkbook.FullName, ActiveWorkbook.Path & "\", "")) + 1) & ".xls"
    End Sub
    这样,你每次单击,就会在那个路径(也就是桌面,当然你可以第一次保存的时候选择别的路径,那么以后自动保存的时候就在那个路径)自动生成2.xls,3.xls…………我测试通过的。
    ==================
    当然,你的原意肯定是不要按钮的,我这里只是提供一下测试,让你能够清晰的看到效果,你把我这个代码的核心
    ActiveWorkbook.SaveAs ActiveWorkbook.Path & "\" & CStr(Val(Replace(ActiveWorkbook.FullName, ActiveWorkbook.Path & "\", "")) + 1) & ".xls"
    相应的弄到你的代码里,就OK了。
    展开全文
  • VB.Net - 对话框

    2018-03-01 09:53:52
    VB.Net - 对话框有许多内置的对话框,用于Windows窗体中的各种任务,例如打开和保存文件,打印页面,向应用程序的用户提供颜色,字体,页面设置等选择。 这些内置的对话框减少了开发人员的时间和工作量。所有这些...

    VB.Net - 对话框


    有许多内置的对话框,用于Windows窗体中的各种任务,例如打开和保存文件,打印页面,向应用程序的用户提供颜色,字体,页面设置等选择。 这些内置的对话框减少了开发人员的时间和工作量。

    所有这些对话框控件类继承自CommonDialog类,并覆盖基类的RunDialog()函数以创建特定对话框。

    当对话框的用户调用其ShowDialog()函数时,将自动调用RunDialog()函数。

    ShowDialog方法用于在运行时显示所有对话框控件。 它返回一个DialogResult枚举类型的值。 DialogResult枚举的值为:

    • Abort 中止 - returns DialogResult.Abort value, when user clicks an Abort button.  当用户单击“中止”按钮时,返回DialogResult.Abort值。

    • Cancel 取消 -returns DialogResult.Cancel, when user clicks a Cancel button.  当用户单击Ignore按钮时,返回DialogResult.Ignore。

    • Ignore 忽略 -returns DialogResult.Ignore, when user clicks an Ignore button.  返回DialogResult.No,当用户单击否按钮。

    • No  -returns DialogResult.No, when user clicks a No button.  不返回任何内容,对话框继续运行。

    • None  -returns nothing and the dialog box continues running.  返回DialogResult.OK,当用户单击确定按钮

    • OK -returns DialogResult.OK, when user clicks an OK button.  返回DialogResult.  OK,当用户点击OK键

    • Retry 重试 -returns DialogResult.Retry , when user clicks an Retry button.  当用户单击重试按钮时,返回DialogResult.Retry

    • Yes  -returns DialogResult.Yes, when user clicks an Yes button.  返回DialogResult.Yes,当用户单击是按钮


    下图显示了通用对话框类继承:


    VB.Net对话框

    上述 所有 相应 控件,可以在设计期间从工具箱中添加。 您可以通过以编程方式实例化类或通过使用相关控件,将这些类的相关功能包括到应用程序中。

    当双击工具箱中的任何对话框控件或将控件拖动到窗体上时,它将显示在Windows窗体设计器底部的组件托盘中,但不会直接显示在窗体上。

    下表列出了常用的对话框控件。 点击以下链接查看其详细信息:

     
    S.N.控制& 说明
    1

    ColorDialog

    It represents a common dialog box that displays available colors along with controls that enable the user to define custom colors.

    它表示一个公共对话框,显示可用颜色以及允许用户定义自定义颜色的控件。

    2

    FontDialog

    It prompts the user to choose a font from among those installed on the local computer and lets the user select the font, font size, and color.

    它提示用户从安装在本地计算机上的字体中选择字体,并让用户选择字体,字体大小和颜色。

    3

    OpenFileDialog

    It prompts the user to open a file and allows the user to select a file to open.

    它提示用户打开文件,并允许用户选择要打开的文件。

    4

    SaveFileDialog

    It prompts the user to select a location for saving a file and allows the user to specify the name of the file to save data.

    它提示用户选择保存文件的位置,并允许用户指定保存数据的文件的名称。

    5

    PrintDialog

    It lets the user to print documents by selecting a printer and choosing which sections of the document to print from a Windows Forms application.

    它允许用户通过选择打印机并从Windows窗体应用程序中选择要打印的文档的哪些部分来打印文档。

    展开全文
  • 通用打开文件对话框,可以多选文件。一个模块搞定!
  • VB打开对话框ShowOpen

    2021-01-07 20:40:29
    在工具箱空白处右键,选择“部件“,进入控件选择界面。 找到Microsoft Common Dialog Control 6.0(SP6),在其复选框打勾,然后单击确定按钮。即可将此控件添加到工具箱。 少部分电脑如果不能成功添加,那么是因为...
  • 在窗体中画一个Text1输入框和一个Command1按钮,代码如下: Option ...Click() Dim WJJurl As String WJJurl = GetFolderName(Me.hwnd, “在以下选择一个文件夹”) If WJJurl <> “” Then Text1.Text = WJJurl End Sub
  • vb编写实现浏览文件夹对话框,实现比较简单,运用到了SHBrowseForFolder和SHGetPathFromIDList两个API函数,希望对你有用。

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 21,122
精华内容 8,448
关键字:

vb文件选择对话框