大家都很熟悉Excel电子表格了，可是很少有人研究过，工作薄到底有多少个工作表，每个工作表到底有多少个行和列。

　　下面，就针对这个最基本的问题，给大家诠释一下有关的知识

　　①工作薄中的工作表

　　就目前而言，一个工作薄，最多能包含255个工作表。

　　也就是说，每个工作薄，即每个Exccel文件，最多只能包含255个工作表。

　　工作表的名称一般采用Sheet1、Sheet2、Sheet3……来命名，当然，你完全可以修改这些工作表的名称。

　　②工作表中的行数量与列数量

　　行的最大数量为：65536

　　列的最大数量为：256

　　如上数据是Excel2003及之前的最大行列数，如果版本再高点，比如，Excel2007至Excel2012等，所包含的最大行数就为1048576(2^20)行；最大列数则为16384(2^14)列。

　　行的名称，使用数字：1，2，3，4，5，6……65536来表示，数字为多少就是多少行；而列使用字母A，B，C，D……AA—AZ，BA—BZ，……，IA—IV来表示。

　　而我们平时面对得更多的是工作表中的格子，说得专业点，就是单元格。

　　每个单元格，是由每行和每列交叉形成的。因此，每个单元格的名称，是由列名＋行号来组成的。

　　比如，A1，指的是A列中的第一行。再比如，Z99，指的是Z列中的第99行，其它依此类推。

　　最后，比如，Excel2003，每个工作表的单元格个数是256?65536，一般仅使用少数的格子就能解决工作问题了，很少遇到全部使用完256?65536个格子的情况。当然，如果有需求使用比这个更多的格子，那么，Excel就无法解决这样的问题了，就应该使用数据库软件ACCESS、VFP、MS SQL……来保存数据了。因为Excel只是个轻量级的“数据库”。

在Excel中创建默认的工作簿工作表模板sheet.xlt和book.xlt




　　在Excel 2003中可以保存的默认设置相当少，只有“工具→选项”中的小部分设置可以被保存下来，对于最常用的页眉页脚、打印页边距、单元格格式设置等等就无能为力了。其实修改一下Excel的默认模板同样可以将它们保存为默认设置，不过和Word不一样的是，Excel本来并没有设置默认模板，我们得自己动手帮它建两个。


一、创建默认工作簿模板


　　1.打开Excel 2003，把三个工作表分别重命名为:工作表(1)、工作表(2)、工作表(3)。


　　2.按住Ctrl键逐一单击工作表标签，选中这三个工作表，按我们的需要进行页面设置、修改“工具→选项”中的项目以及各单元格的格式等等，还可以录制一些常用的宏。在此按Ctrl键全选是为了对三个工作表做相同设置，当然你也可以对三个工作表逐一进行不同的设置。


　　注意:请不要在表格中随便输入文字，这些内容将会直接出现在以后新建的工作簿中。


　　3.点击“文件→另存为”，在“保存类型”中选择“模板(*.xlt)”，输入模板的文件名为 book.xlt，“保存位置”则选择“C:\Program Files\Microsoft Office\Office11\XLStart”。这是默认安装时的位置，如果你不是按默认路径安装，请做相应修改。


　　现在再重新打开Excel，你会发现新建的工作簿已经保存了我们在 book.xlt 中做的全部修改设置，当然你可以随时修改 book.xlt 文件中的设置来改变默认设置。此外，在设置默认工作簿后，“工具→选项”中的“新工作簿内的工作表数”设置将会失效，你只能通过修改 book.xlt 中的工作表个数来改变。


二、创建默认工作表模板


　　经过上面设置后新建的工作簿确实已保存了我们的设置，但是当我们单击“插入→工作表”的时候，新插入的工作表却还是保持最原始的未设置状态，我们还得再设置一个默认的工作表模板才行。


　　新建一个工作簿，删除工作表(2)、(3)，只保留下工作表(1)。同样另存为“模板(*.xlt)”类型，保存在“C:\Program Files\Microsoft Office\Office11\XLStart”中，不过模板的文件名则改为 sheet.xlt。


　　现在再插入工作表，它的格式设置就和我们的设置一样了。在此如果你在 sheet.xlt 中保留了两张工作表，则选择插入工作表时就会一次插入两张，以此类推。以后如果需要修改插入新工作表的设置，只要对 sheet.xlt 进行修改并保存就OK了。


　　该方法不仅可以把页面设置、自定义工具栏、宏、超链接和窗体上的 ActiveX 控件等默认设置彻底改变，甚至连打印区域设置、单元格格式设置、数据有效性设置、工作表和行列的隐藏保护乃至工作表中输入的文字、公式、图片、背景等等都可以直接作为默认设置保存下来。只要用该方法我们完全可以按自己的使用习惯定制出一套适合自己使用的Excel。


　　注意：自定义的工具栏必须在保存前将它附加到 book.xlt 模板上才能使用。右击工具栏选择“自定义”，在“工具栏”选项卡中单击“附加”按钮，在“自定义工具栏”列表中选中要附加的工具栏，单击“复制”按钮即可。





转载来自于：http://blog.excelhome.net/user1/fanjy/archives/2006/703.html


[禅语]无迹可寻
僧人问郢州芭蕉山山圆禅师道：“没神通的菩萨应该是有形有相的，我怎么却找不到他的踪迹呢？”
“同道方知。”山圆禅师答道，“只有你也达到同样的境界，才能真正明白那种境界的种种现象。要不然，即使讲了，你也不会懂的。”
僧人问道：“即然同道方知，禅师您知道吗？”
“不知道。”山圆禅师直截了当地回答。
僧人仍没有领悟，继续问道：“为什么您不知道啊？”
“不是诗人不谈诗。”山圆禅师摇摇头，“你根本听不懂我的话。”
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
上面的故事有何禅机呢？有一些成功你看不到，是因为你的目光太过短浅。有一些道理你不明白，是因为你的知识太过浅陋。
学习也是这样，光读书而不实践，只看到表面现象而不深入研究，是不会熟练运用的，当出现问题时也会不知所措。
那么，现在让我们看看在Excel工作表中如何找到最后一行吧。
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
引子
在日常生活中，我们经常会遇到这样一些情况。譬如，中午在食堂买饭时，由于人很多，排的队很长，于是，在最后的两位干脆不排了，坐在旁边的椅子上等着别人买完饭后或队伍中的人少了后再排在后面，这时，如果再来了一个人，那么他的位置就应该是在那两个人之后，虽然那两个人并未排在队伍中，可能刚来的那个人不知道他前面还有两个人，排在了队伍的最后。又如，学校组织全校学生出去郊游，按班级排队前进且各班按到达的先后顺序排队，此时，若校长想找最后一个人，他必须指定是那个班级的最后一个人或整个队伍的最后一个人；或者，此时1班的一个同学到了，他应该自觉地排在他们班的队伍的最后一位。……
在Excel中，也有类似情形。例如，如果想在工作表的最后一行输入数据，则必须先找到最后一行的位置，而在有些情况下，已输入的数据中可能有隐藏的行，也可能最后一行的数据没有显示，此时，该如何有效的找到最后一行呢？又如，如果想找到最后一个公式所在的行，又该如何查找？还有一些情况，比如，在第一行和最后一行之间存在着空行；各列的最后一行不相同，在工作表无数据区域中虽没有数据但已设置了格式……等等。
当然，在Excel中，有许多可以用来查找最后一行的方法，比如end(xlUp)属性、UsedRange属性、CurrentRegion属性、SpecialCells方法、以及Find方法等，这些方法可以在不同的情形下使用。但正如前面所讲述的，关键是要清楚Excel将“已使用范围”、“当前区域”、和一些常量如xlCellTypeLastCell在工作表中代表什么区域，以及您是在什么情形下查找最后一行，然后选用合适的方法，以确保找到正确的最后一行，否则，可能所找到的并不是您所想要的最后一行。
“最后一行”可能的情形
在查找最后一行时，可能是查找以下情形单元格所在的“最后一行”，即：
(1)  含有公式的单元格
(2)  格式化的单元格
(3)  含有颜色的单元格
(4)  包含数据有效性的单元格
(5)  包含批注的单元格
(6)  直接输入数据(文本和/或数字)的单元格
(7)  由公式生成数据(文本和/或数字)的单元格
(8)  直接输入数据(文本和/或数字)或者由公式生成数据(文本和/或数字)的单元格
(9)  直接输入数字的单元格
(10) 由公式生成数字的单元格
(11) 直接输入数字或由公式生成数字的单元格
(12) 直接输入文本的单元格
(13) 由公式生成文本的单元格
(14) 直接输入文本或由公式生成文本的单元格
(15) 其它情形
(16) 包含上述所有情形的单元格
此外，还需要考虑工作表中的最后一行是否被隐藏了，而哪些方法忽略隐藏的行？最后一行的单元格中的数据是否显示？这些都会影响到您是否能查找到正确的最后一行。
下面，我们来讨论查找最后一行的方法以及可能出现的一些情况。

找到最后一行的一些方法探讨
使用End属性
在ExcelVBA中，使用End(xlUp)查找最后一行是最常使用且最为简单的方法，它假设要有一列总包含有数据(数字、文本和公式等)，并且在该列中最后输入数据的单元格的下一行不会包含数据，因此不必担心会覆盖掉已有数据。但该方法有两个缺点：
(1) 仅局限于查找指定列的最后一行。
(2) 如果该列中最后一行被隐藏，那么该隐藏行将被视作最后一行。因此，在最后一行被隐藏时，其数据可能会被覆盖。但该列中间的隐藏行不会影响查找的结果。
[示例代码01]
Sub EndxlUp_OneColLastRow()
  If Range("A" & Rows.Count).End(xlUp) = Empty Then GoTo Finish
  '获取最后一行
  MsgBox "最后一行是第" & Range("A" & Rows.Count).End(xlUp).Row & “行.”
  Exit Sub
Finish:
  MsgBox "没有发现公式或数据! "
End Sub
[示例代码02]
Sub NextRowInColumnUsedAsSub()
'包含所有数据和公式，忽略隐藏的最后一行
  Range("A" & Range("A" & Rows.Count).End(xlUp).Row + 1).Select
End Sub
[示例代码03]
Sub NextRowInColumnUsedAsFunction()
'包含所有数据和公式，忽略隐藏的最后一行
  Range("A" & LastRowInColumn("A") + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - - - 
Public Function LastRowInColumn(Column As String) As Long
     LastRowInColumn = Range(Column & Rows.Count).End(xlUp).Row
End Function
注意，要输入新数据的列可能与我们所查找最后一行时所使用的列不同，例如，在上例中，我们可以修改为在B列中查找该列的最后一行，而在A列相应行的下一行中输入新的数据。
使用Find方法
Find方法在当前工作有数据中进行查找，不需要指定列，也可以确保不会意外地覆盖掉已有数据。其中，参数LookIn指定所查找的类型，有三个常量可供选择，即xlValues、xlFormulas和xlComments。
(1) 常量xlFormulas将包含零值的单元格作为有数据的单元格。(当设置零值不显示时，该单元格看起来为空，但该参数仍将该单元格视为有数据的单元格)
(2) 常量xlValues将包含零值的单元格(如果设置零值不显示时)作为空白单元格，此时，若该单元格在最后一行，则Find方法会认为该单元格所在的行为空行，因此，该单元格中的内容可能会被新数据所覆盖。
[注：在Excel中，选择菜单“工具”——“选项”，在打开的“选项”对话框中，选择“视图”选项卡，将其中的“零值”前的复选框取消选中，则工作表中的零值都不会显示]
如果在参数LookIn中使用常量xlValues的话，还存在一个问题是：如果您将最后一行隐藏，则Find方法会认为倒数第二行是最后一行，此时您在最后一行的下一行输入数据，则会将实际的最后一行的数据覆盖。
您可以在隐藏最后一行与不隐藏最后一行，或者是最后一行显示零值与不显示零值时，运行下面的示例代码04，看看所得的结果有什么不同。
[示例代码04]
Sub Find_LastRowxlValues()
   On Error GoTo Finish
   '获取最后一行
   MsgBox "最后一行是第" & Cells.Find("*", _
   SearchOrder:=xlByRows, LookIn:=xlValues, _
   SearchDirection:=xlPrevious).EntireRow.Row & “行”
   Exit Sub
Finish:
   MsgBox "没有发现数值！"
End Sub
因此，在使用Find方法时，您应该考虑所选参数设置的常量，以及工作表最后一行是否有可能被隐藏或不显示零值。如果您忽视这些情况，很可能得不到您想要的结果，或者是覆盖掉已有数据。使用常量xlFormulas可以避免这个问题，如下面的示例代码05所示。
[示例代码05]
Sub Find_LastRowxlFormulas()
   On Error GoTo Finish
   '获取最后一行
   MsgBox "最后一行是第" & Cells.Find("*", _
   SearchOrder:=xlByRows, LookIn:=xlFormulas, _
   SearchDirection:=xlPrevious).EntireRow.Row & “行”
   Exit Sub
Finish:
   MsgBox "没发现数值或公式！"
End Sub
下面再列举几个示例代码。
[示例代码06]
Sub NextRowUsedAsSub()
'选取最后一行的下一行
  Range("A" & Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row + 1).Select
End Sub
[示例代码07]
Sub NextRowUsedAsFunction()
'选取最后一行的下一行(调用函数)
  Range("A" & LastRow + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - - - 
Public Function LastRow() As Long
'本代码包含隐藏行
'使用常量xlFormulas，因为常量xlValues会忽略隐藏的最后一行
  LastRow = Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row
End Function
注：Find方法中，参数LookIn的默认值为xlFormulas。
使用SpecialCells方法
SpecialCells方法用于查找指定类型的值，其语法为SpecialCells(Type,Value)，有两种主要的使用方式：
(1) 若参数Type仅考虑常量，则在查找时会忽略和覆盖由公式生成的任何数据，如示例代码08所示。
(2) 若参数Type仅考虑由公式生成的数据，则在查找时会忽略和覆盖任何常量数据，如示例代码09所示。
如果参数Type是xlCellTypeConstants或者是xlCellTypeFormulas，则Value参数可使用常量决定哪种类型的单元格将被包含在结果中，这些常量值能组合而返回多个类型，其缺省设置是选择所有的常量或公式，而不管是何类型，可使用下面四个可选的常量：
1) xlTextValues(包含文本);     2) xlNumbers(包含数字);
3) xlErrors(包含错误值);       4) xlLogical(包含逻辑值)
自已在工作表输入一些含有数值和公式的数据，隐藏或不隐藏最后一行或公式所在的行，先体验下面的两段示例代码。
[示例代码08]
'当最后一行为公式或隐藏了最后行时，会忽略，即认为倒数第二行为最后一行
Sub NextConstantRowFunction()
     Range("A" & LastConstantRow(True, True, True, True) + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - - 
Public Function LastConstantRow(Optional IncludeText As Boolean, _
                               Optional IncludeNumbers As Boolean, _
                               Optional IncludeErrors As Boolean, _
                               Optional IncludeLogicals As Boolean) As Long
   Dim Text As Long, Numbers As Long, Errors As Long
   Dim Logical As Long, AllTypes As Long
   If IncludeText Then Text = xlTextValues Else Text = 0
   If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
   If IncludeErrors Then Errors = xlErrors Else Errors = 0
   If IncludeLogicals Then Logical = xlLogical Else Logical = 0
   AllTypes = Text + Numbers + Errors + Logical
   On Error GoTo Finish
   LastConstantRow = Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$") _
       (UBound(Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$")))
     Exit Function
Finish:
     MsgBox "没有发现数据！"
End Function
[示例代码09]
'查找含有公式的单元格所在的行，忽略该行以后的常量和隐藏的行
Sub NextFormulaRowFunction()
     Range("A" & LastFormulaRow(True, True, True, True) + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - 
Public Function LastFormulaRow(Optional IncludeText As Boolean, _
                               Optional IncludeNumbers As Boolean, _
                               Optional IncludeErrors As Boolean, _
                               Optional IncludeLogicals As Boolean) As Long
  Dim Text As Long, Numbers As Long, Errors As Long
  Dim Logical As Long, AllTypes As Long
  If IncludeText Then Text = xlTextValues Else Text = 0
  If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
  If IncludeErrors Then Errors = xlErrors Else Errors = 0
  If IncludeLogicals Then Logical = xlLogical Else Logical = 0
  AllTypes = Text + Numbers + Errors + Logical
  On Error GoTo Finish
  LastFormulaRow = Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$") _
      (UBound(Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$")))
  Exit Function
Finish:
  MsgBox "没有发现数据！"
End Function
下面的示例代码10忽略最后一行带有公式的单元格，即当最后一行的单元格中含有公式时，将倒数第二行作为最后一行，即只考虑直接输入到工作表中的数据。当最后一行没有公式但被隐藏时，并不影响该方法的判断。
[示例代码10]
Sub SpecialCells_LastRowxlCellTypeConstants()
   Dim MyRow As Range
   On Error GoTo Finish
   Set MyRow = Intersect([A:A], Cells. _
   SpecialCells(xlCellTypeConstants).EntireRow).EntireRow
  '获取最后一行
   MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
   (UBound(Split(MyRow.Address, "$"))) & “行”
   Set MyRow = Nothing
   Exit Sub
Finish:
   MsgBox "没有发现数据！"
End Sub
注：因为上述代码使用了’Split’函数，故只适合于Office2000及以上的版本。
该方法也允许我们指定单个数据类型，诸如数字数据或文本数据，如下所示。
下面，我们查找的最后一行是仅在行中有数字(而不包含公式)的单元格的最后一行。
[示例代码11]
Sub SpecialCells_LastRowxlCellTypeNumberConstants()
   Dim MyRow As Range
   On Error GoTo Finish
   Set MyRow = Intersect([A:A], Cells. _
   SpecialCells(xlCellTypeConstants, xlNumbers).EntireRow)
   '获取最后一行
   MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
   (UBound(Split(MyRow.Address, "$"))) & “行”
   Set MyRow = Nothing
   Exit Sub
Finish:
   MsgBox "没有发现数据！"
End Sub
下面，我们查找的最后一行是仅在行中有文本(而不包含公式)的单元格的最后一行。
[示例代码12]
Sub SpecialCells_LastRowxlCellTypeTextConstants()
   Dim MyRow As Range
   On Error GoTo Finish
   Set MyRow = Intersect([A:A], Cells. _
   SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow)
  '获取最后一行
   MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
   (UBound(Split(MyRow.Address, "$"))) & “行”
   Set MyRow = Nothing
   Exit Sub
Finish:
   MsgBox "没有发现数据！"
End Sub
下面，我们查找的最后一行是仅在行中有公式的单元格的最后一行。
[示例代码13]
Sub SpecialCells_LastRowxlCellTypeFormulas()
   Dim MyRow As Range
   On Error GoTo Finish
   Set MyRow = Intersect([A:A], Cells. _
   SpecialCells(xlCellTypeFormulas).EntireRow).EntireRow
  '获取最后一行
   MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
   (UBound(Split(MyRow.Address, "$"))) & “行”
   Set MyRow = Nothing
   Exit Sub
Finish:
   MsgBox "没有发现数据！"
End Sub
同上面所讲述的一样，我们也能使用SpecailCells方法去找到其它特定类型的单元格所在的最后一行，下面是这些常量的一个完整的列表：
XlCellTypeAllFormatConditions (任何格式的单元格)
XlCellTypeAllValidation (带有数据有效性的单元格)
XlCellTypeBlanks (所使用区域中的空白单元格)
XlCellTypeComments (包含有批注的单元格)
XlCellTypeConstants (包含有常量的单元格)
XlCellTypeFormulas (包含有公式的单元格)
XlCellTypeLastCell (已使用区域中的最后一个单元格(看下面))
XlCellTypeSameFormatConditions (有相同格式的单元格)
XlCellTypeSameValidation (有相同数据有效性条件的单元格)
XlCellTypeVisible (工作表中所有可见的单元格)
使用UsedRange属性(及SpecialCells方法)
UsedRange方法可用于在工作表中已使用区域查找最后一行，该区域包括可能以前使用过的任何单元格，但现在其中的数据被删除了，比如目前的工作表中只有第1行至第5行共5行，其它行都无数据，但在第6行中有些单元格以前使用过(可能仅仅格式化或内容清除了，总之该行现在不含有数据)，那么第6行也包含在该已使用的区域中。此外，如果最后一行被隐藏，那么会将因此，使用该方法查找最后一行是无规律且不可靠的，它通常可能会得到预料不到的结果。
有时，与UsedRange属性相似的技术也能用SpecialCells方法实现，其常量xlCellTypeLastCell代表在”已使用区域”中的最后一个单元格，与UsedRange属性稍有不同的是，当您在最后一行中输入数据后，又将其删除，则此数据所在的单元格也包含在已使用的区域中，并且如果最后的行被隐藏，则将可见行的最后一行当作最后一行。下面有两段代码您可以在工作表中进行调试，看看其特点。
[示例代码14]
Sub NextUsedRowSub()
' 选取可见的最后一行的下一行
  Range("A" & Cells.SpecialCells(xlCellTypeLastCell).Row + 1).Select
End Sub
[示例代码15]
Sub NextUsedRowFunction()
  Range("A" & LastUsedRow + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - 
Public Function LastUsedRow() As Long
  LastUsedRow = Cells.SpecialCells(xlCellTypeLastCell).Row
End Function
使用这里介绍的两种技术时，您一定要清楚工作表当前的状态，以找到正确的最后一行。
使用CurrentRegion属性
CurrentRegion属性返回代表单元格所在的当前区域，即四周有空行的独立区域，因此，可使用此属性查找当前区域的最后一行。但是使用其查找最后一行的一个缺点是，必须首先选取当前区域，然后进行查找。
小结
正如开始所讲述的一样，使用各种方法来查找最后一行都有其优缺点，并且都能找到您想要的最后一行，关键是您要了解各种方法的特性，以及工作表的状态，以便于选择所使用的方法来找到您需要的最后一行。
上述内容可能有不准确的地方，也可能有遗漏之处，您也可以在调试中体会和改进。


By fanjy in 2006-11-2

在博文 VBA添加工作表详解 中为大家讲了如何使用一句代码在指定位置插快速入指定名称的工作表。但是如果工作簿中已经存在同名工作表，那么运行时错误’1004‘就不期而遇的跳了出来。 


老规则 —— 先删除再创建，删除工作表很简单嘛，Sheets(..).Delete一句代码搞定。怎么又弹出一个消息窗口，Excel的产品经理考虑过宝宝们的用户体验吗！？删除工作表也搞得这么复杂，又不是从银行账户里转走500万。 


每次都这么麻烦，必须拿出VBA来搞定它了。



Sub DelSheet(vShtName, Optional sWkName As String)
    Dim sName
    With Application
        .DisplayAlerts = False
        On Error Resume Next
        If Len(sWkName) > 0 Then
            Set objWk = ActiveWorkbook
        Else
            Set objWk = Workbooks(sWkName)
        End If
        If VBA.IsArray(vShtName) Then
            For Each sName In vShtName
                objWk.Sheets(sName).Delete
            Next
        Else
            objWk.Sheets(sShtName).Delete
        End If
        On Error GoTo 0
        .DisplayAlerts = True
    End With
End Sub

这个事儿整的似乎有点儿大，一句代码怎么被扩展成了20多行。莫急，俗话说工欲善其事，必先利其器，以后调用起来就so easy。

Sub Demo()
    '删除单个工作表
    DelSheet Array("sheet1")
    '删除多个工作表，并指定工作簿
    DelSheet Array("sheet3", "sheet4"), "MyData.xlsx"
End Sub

无论是当前工作簿还是其他工作簿，即可以删除单个工作表，又可以删除一组工作表，随心所欲一句代码就搞定。