在windows里面用命令搜索哪个文件里包含了所需要查找的字符串

场景：有时，由于各种原因，我们可能需要查找windows系统下哪些配置文件里面还有某些字符串，比如我们想知道连接数据库的配置文件是什么，我们就可以按ip来搜索，看哪些文件里面含有该ip。

	



cd E:\PhoneService\PhoneService\

		findstr /R/N/s "10.72.32.111" *  

	

		

输出结果为：

backup_20140827_Web.config:9:    10.72.32.111\SQLEXPRESS,2021;Initial Catalog=HKQDC;User ID=xxx;Password=

xxxxx"/>

Web.config:9:    10.72.3
 2.111\SQLEXPRESS,3434;Initial Catalog=HKQDC;User ID=xxxx;Password=xxxxxxxx"/>

			




	

		注释：上面表示，在E:\PhoneService\PhoneService\目录及其下面的子目录下，搜寻含有10.72.32.111字样的文件。 
	
	

		10.72.32.111是要搜索的字符串，不用*做匹配自动就匹配所有含有该字符的文件。


看到我的backup_20140827_Web.config和Web.config文件里面还有10.72.32.111字符串。




 /R        将搜索字符串作为一般表达式使用。

 /S        在当前目录和所有子目录中搜索匹配文件。

 /N        在匹配的每行前打印行数。

                    

                                                    来自 “ ITPUB博客 ” ，链接：http://blog.itpub.net/28916011/viewspace-1399963/，如需转载，请注明出处，否则将追究法律责任。
                                            

                
转载于:http://blog.itpub.net/28916011/viewspace-1399963/

虽然，在WINDOWS系统中，可以直接使用文件查找对话框进行文件查找。然而查找的结果无法与命令行方式交互。我们知道，批处理的优点在于自动性，即一旦启动后，可以无需人工干预，按一系列流程走下去。这与WINDOWS本身的设计思想是不同的。


WINDOWS的核心，就在于它对用户的操作不做任何假定。所以通常Windows程序启动之后，总是在等待用户输入，没有用户输入，WINDOWS程序什么也不做。对于某些应用，WINDOWS应用程序在这方面的优势反而会变成劣势。比如说，配置IP地址，按WINDOWS程序，我们常常需要通过多次点击，键盘输入，才能完成一次配置。而通过配置文件，我们不需要人工干预即可完成此功能。对于后面的应用方式，正是批处理等脚本程序所擅长的事情。


基于上面的认识，我们知道，WINDOWS下面的文件查找应用，有时候是不能满足要求的。那么我们在命令行方式下通过“dir test.file /s”这样的方式查找文件，是否就能充分满足我们的要求呢？答案是否定的。因为 DIR 这个命令，要么只能显示一个目录下面的所有文件列表，要么在一个目录下面搜索一个指定了文件名的文件。我们知道在一个系统中，比如一个编译器，可能在本机存储了两个同名的文件。虽然它们的大小时间都相同，但安装的和不安装的系统环境是不一样的。所以我们可能要寻求一个符合特定目录结构的文件，来确定一个应用程序究竟被安装在了哪里。这一点，正是本例所要介绍的应用。代码如下（假设批处理的文件名为batFind.bat）：

@rem =========================================================================

@rem 功能

@rem     在所有的硬盘驱动器上查找目标文件, 并打印出第一个匹配文件所在路径

@rem 语法

@rem     batfind toSearchFile fileTime1 fileTime2 [dirDepth]

@rem 参数

@rem     toSearchFile - 待搜索文件, 可以包含前置子目录

@rem     fileTime1 - 目标文件上次修改的最早时间, 必须是yyyy-mm-dd格式

@rem     fileTime2 - 目标文件上次修改的最晚时间, 必须是yyyy-mm-dd格式

@rem     dirDepth - 搜索的目录深度, 0为根目录, 不指定则所有深度

@rem 附注

@rem     可单独拷贝为一个批处理文件, 参数及用法仍如上所述

@rem 作者

@rem     笑十子@2007-8-23 10:40

@rem -------------------------------------------------------------------------

@echo off


@rem -------------------------------------------------------------------------

@rem 启用延时扩展, 这是搜索处理的需要

@rem -------------------------------------------------------------------------

setlocal ENABLEDELAYEDEXPANSION


@rem -------------------------------------------------------------------------

@rem 初始化搜索变量

@rem -------------------------------------------------------------------------

set torSearchDirs=0

set torRecursiveLevel=0

set savedCurDir=%CD%

set foundDir=


if "%~1" EQU "" (

   echo Please input filename to be searched.

   goto searchAllDriveReturn

)

set torSearchFile=%~1


@rem -------------------------------------------------------------------------

@rem 对搜索的时间范围参数进行检查

@rem -------------------------------------------------------------------------

if "%~2" EQU "" (

   set torFileTime1=1900-01-01

   set torFileTime2=9999-12-31

) else (

   if "%~2" EQU "*" (

       set torFileTime1=1900-01-01

   ) else (

       set torFileTime1=%~2

   )

   if "%~3" EQU "" (

       if "%~2" EQU "*" (

           set torFileTime2=9999-12-31

       ) else (

           set torFileTime2=%~2

       )

   ) else (

       if "%~3" EQU "*" (

           set torFileTime2=9999-12-31

       ) else (

           set torFileTime2=%~3

       )

   )

)

if "%4" EQU "" (set torSearchDepth=9999) else (set /a torSearchDepth=%4)


@rem echo torSearchFile=%torSearchFile%

@rem echo torFileTime1=%torFileTime1%

@rem echo torFileTime2=%torFileTime2%

@rem echo torSearchDepth=%torSearchDepth%


@rem -------------------------------------------------------------------------

@rem 下面的程序段用来搜索本机上有效的硬盘驱动器

@rem -------------------------------------------------------------------------

@set driveList=

regedit /e driveslist.txt HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices

for /f "usebackq skip=2 tokens=3 delims=\:" %%a in (

   `find "DosDevices" driveslist.txt`) do (

   if /I "%%a" GEQ "C" (if exist %%a:\. set driveList=!driveList! %%a:)

)

del driveslist.txt

@rem echo search in driveList: %driveList%


@rem -------------------------------------------------------------------------

@rem 依次在各硬盘上查找目标文件, 如果找到则立即停止

@rem -------------------------------------------------------------------------

for %%a in (%driveList%) do (


    @rem ---------------------------------------------------------------------

    @rem 进入目标驱动器, 并在此根目录下直接进行搜索

    @rem ---------------------------------------------------------------------

    %%a

    cd\

    @rem echo Now search "%torSearchFile%" in drive %%a

    set /a torSearchDirs+=1

    if EXIST "%torSearchFile%" for %%i in ("%torSearchFile%") do (

        if "%%~ti" GEQ "%torFileTime1% 00:00" (

            if "%%~ti" LEQ "%torFileTime2% 23:59" (

                set foundDir=%%a

                goto searchAllDriveReturn

            )

        )

    )


    @rem ---------------------------------------------------------------------

    @rem 如果是最大深度搜索, 则直接使用批处理的for /R 功能

    @rem ---------------------------------------------------------------------

    if %torSearchDepth% EQU 9999 (

        for /r /d %%b in (*) do if EXIST "%%~fb\%torSearchFile%" (

            for %%i in ("%%~fb\%torSearchFile%") do (

                if "%%~ti" GEQ "%torFileTime1% 00:00" (

                    if "%%~ti" LEQ "%torFileTime2% 23:59" (

                        set foundDir=%%~fb

                        goto searchAllDriveReturn

                    )

                )

            )

        )

    @rem ---------------------------------------------------------------------

    @rem 否则调用递归搜索过程

    @rem ---------------------------------------------------------------------

    ) else if %torSearchDepth% GTR 0 (call :recursiveSearch)


    @rem ---------------------------------------------------------------------

    @rem 如果已经找到, 则直接跳出搜索

    @rem ---------------------------------------------------------------------

    if "!foundDir!" NEQ "" goto searchAllDriveReturn

)


:searchAllDriveReturn

    @rem ---------------------------------------------------------------------

    @rem 恢复原来的工作目录, 并打印搜索结果

    @rem ---------------------------------------------------------------------

    %savedCurDir:~0,2%

    cd "%savedCurDir%"

    echo "%foundDir%"

    goto :EOF


@rem =========================================================================

@rem 递归搜索过程

@rem -------------------------------------------------------------------------

:recursiveSearch

    @rem ---------------------------------------------------------------------

    @rem 在每一个子目录下面依次搜索

    @rem ---------------------------------------------------------------------

    set /a torRecursiveLevel+=1

    for /d %%b in (*) do (


        set /a torSearchDirs+=1

        @rem echo curdir="%cd%\%%b"

        if EXIST "%%b\%torSearchFile%" for %%i in ("%%b\%torSearchFile%") do (

            if "%%~ti" GEQ "%torFileTime1% 00:00" (

                if "%%~ti" LEQ "%torFileTime2% 23:59" (

                    set foundDir=%%~fb

                    goto :recursiveSearchReturn

                )

            )

        )


        @rem -----------------------------------------------------------------

        @rem 小于搜索深度, 则进行更深一步的递归搜索

        @rem -----------------------------------------------------------------

        if !torRecursiveLevel! LSS %torSearchDepth% (

            cd "%%b"

            call :recursiveSearch

            cd ..

            if "!foundDir!" NEQ "" goto :recursiveSearchReturn

        )

    )


:recursiveSearchReturn

    set /a torRecursiveLevel-=1

    goto :EOF

本例采用了递归算法进行文件搜索。注意这里的递归算法，从算法上来讲，可能更简单的办法是设定目标文件不存在，然后检查目标文件存在与否，不存在则进入递归，否则退出。这里的算法是是先在本级目录下面检查目标文件是否存在，如不存在，再进入下一目录，进行递归调用。这是由于实测的结果，现有的方法比前一种更快。作者未仔细分析其中的原因，有兴趣的朋友不妨可以探讨一下。  

                    
						

	Windows系统有所谓的「上帝模式」，说穿了其实也没什么，就是将所有的设定列出来，并且让你可以快速点选开启。这个功能在Windows  
7、Windows 8时代都有，而来到了Windows 10的世界中，当然也有。设定方式也与过去差不多，使用上帝模式几乎毫无难度。


	


	设定上帝模式 


	1.在桌面按鼠标右键，新增一个文件夹。


	


	2.在文件夹名称输入「GodMode.{ED7BA470-8E54-465E-825C-99712043E01C}」(不要加上下引号)。这样就好了。


	

	使用上帝模式 


	1.现在你会在桌面上看到文件夹变成这个样子。


	

	2.点选进入之后，可以看到列出来的各种类型设定。


	
上帝模式主要就是将系统设定的功能集中在一个接口来管理，所有的设定几乎可以在这里都找得到，而且还兼具有Help的功能。不过，由于
Windows  
10把部分设定功能移到「设定」里头去调整，不过我们检视了这个上帝模式，看起来是无法叫出「设定」里头的相关功能，仅能叫出「控制台」里头的相关设定                                   
        
        
                
    

Flash用了N年了,也不知从什么时候开始感觉元件库的管理面板不人性,检索功能差,找个对象如同在玩躲猫猫.
今天不小心按到了Shift,发现一个惊人的变化,原来可以使用Shift+英文字母来查找对象,真是OUT了,还有这么个功能,早该想到库面板是与Windows一样的操作快捷键.