精华内容
下载资源
问答
  • 探讨在工作表中找到最后一行

    千次阅读 2007-01-26 14:18:00
    无迹可寻——探讨在工作表中找到最后一行分类:ExcelVBA>>Web资源整理(HardCore XL VBA)>>技术技巧[禅语]无迹可寻僧人问郢州芭蕉山山圆禅师道:“没神通的菩萨应该是有形有相的,我怎么却找不到他的踪迹呢?...
    无迹可寻——探讨在工作表中找到最后一行
    分类:ExcelVBA>>Web资源整理(HardCore XL VBA)>>技术技巧

    [禅语]无迹可寻
    僧人问郢州芭蕉山山圆禅师道:“没神通的菩萨应该是有形有相的,我怎么却找不到他的踪迹呢?”
    “同道方知。”山圆禅师答道,“只有你也达到同样的境界,才能真正明白那种境界的种种现象。要不然,即使讲了,你也不会懂的。”
    僧人问道:“即然同道方知,禅师您知道吗?”
    “不知道。”山圆禅师直截了当地回答。
    僧人仍没有领悟,继续问道:“为什么您不知道啊?”
    “不是诗人不谈诗。”山圆禅师摇摇头,“你根本听不懂我的话。”
    - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    上面的故事有何禅机呢?有一些成功你看不到,是因为你的目光太过短浅。有一些道理你不明白,是因为你的知识太过浅陋。
    学习也是这样,光读书而不实践,只看到表面现象而不深入研究,是不会熟练运用的,当出现问题时也会不知所措。
    那么,现在让我们看看在Excel工作表中如何找到最后一行吧。
    - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    引子
    在日常生活中,我们经常会遇到这样一些情况。譬如,中午在食堂买饭时,由于人很多,排的队很长,于是,在最后的两位干脆不排了,坐在旁边的椅子上等着别人买完饭后或队伍中的人少了后再排在后面,这时,如果再来了一个人,那么他的位置就应该是在那两个人之后,虽然那两个人并未排在队伍中,可能刚来的那个人不知道他前面还有两个人,排在了队伍的最后。又如,学校组织全校学生出去郊游,按班级排队前进且各班按到达的先后顺序排队,此时,若校长想找最后一个人,他必须指定是那个班级的最后一个人或整个队伍的最后一个人;或者,此时1班的一个同学到了,他应该自觉地排在他们班的队伍的最后一位。……
    在Excel中,也有类似情形。例如,如果想在工作表的最后一行输入数据,则必须先找到最后一行的位置,而在有些情况下,已输入的数据中可能有隐藏的行,也可能最后一行的数据没有显示,此时,该如何有效的找到最后一行呢?又如,如果想找到最后一个公式所在的行,又该如何查找?还有一些情况,比如,在第一行和最后一行之间存在着空行;各列的最后一行不相同,在工作表无数据区域中虽没有数据但已设置了格式……等等。
    当然,在Excel中,有许多可以用来查找最后一行的方法,比如end(xlUp)属性、UsedRange属性、CurrentRegion属性、SpecialCells方法、以及Find方法等,这些方法可以在不同的情形下使用。但正如前面所讲述的,关键是要清楚Excel将“已使用范围”、“当前区域”、和一些常量如xlCellTypeLastCell在工作表中代表什么区域,以及您是在什么情形下查找最后一行,然后选用合适的方法,以确保找到正确的最后一行,否则,可能所找到的并不是您所想要的最后一行。
    “最后一行”可能的情形
    在查找最后一行时,可能是查找以下情形单元格所在的“最后一行”,即:
    (1)  含有公式的单元格
    (2)  格式化的单元格
    (3)  含有颜色的单元格
    (4)  包含数据有效性的单元格
    (5)  包含批注的单元格
    (6)  直接输入数据(文本和/或数字)的单元格
    (7)  由公式生成数据(文本和/或数字)的单元格
    (8)  直接输入数据(文本和/或数字)或者由公式生成数据(文本和/或数字)的单元格
    (9)  直接输入数字的单元格
    (10) 由公式生成数字的单元格
    (11) 直接输入数字或由公式生成数字的单元格
    (12) 直接输入文本的单元格
    (13) 由公式生成文本的单元格
    (14) 直接输入文本或由公式生成文本的单元格
    (15) 其它情形
    (16) 包含上述所有情形的单元格
    此外,还需要考虑工作表中的最后一行是否被隐藏了,而哪些方法忽略隐藏的行?最后一行的单元格中的数据是否显示?这些都会影响到您是否能查找到正确的最后一行。
    下面,我们来讨论查找最后一行的方法以及可能出现的一些情况。

    找到最后一行的一些方法探讨
    使用End属性
    在ExcelVBA中,使用End(xlUp)查找最后一行是最常使用且最为简单的方法,它假设要有一列总包含有数据(数字、文本和公式等),并且在该列中最后输入数据的单元格的下一行不会包含数据,因此不必担心会覆盖掉已有数据。但该方法有两个缺点:
    (1) 仅局限于查找指定列的最后一行。
    (2) 如果该列中最后一行被隐藏,那么该隐藏行将被视作最后一行。因此,在最后一行被隐藏时,其数据可能会被覆盖。但该列中间的隐藏行不会影响查找的结果。
    [示例代码01]
    Sub EndxlUp_OneColLastRow()
      If Range("A" & Rows.Count).End(xlUp) = Empty Then GoTo Finish
      '获取最后一行
      MsgBox "最后一行是第" & Range("A" & Rows.Count).End(xlUp).Row & “行.”
      Exit Sub
    Finish:
      MsgBox "没有发现公式或数据! "
    End Sub
    [示例代码02]
    Sub NextRowInColumnUsedAsSub()
    '包含所有数据和公式,忽略隐藏的最后一行
      Range("A" & Range("A" & Rows.Count).End(xlUp).Row + 1).Select
    End Sub
    [示例代码03]
    Sub NextRowInColumnUsedAsFunction()
    '包含所有数据和公式,忽略隐藏的最后一行
      Range("A" & LastRowInColumn("A") + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - - -
    Public Function LastRowInColumn(Column As String) As Long
         LastRowInColumn = Range(Column & Rows.Count).End(xlUp).Row
    End Function
    注意,要输入新数据的列可能与我们所查找最后一行时所使用的列不同,例如,在上例中,我们可以修改为在B列中查找该列的最后一行,而在A列相应行的下一行中输入新的数据。

    使用Find方法
    Find方法在当前工作有数据中进行查找,不需要指定列,也可以确保不会意外地覆盖掉已有数据。其中,参数LookIn指定所查找的类型,有三个常量可供选择,即xlValues、xlFormulas和xlComments。
    (1) 常量xlFormulas将包含零值的单元格作为有数据的单元格。(当设置零值不显示时,该单元格看起来为空,但该参数仍将该单元格视为有数据的单元格)
    (2) 常量xlValues将包含零值的单元格(如果设置零值不显示时)作为空白单元格,此时,若该单元格在最后一行,则Find方法会认为该单元格所在的行为空行,因此,该单元格中的内容可能会被新数据所覆盖。
    [注:在Excel中,选择菜单“工具”——“选项”,在打开的“选项”对话框中,选择“视图”选项卡,将其中的“零值”前的复选框取消选中,则工作表中的零值都不会显示]
    如果在参数LookIn中使用常量xlValues的话,还存在一个问题是:如果您将最后一行隐藏,则Find方法会认为倒数第二行是最后一行,此时您在最后一行的下一行输入数据,则会将实际的最后一行的数据覆盖。
    您可以在隐藏最后一行与不隐藏最后一行,或者是最后一行显示零值与不显示零值时,运行下面的示例代码04,看看所得的结果有什么不同。
    [示例代码04]
    Sub Find_LastRowxlValues()
       On Error GoTo Finish
       '获取最后一行
       MsgBox "最后一行是第" & Cells.Find("*", _
       SearchOrder:=xlByRows, LookIn:=xlValues, _
       SearchDirection:=xlPrevious).EntireRow.Row & “行”
       Exit Sub
    Finish:
       MsgBox "没有发现数值!"
    End Sub
    因此,在使用Find方法时,您应该考虑所选参数设置的常量,以及工作表最后一行是否有可能被隐藏或不显示零值。如果您忽视这些情况,很可能得不到您想要的结果,或者是覆盖掉已有数据。使用常量xlFormulas可以避免这个问题,如下面的示例代码05所示。
    [示例代码05]
    Sub Find_LastRowxlFormulas()
       On Error GoTo Finish
       '获取最后一行
       MsgBox "最后一行是第" & Cells.Find("*", _
       SearchOrder:=xlByRows, LookIn:=xlFormulas, _
       SearchDirection:=xlPrevious).EntireRow.Row & “行”
       Exit Sub
    Finish:
       MsgBox "没发现数值或公式!"
    End Sub
    下面再列举几个示例代码。
    [示例代码06]
    Sub NextRowUsedAsSub()
    '选取最后一行的下一行
      Range("A" & Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row + 1).Select
    End Sub
    [示例代码07]
    Sub NextRowUsedAsFunction()
    '选取最后一行的下一行(调用函数)
      Range("A" & LastRow + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - - -
    Public Function LastRow() As Long
    '本代码包含隐藏行
    '使用常量xlFormulas,因为常量xlValues会忽略隐藏的最后一行
      LastRow = Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row
    End Function
    注:Find方法中,参数LookIn的默认值为xlFormulas。

    使用SpecialCells方法
    SpecialCells方法用于查找指定类型的值,其语法为SpecialCells(Type,Value),有两种主要的使用方式:
    (1) 若参数Type仅考虑常量,则在查找时会忽略和覆盖由公式生成的任何数据,如示例代码08所示。
    (2) 若参数Type仅考虑由公式生成的数据,则在查找时会忽略和覆盖任何常量数据,如示例代码09所示。
    如果参数Type是xlCellTypeConstants或者是xlCellTypeFormulas,则Value参数可使用常量决定哪种类型的单元格将被包含在结果中,这些常量值能组合而返回多个类型,其缺省设置是选择所有的常量或公式,而不管是何类型,可使用下面四个可选的常量:
    1) xlTextValues(包含文本);     2) xlNumbers(包含数字);
    3) xlErrors(包含错误值);       4) xlLogical(包含逻辑值)
    自已在工作表输入一些含有数值和公式的数据,隐藏或不隐藏最后一行或公式所在的行,先体验下面的两段示例代码。
    [示例代码08]
    '当最后一行为公式或隐藏了最后行时,会忽略,即认为倒数第二行为最后一行
    Sub NextConstantRowFunction()
         Range("A" & LastConstantRow(True, True, True, True) + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - -
    Public Function LastConstantRow(Optional IncludeText As Boolean, _
                                   Optional IncludeNumbers As Boolean, _
                                   Optional IncludeErrors As Boolean, _
                                   Optional IncludeLogicals As Boolean) As Long
       Dim Text As Long, Numbers As Long, Errors As Long
       Dim Logical As Long, AllTypes As Long
       If IncludeText Then Text = xlTextValues Else Text = 0
       If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
       If IncludeErrors Then Errors = xlErrors Else Errors = 0
       If IncludeLogicals Then Logical = xlLogical Else Logical = 0
       AllTypes = Text + Numbers + Errors + Logical
       On Error GoTo Finish
       LastConstantRow = Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$") _
           (UBound(Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$")))
         Exit Function
    Finish:
         MsgBox "没有发现数据!"
    End Function
    [示例代码09]
    '查找含有公式的单元格所在的行,忽略该行以后的常量和隐藏的行
    Sub NextFormulaRowFunction()
         Range("A" & LastFormulaRow(True, True, True, True) + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - -
    Public Function LastFormulaRow(Optional IncludeText As Boolean, _
                                   Optional IncludeNumbers As Boolean, _
                                   Optional IncludeErrors As Boolean, _
                                   Optional IncludeLogicals As Boolean) As Long
      Dim Text As Long, Numbers As Long, Errors As Long
      Dim Logical As Long, AllTypes As Long
      If IncludeText Then Text = xlTextValues Else Text = 0
      If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
      If IncludeErrors Then Errors = xlErrors Else Errors = 0
      If IncludeLogicals Then Logical = xlLogical Else Logical = 0
      AllTypes = Text + Numbers + Errors + Logical
      On Error GoTo Finish
      LastFormulaRow = Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$") _
          (UBound(Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$")))
      Exit Function
    Finish:
      MsgBox "没有发现数据!"
    End Function
    下面的示例代码10忽略最后一行带有公式的单元格,即当最后一行的单元格中含有公式时,将倒数第二行作为最后一行,即只考虑直接输入到工作表中的数据。当最后一行没有公式但被隐藏时,并不影响该方法的判断。
    [示例代码10]
    Sub SpecialCells_LastRowxlCellTypeConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants).EntireRow).EntireRow
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    注:因为上述代码使用了’Split’函数,故只适合于Office2000及以上的版本。
    该方法也允许我们指定单个数据类型,诸如数字数据或文本数据,如下所示。
    下面,我们查找的最后一行是仅在行中有数字(而不包含公式)的单元格的最后一行。
    [示例代码11]
    Sub SpecialCells_LastRowxlCellTypeNumberConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants, xlNumbers).EntireRow)
       '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    下面,我们查找的最后一行是仅在行中有文本(而不包含公式)的单元格的最后一行。
    [示例代码12]
    Sub SpecialCells_LastRowxlCellTypeTextConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow)
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    下面,我们查找的最后一行是仅在行中有公式的单元格的最后一行。
    [示例代码13]
    Sub SpecialCells_LastRowxlCellTypeFormulas()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeFormulas).EntireRow).EntireRow
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    同上面所讲述的一样,我们也能使用SpecailCells方法去找到其它特定类型的单元格所在的最后一行,下面是这些常量的一个完整的列表:
    XlCellTypeAllFormatConditions (任何格式的单元格)
    XlCellTypeAllValidation (带有数据有效性的单元格)
    XlCellTypeBlanks (所使用区域中的空白单元格)
    XlCellTypeComments (包含有批注的单元格)
    XlCellTypeConstants (包含有常量的单元格)
    XlCellTypeFormulas (包含有公式的单元格)
    XlCellTypeLastCell (已使用区域中的最后一个单元格(看下面))
    XlCellTypeSameFormatConditions (有相同格式的单元格)
    XlCellTypeSameValidation (有相同数据有效性条件的单元格)
    XlCellTypeVisible (工作表中所有可见的单元格)

    使用UsedRange属性(及SpecialCells方法)
    UsedRange方法可用于在工作表中已使用区域查找最后一行,该区域包括可能以前使用过的任何单元格,但现在其中的数据被删除了,比如目前的工作表中只有第1行至第5行共5行,其它行都无数据,但在第6行中有些单元格以前使用过(可能仅仅格式化或内容清除了,总之该行现在不含有数据),那么第6行也包含在该已使用的区域中。此外,如果最后一行被隐藏,那么会将因此,使用该方法查找最后一行是无规律且不可靠的,它通常可能会得到预料不到的结果。
    有时,与UsedRange属性相似的技术也能用SpecialCells方法实现,其常量xlCellTypeLastCell代表在”已使用区域”中的最后一个单元格,与UsedRange属性稍有不同的是,当您在最后一行中输入数据后,又将其删除,则此数据所在的单元格也包含在已使用的区域中,并且如果最后的行被隐藏,则将可见行的最后一行当作最后一行。下面有两段代码您可以在工作表中进行调试,看看其特点。
    [示例代码14]
    Sub NextUsedRowSub()
    ' 选取可见的最后一行的下一行
      Range("A" & Cells.SpecialCells(xlCellTypeLastCell).Row + 1).Select
    End Sub
    [示例代码15]
    Sub NextUsedRowFunction()
      Range("A" & LastUsedRow + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - -
    Public Function LastUsedRow() As Long
      LastUsedRow = Cells.SpecialCells(xlCellTypeLastCell).Row
    End Function
    使用这里介绍的两种技术时,您一定要清楚工作表当前的状态,以找到正确的最后一行。

    使用CurrentRegion属性
    CurrentRegion属性返回代表单元格所在的当前区域,即四周有空行的独立区域,因此,可使用此属性查找当前区域的最后一行。但是使用其查找最后一行的一个缺点是,必须首先选取当前区域,然后进行查找。

    小结
    正如开始所讲述的一样,使用各种方法来查找最后一行都有其优缺点,并且都能找到您想要的最后一行,关键是您要了解各种方法的特性,以及工作表的状态,以便于选择所使用的方法来找到您需要的最后一行。
    上述内容可能有不准确的地方,也可能有遗漏之处,您也可以在调试中体会和改进。 
    展开全文
  • [VBA]探讨在工作表中找到最后一行

    万次阅读 2012-02-02 14:35:42
    因此,使用Find方法时,您应该考虑所选参数设置的常量,以及工作表最后一行是否有可能被隐藏不显示零值。如果您忽视这些情况,很可能得不到您想要的结果,或者是覆盖掉已有数据。使用常量xlFormulas可以避免这个...

    转载来自于:http://blog.excelhome.net/user1/fanjy/archives/2006/703.html


    [禅语]无迹可寻

    僧人问郢州芭蕉山山圆禅师道:“没神通的菩萨应该是有形有相的,我怎么却找不到他的踪迹呢?”
    “同道方知。”山圆禅师答道,“只有你也达到同样的境界,才能真正明白那种境界的种种现象。要不然,即使讲了,你也不会懂的。”
    僧人问道:“即然同道方知,禅师您知道吗?”
    “不知道。”山圆禅师直截了当地回答。
    僧人仍没有领悟,继续问道:“为什么您不知道啊?”
    “不是诗人不谈诗。”山圆禅师摇摇头,“你根本听不懂我的话。”
    - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
    上面的故事有何禅机呢?有一些成功你看不到,是因为你的目光太过短浅。有一些道理你不明白,是因为你的知识太过浅陋。
    学习也是这样,光读书而不实践,只看到表面现象而不深入研究,是不会熟练运用的,当出现问题时也会不知所措。
    那么,现在让我们看看在Excel工作表中如何找到最后一行吧。
    - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
    引子
    在日常生活中,我们经常会遇到这样一些情况。譬如,中午在食堂买饭时,由于人很多,排的队很长,于是,在最后的两位干脆不排了,坐在旁边的椅子上等着别人买完饭后或队伍中的人少了后再排在后面,这时,如果再来了一个人,那么他的位置就应该是在那两个人之后,虽然那两个人并未排在队伍中,可能刚来的那个人不知道他前面还有两个人,排在了队伍的最后。又如,学校组织全校学生出去郊游,按班级排队前进且各班按到达的先后顺序排队,此时,若校长想找最后一个人,他必须指定是那个班级的最后一个人或整个队伍的最后一个人;或者,此时1班的一个同学到了,他应该自觉地排在他们班的队伍的最后一位。……
    在Excel中,也有类似情形。例如,如果想在工作表的最后一行输入数据,则必须先找到最后一行的位置,而在有些情况下,已输入的数据中可能有隐藏的行,也可能最后一行的数据没有显示,此时,该如何有效的找到最后一行呢?又如,如果想找到最后一个公式所在的行,又该如何查找?还有一些情况,比如,在第一行和最后一行之间存在着空行;各列的最后一行不相同,在工作表无数据区域中虽没有数据但已设置了格式……等等。
    当然,在Excel中,有许多可以用来查找最后一行的方法,比如end(xlUp)属性、UsedRange属性、CurrentRegion属性、SpecialCells方法、以及Find方法等,这些方法可以在不同的情形下使用。但正如前面所讲述的,关键是要清楚Excel将“已使用范围”、“当前区域”、和一些常量如xlCellTypeLastCell在工作表中代表什么区域,以及您是在什么情形下查找最后一行,然后选用合适的方法,以确保找到正确的最后一行,否则,可能所找到的并不是您所想要的最后一行。
    “最后一行”可能的情形
    在查找最后一行时,可能是查找以下情形单元格所在的“最后一行”,即:
    (1)  含有公式的单元格
    (2)  格式化的单元格
    (3)  含有颜色的单元格
    (4)  包含数据有效性的单元格
    (5)  包含批注的单元格
    (6)  直接输入数据(文本和/或数字)的单元格
    (7)  由公式生成数据(文本和/或数字)的单元格
    (8)  直接输入数据(文本和/或数字)或者由公式生成数据(文本和/或数字)的单元格
    (9)  直接输入数字的单元格
    (10) 由公式生成数字的单元格
    (11) 直接输入数字或由公式生成数字的单元格
    (12) 直接输入文本的单元格
    (13) 由公式生成文本的单元格
    (14) 直接输入文本或由公式生成文本的单元格
    (15) 其它情形
    (16) 包含上述所有情形的单元格
    此外,还需要考虑工作表中的最后一行是否被隐藏了,而哪些方法忽略隐藏的行?最后一行的单元格中的数据是否显示?这些都会影响到您是否能查找到正确的最后一行。
    下面,我们来讨论查找最后一行的方法以及可能出现的一些情况。


    找到最后一行的一些方法探讨
    使用End属性
    在ExcelVBA中,使用End(xlUp)查找最后一行是最常使用且最为简单的方法,它假设要有一列总包含有数据(数字、文本和公式等),并且在该列中最后输入数据的单元格的下一行不会包含数据,因此不必担心会覆盖掉已有数据。但该方法有两个缺点:
    (1) 仅局限于查找指定列的最后一行。
    (2) 如果该列中最后一行被隐藏,那么该隐藏行将被视作最后一行。因此,在最后一行被隐藏时,其数据可能会被覆盖。但该列中间的隐藏行不会影响查找的结果。
    [示例代码01]
    Sub EndxlUp_OneColLastRow()
      If Range("A" & Rows.Count).End(xlUp) = Empty Then GoTo Finish
      '获取最后一行
      MsgBox "最后一行是第" & Range("A" & Rows.Count).End(xlUp).Row & “行.”
      Exit Sub
    Finish:
      MsgBox "没有发现公式或数据! "
    End Sub
    [示例代码02]
    Sub NextRowInColumnUsedAsSub()
    '包含所有数据和公式,忽略隐藏的最后一行
      Range("A" & Range("A" & Rows.Count).End(xlUp).Row + 1).Select
    End Sub
    [示例代码03]
    Sub NextRowInColumnUsedAsFunction()
    '包含所有数据和公式,忽略隐藏的最后一行
      Range("A" & LastRowInColumn("A") + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - - - 
    Public Function LastRowInColumn(Column As String) As Long
         LastRowInColumn = Range(Column & Rows.Count).End(xlUp).Row
    End Function
    注意,要输入新数据的列可能与我们所查找最后一行时所使用的列不同,例如,在上例中,我们可以修改为在B列中查找该列的最后一行,而在A列相应行的下一行中输入新的数据。

    使用Find方法
    Find方法在当前工作有数据中进行查找,不需要指定列,也可以确保不会意外地覆盖掉已有数据。其中,参数LookIn指定所查找的类型,有三个常量可供选择,即xlValues、xlFormulas和xlComments。
    (1) 常量xlFormulas将包含零值的单元格作为有数据的单元格。(当设置零值不显示时,该单元格看起来为空,但该参数仍将该单元格视为有数据的单元格)
    (2) 常量xlValues将包含零值的单元格(如果设置零值不显示时)作为空白单元格,此时,若该单元格在最后一行,则Find方法会认为该单元格所在的行为空行,因此,该单元格中的内容可能会被新数据所覆盖。
    [注:在Excel中,选择菜单“工具”——“选项”,在打开的“选项”对话框中,选择“视图”选项卡,将其中的“零值”前的复选框取消选中,则工作表中的零值都不会显示]
    如果在参数LookIn中使用常量xlValues的话,还存在一个问题是:如果您将最后一行隐藏,则Find方法会认为倒数第二行是最后一行,此时您在最后一行的下一行输入数据,则会将实际的最后一行的数据覆盖。
    您可以在隐藏最后一行与不隐藏最后一行,或者是最后一行显示零值与不显示零值时,运行下面的示例代码04,看看所得的结果有什么不同。
    [示例代码04]
    Sub Find_LastRowxlValues()
       On Error GoTo Finish
       '获取最后一行
       MsgBox "最后一行是第" & Cells.Find("*", _
       SearchOrder:=xlByRows, LookIn:=xlValues, _
       SearchDirection:=xlPrevious).EntireRow.Row & “行”
       Exit Sub
    Finish:
       MsgBox "没有发现数值!"
    End Sub
    因此,在使用Find方法时,您应该考虑所选参数设置的常量,以及工作表最后一行是否有可能被隐藏或不显示零值。如果您忽视这些情况,很可能得不到您想要的结果,或者是覆盖掉已有数据。使用常量xlFormulas可以避免这个问题,如下面的示例代码05所示。
    [示例代码05]
    Sub Find_LastRowxlFormulas()
       On Error GoTo Finish
       '获取最后一行
       MsgBox "最后一行是第" & Cells.Find("*", _
       SearchOrder:=xlByRows, LookIn:=xlFormulas, _
       SearchDirection:=xlPrevious).EntireRow.Row & “行”
       Exit Sub
    Finish:
       MsgBox "没发现数值或公式!"
    End Sub
    下面再列举几个示例代码。
    [示例代码06]
    Sub NextRowUsedAsSub()
    '选取最后一行的下一行
      Range("A" & Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row + 1).Select
    End Sub
    [示例代码07]
    Sub NextRowUsedAsFunction()
    '选取最后一行的下一行(调用函数)
      Range("A" & LastRow + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - - - 
    Public Function LastRow() As Long
    '本代码包含隐藏行
    '使用常量xlFormulas,因为常量xlValues会忽略隐藏的最后一行
      LastRow = Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row
    End Function
    注:Find方法中,参数LookIn的默认值为xlFormulas。

    使用SpecialCells方法
    SpecialCells方法用于查找指定类型的值,其语法为SpecialCells(Type,Value),有两种主要的使用方式:
    (1) 若参数Type仅考虑常量,则在查找时会忽略和覆盖由公式生成的任何数据,如示例代码08所示。
    (2) 若参数Type仅考虑由公式生成的数据,则在查找时会忽略和覆盖任何常量数据,如示例代码09所示。
    如果参数Type是xlCellTypeConstants或者是xlCellTypeFormulas,则Value参数可使用常量决定哪种类型的单元格将被包含在结果中,这些常量值能组合而返回多个类型,其缺省设置是选择所有的常量或公式,而不管是何类型,可使用下面四个可选的常量:
    1) xlTextValues(包含文本);     2) xlNumbers(包含数字);
    3) xlErrors(包含错误值);       4) xlLogical(包含逻辑值)
    自已在工作表输入一些含有数值和公式的数据,隐藏或不隐藏最后一行或公式所在的行,先体验下面的两段示例代码。
    [示例代码08]
    '当最后一行为公式或隐藏了最后行时,会忽略,即认为倒数第二行为最后一行
    Sub NextConstantRowFunction()
         Range("A" & LastConstantRow(True, True, True, True) + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - - - - - 
    Public Function LastConstantRow(Optional IncludeText As Boolean, _
                                   Optional IncludeNumbers As Boolean, _
                                   Optional IncludeErrors As Boolean, _
                                   Optional IncludeLogicals As Boolean) As Long
       Dim Text As Long, Numbers As Long, Errors As Long
       Dim Logical As Long, AllTypes As Long
       If IncludeText Then Text = xlTextValues Else Text = 0
       If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
       If IncludeErrors Then Errors = xlErrors Else Errors = 0
       If IncludeLogicals Then Logical = xlLogical Else Logical = 0
       AllTypes = Text + Numbers + Errors + Logical
       On Error GoTo Finish
       LastConstantRow = Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$") _
           (UBound(Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$")))
         Exit Function
    Finish:
         MsgBox "没有发现数据!"
    End Function
    [示例代码09]
    '查找含有公式的单元格所在的行,忽略该行以后的常量和隐藏的行
    Sub NextFormulaRowFunction()
         Range("A" & LastFormulaRow(True, True, True, True) + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - 
    Public Function LastFormulaRow(Optional IncludeText As Boolean, _
                                   Optional IncludeNumbers As Boolean, _
                                   Optional IncludeErrors As Boolean, _
                                   Optional IncludeLogicals As Boolean) As Long
      Dim Text As Long, Numbers As Long, Errors As Long
      Dim Logical As Long, AllTypes As Long
      If IncludeText Then Text = xlTextValues Else Text = 0
      If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
      If IncludeErrors Then Errors = xlErrors Else Errors = 0
      If IncludeLogicals Then Logical = xlLogical Else Logical = 0
      AllTypes = Text + Numbers + Errors + Logical
      On Error GoTo Finish
      LastFormulaRow = Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$") _
          (UBound(Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$")))
      Exit Function
    Finish:
      MsgBox "没有发现数据!"
    End Function
    下面的示例代码10忽略最后一行带有公式的单元格,即当最后一行的单元格中含有公式时,将倒数第二行作为最后一行,即只考虑直接输入到工作表中的数据。当最后一行没有公式但被隐藏时,并不影响该方法的判断。
    [示例代码10]
    Sub SpecialCells_LastRowxlCellTypeConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants).EntireRow).EntireRow
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    注:因为上述代码使用了’Split’函数,故只适合于Office2000及以上的版本。
    该方法也允许我们指定单个数据类型,诸如数字数据或文本数据,如下所示。
    下面,我们查找的最后一行是仅在行中有数字(而不包含公式)的单元格的最后一行。
    [示例代码11]
    Sub SpecialCells_LastRowxlCellTypeNumberConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants, xlNumbers).EntireRow)
       '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    下面,我们查找的最后一行是仅在行中有文本(而不包含公式)的单元格的最后一行。
    [示例代码12]
    Sub SpecialCells_LastRowxlCellTypeTextConstants()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow)
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    下面,我们查找的最后一行是仅在行中有公式的单元格的最后一行。
    [示例代码13]
    Sub SpecialCells_LastRowxlCellTypeFormulas()
       Dim MyRow As Range
       On Error GoTo Finish
       Set MyRow = Intersect([A:A], Cells. _
       SpecialCells(xlCellTypeFormulas).EntireRow).EntireRow
      '获取最后一行
       MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
       (UBound(Split(MyRow.Address, "$"))) & “行”
       Set MyRow = Nothing
       Exit Sub
    Finish:
       MsgBox "没有发现数据!"
    End Sub
    同上面所讲述的一样,我们也能使用SpecailCells方法去找到其它特定类型的单元格所在的最后一行,下面是这些常量的一个完整的列表:
    XlCellTypeAllFormatConditions (任何格式的单元格)
    XlCellTypeAllValidation (带有数据有效性的单元格)
    XlCellTypeBlanks (所使用区域中的空白单元格)
    XlCellTypeComments (包含有批注的单元格)
    XlCellTypeConstants (包含有常量的单元格)
    XlCellTypeFormulas (包含有公式的单元格)
    XlCellTypeLastCell (已使用区域中的最后一个单元格(看下面))
    XlCellTypeSameFormatConditions (有相同格式的单元格)
    XlCellTypeSameValidation (有相同数据有效性条件的单元格)
    XlCellTypeVisible (工作表中所有可见的单元格)

    使用UsedRange属性(及SpecialCells方法)
    UsedRange方法可用于在工作表中已使用区域查找最后一行,该区域包括可能以前使用过的任何单元格,但现在其中的数据被删除了,比如目前的工作表中只有第1行至第5行共5行,其它行都无数据,但在第6行中有些单元格以前使用过(可能仅仅格式化或内容清除了,总之该行现在不含有数据),那么第6行也包含在该已使用的区域中。此外,如果最后一行被隐藏,那么会将因此,使用该方法查找最后一行是无规律且不可靠的,它通常可能会得到预料不到的结果。
    有时,与UsedRange属性相似的技术也能用SpecialCells方法实现,其常量xlCellTypeLastCell代表在”已使用区域”中的最后一个单元格,与UsedRange属性稍有不同的是,当您在最后一行中输入数据后,又将其删除,则此数据所在的单元格也包含在已使用的区域中,并且如果最后的行被隐藏,则将可见行的最后一行当作最后一行。下面有两段代码您可以在工作表中进行调试,看看其特点。
    [示例代码14]
    Sub NextUsedRowSub()
    ' 选取可见的最后一行的下一行
      Range("A" & Cells.SpecialCells(xlCellTypeLastCell).Row + 1).Select
    End Sub
    [示例代码15]
    Sub NextUsedRowFunction()
      Range("A" & LastUsedRow + 1).Select
    End Sub
    '- - - - - - - - - - - - - - - - - - - - 
    Public Function LastUsedRow() As Long
      LastUsedRow = Cells.SpecialCells(xlCellTypeLastCell).Row
    End Function
    使用这里介绍的两种技术时,您一定要清楚工作表当前的状态,以找到正确的最后一行。

    使用CurrentRegion属性
    CurrentRegion属性返回代表单元格所在的当前区域,即四周有空行的独立区域,因此,可使用此属性查找当前区域的最后一行。但是使用其查找最后一行的一个缺点是,必须首先选取当前区域,然后进行查找。

    小结
    正如开始所讲述的一样,使用各种方法来查找最后一行都有其优缺点,并且都能找到您想要的最后一行,关键是您要了解各种方法的特性,以及工作表的状态,以便于选择所使用的方法来找到您需要的最后一行。
    上述内容可能有不准确的地方,也可能有遗漏之处,您也可以在调试中体会和改进。

    By fanjy in 2006-11-2


    展开全文
  • 写了个VBA宏程序,用来自动将EXCEL一列转换为不同的工作表。...'宏SeperateColumn用来将当前工作表,按某一列进行分类,每类新建为以该值变量命名的工作表,工作表第行为表头,不进行分离; '注意:使用前

    写了一个VBA宏程序,用来自动将EXCEL一列转换为不同的工作表。例如:

    姓名  性别

    张三  男

    李四  女

    通过该程序可以自动分离出“男”工作表和“女”工作表。先上代码,注释写的很清楚。

    在excel中先使用alt+F11组合键打开代码窗口,在当前项目中新建一个模块(modules),复制代码到当前模块。使用ctrl+G打开调试窗口,复制代码并执行。

    '时间:2/6/2015
    '版本:1.0
    
    '宏SeperateColumn用来将当前工作表,按某一列进行分类,每一类新建为以该值变量命名的工作表中,工作表第一行为表头,不进行分离;
    '注意:使用前请提前备份工作簿,最好先搜索目标列确认列值符合工作表命名规范
    
    Sub SeperateColumn()
    
      '定义了需要分离的列
      Dim col As Integer
      
      '从选择的行开始进行迭代分离col列*********************
      col = getSeperateCol()
      
     
         '取得当前工作表的最大行数tableRows
         Dim tableRows As Integer
         tableRows = ActiveSheet.Range("A65535").End(xlUp).Row
         
         '取得当前工作表的名字
         Dim tableName As String
         tableName = ActiveSheet.Name()
         
            '对当前工作表从第二行开始迭代(第一行为表头),取col列的值进行处理
            Dim stringEveryItem As String
            For Index = 2 To tableRows
            
                stringEveryItem = ActiveSheet.Cells(Index, col)
                
                '如果此值在所有的工作表中五法找到则新建一个该名称的工作表并且将该行插入
                If stringExistWorkSheet(stringEveryItem) = False Then
                   resultAddsheet = addWorkSheetCopyFirstRow(tableName, stringEveryItem)
                   resultInsertSheet = copyRowToWorksheet(tableName, Index, stringEveryItem)
                    
                '若此值在所有工作表中能找到,则直接插入到该工作表中
                Else
                   resultInsertExistSheet = copyRowToWorksheet(tableName, Index, stringEveryItem)
                End If
            Next
                    
      Debug.Print "转换完成"
      
      MsgBox "转换完成 Seperate Completed.", vbInformation, "运行结果RESULT"
            
      
    End Sub
    
    '函数stringExistWorkSheet()判断通过值传递来的value_name是否在本workbook中存在该worksheet(这里不区分大小写)
    Function stringExistWorkSheet(ByVal value_name As String) As Boolean
        
        '先定义一个Worksheet对象
        Dim sht As Worksheet
        
        '默认下找不到该Worksheet
        stringExistWorkSheet = False
        
        '下面对该Workbook进行遍历
        For Each sht In ActiveWorkbook.Worksheets
            '比较时worksheet和value_name不区分大小写
            If VBA.LCase(sht.Name) = VBA.LCase(value_name) Then
                stringExistWorkSheet = True
                Exit Function
                
            End If
        Next
    End Function
    '函数addWorkSheetCopyFirstRow(tableName,sName)用来新建一个以sName的工作表,并且将tableName工作表的第一行复制到新工作表的第一行
    Function addWorkSheetCopyFirstRow(ByVal tableName As String, ByVal sName As String) As Boolean
    
        addWorkSheetCopyFirstRow = False
    
        '插入制定名称的工作表
        Worksheets.Add.Name = sName
        
        Debug.Print "创建新工作表"; sName; "成功"
        
        '选中主表的第一行
         Worksheets(tableName).Activate
         Rows(1).Select
        '复制选中的第一行
        Selection.Copy
        
        '选中新建表的第一行
        Sheets(sName).Activate
        Rows(1).Select
        '粘贴
        ActiveSheet.Paste
        
        addWorkSheetCopyFirstRow = True
        Worksheets(tableName).Activate '最后将当前活动工作表还原为主表
        
        Debug.Print "已经复制第一行到"; sName; "工作表"
        
    End Function
    'copyRowToWorksheet函数用来从tableNameCopy工作表中选取第tableNameCopyRow行,然后复制到tableNamePaste表中
    Function copyRowToWorksheet(ByVal tableNameCopy As String, ByVal tableNameCopyRow As Single, ByVal tableNamePaste As String) As Boolean
        
        copyRowToWorksheet = False
        
        '首先将主表设为活动表,选取某行进行复制
        Worksheets(tableNameCopy).Activate
        Rows(tableNameCopyRow).Select
        Selection.Copy
        
        '其次将要粘贴的目的表设为活动表,选取其尾部的行进行粘贴
        Worksheets(tableNamePaste).Activate
        
        '这里使用目的表的最后一行
        Dim rowNumber As Integer
        rowNumber = ActiveSheet.Range("A65535").End(xlUp).Row + 1
        
        Rows(rowNumber).Select
        ActiveSheet.Paste
        
      
        '粘贴成功后还原活动表
        copyRowToWorksheet = True
        Worksheets(tableNameCopy).Activate
        
    End Function
    'getSeperateCol函数通过使用inputbox提供用户选择输入,用来获得需要分离的列,这里先使用数字,后续添加输入列名的功能
    Function getSeperateCol() As Integer
        Dim colIndex As Integer
        
        '这里使用VBA.InputBox提供用户交互
        colIndex = VBA.InputBox("请输入需要分离的列序号(数字)Please input the index of the column which you want to seperate.(Integer)", "选择框CHOOSEBOX")
        
        '这里提供给用户确认选择框
        MsgBox "需要转换的列序号 Column Index:" & colIndex, vbInformation, "提示NOTICE"
        
        getSeperateCol = colIndex
             
    End Function
                                
    
    简述下自己的编程思想:

    首先遍历当前工作表的第二行至最后一行,根据选定的列进行迭代;这里,通过拆分功能区域,将程序拆分出1.遍历所有工作表名称。2,新建工作表并复制第一行。3,复制某一行到目标工作表。4,用户交互。4个函数区,分别实现测试,然后在主函数中调用。有效降低了编程的复杂性。

    展开全文
  • 问题VBA代码,如何引用当前工作表中的单个单元格(例如引用单元格C3)? 回答:可以使用下面列举的任一方式对当前工作表中的单元格(C3)进行引用。 (1) Range("C3") (2) [C3] (3) Cells(3, 3) ...

    问题一:在VBA代码中,如何引用当前工作表中的单个单元格(例如引用单元格C3)?

    回答:可以使用下面列举的任一方式对当前工作表中的单元格(C3)进行引用。

    (1) Range("C3")

    (2) [C3]

    (3) Cells(3, 3)

    (4) Cells(3, "C")

    (5) Range("C4").Offset(-1)

    Range("D3").Offset(, -1)

    Range("A1").Offset(2, 2)

    (6) 若C3为当前单元格,则可使用:ActiveCell

    (7) 若将C3单元格命名为“Range1”,则可使用:Range("Range1")或[Range1]

    (8) Cells(4, 3).Offset(-1)

    (9) Range("A1").Range("C3")

    问题二:在VBA代码中,我要引用当前工作表中的B2:D6单元格区域,有哪些方式?

    回答:可以使用下面列举的任一方式对当前工作表中单元格区域B2:D6进行引用。

    (1) Range(“B2:D6”)

    (2) Range("B2", "D6")

    (3) [B2:D6]

    (4) Range(Range("B2"), Range("D6"))

    (5) Range(Cells(2, 2), Cells(6, 4))

    (6) 若将B2:D6区域命名为“MyRange”,则又可以使用下面的语句引用该区域:

    ① Range("MyRange")

    ② [MyRange]

    (7) Range("B2").Resize(5, 3)

    (8) Range("A1:C5").Offset(1, 1)

    (9) 若单元格B2为当前单元格,则可使用语句:Range(ActiveCell, ActiveCell.Offset(4, 2))

    (10) 若单元格D6为当前单元格,则可使用语句:Range("B2", ActiveCell)

    问题三:在VBA代码中,如何使用变量实现对当前工作表中不确定单元格区域的引用?

    回答:有时,我们需要在代码中依次获取工作表中特定区域内的单元格,这通常可以采取下面的几种方式:

    (1) Range(“A” & i)

    (2) Range(“A” & i & “:C” & i)

    (3) Cells(i,1)

    (4) Cells(i,j)

    其中,i、j为变量,在循环语句中指定i和j的范围后,依次获取相应单元格。

    问题四:在VBA代码中,如何扩展引用当前工作表中的单元格区域?

    回答:可以使用Resize属性,例如:

    (1) ActiveCell.Resize(4, 4),表示自当前单元格开始创建一个4行4列的区域。

    (2) Range("B2").Resize(2, 2),表示创建B2:C3单元格区域。

    (3) Range("B2").Resize(2),表示创建B2:B3单元格区域。

    (4) Range("B2").Resize(, 2),表示创建B2:C2单元格区域。

    如果是在一个单元格区域(如B3:E6),或一个命名区域中(如将单元格区域B3:E6命名为“MyRange”)使用Resize属性,则只是相对于单元格区域左上角单元格扩展区域,例如:

    代码Range("C3:E6").Resize(, 2),表示单元格区域C3:D6,并且扩展的单元格区域可不在原单元格区域内。

    因此,可以知道Resize属性是相对于当前活动单元格或某单元格区域中左上角单元格按指定的行数或列数扩展单元格区域。

    问题五:在VBA代码中,如何在当前工作表中基于当前单元格区域或指定单元格区域处理其它单元格区域?

    回答:可以使用Offset属性,例如:

    (1) Range("A1").Offset(2, 2),表示单元格C3。

    (2) ActiveCell.Offset(, 1),表示当前单元格下一列的单元格。

    (3) ActiveCell.Offset(1),表示当前单元格下一行的单元格。

    (4) Range("C3:D5").Offset(, 1),表示单元格区域D3:E5,即将整个区域偏移一列。

    从上面的代码示例可知,Offset属性从所指定的单元格开始按指定的行数和列数偏移,从而到达目的单元格,但偏移的行数和列数不包括指定单元格本身。

    问题六:在VBA代码中,如何在当前工作表中引用交叉区域?

    回答:可以使用Intersect方法,例如:

    Intersect(Range("C3:E6"), Range("D5:F8")),表示单元格区域D5:E6,即单元格区域C3:E6与D5:F8相重迭的区域。

    问题七:在VBA代码中,如何在当前工作表中引用多个区域?

    回答:

    (1) 可以使用Union方法,例如:

    Union(Range("C3:D4"), Range("E5:F6")),表示单元格区域C3:D4和E5:F6所组成的区域。

    Union方法可以将多个非连续区域连接起来成为一个区域,从而可以实现对多个非连续区域一起进行操作。

    (2) 也可以使用下面的代码:

    Range("C3:D4, E5:F6")或[C3:D4, E5:F6]

    注意:Range("C3:D4","F5:G6"),表示单元格区域C3:G6,即将两个区域以第一个区域左上角单元格为起点,以第二个区域右下角单元格为终点连接成一个新区域。

    同时,在引用区域后使用Rows属性和Columns属性时,注意下面代码的区别:

    ①Range("C3:D4", "F8:G10").Rows.Count,返回的值为8;

    ②Range("C3:D4,F8:G10").Rows.Count,返回的值为2,即只计算第一个单元格区域。

    问题八:在VBA代码中,如何引用当前工作表中活动单元格或指定单元格所在的区域(当前区域)?

    回答:可以使用CurrentRegion属性,例如:

    (1) ActiveCell.CurrentRegion,表示活动单元格所在的当前区域。

    (2) Range("D5").CurrentRegion,表示单元格D5所在的当前区域。

    当前区域是指周围由空行或空列所围成的区域。该属性的详细使用参见《CurrentRegion属性示例》一文。

    问题九:在VBA代码中,如何引用当前工作表中已使用的区域?

    回答:可以使用UsedRange属性,例如:

    (1) Activesheet.UsedRange,表示当前工作表中已使用的区域。

    (2) Worksheets("sheet1").UsedRange,表示工作表sheet1中已使用的区域。

    与CurrentRegion属性不同的是,该属性代表工作表中已使用的单元格区域,包括显示为空行,但已进行过格式的单元格区域。该属性的详细使用参见《解析UsedRange属性》一文。

    问题十:如何在单元格区域内指定特定的单元格?

    回答:可以使用Item属性,例如:

    (1)Range("A1:B10").Item(5,3)指定单元格C5,这个单元格处于以区域中左上角单元格A1(即区域中第1行第1列的单元格)为起点的第5行第3列。因为Item属性为默认属性,因此也可以简写为:Range("A1:B10")(5,3)。

    如果将A1:B10区域命名为”MyRange”,那么Range("MyRange")(5,3)也指定单元格C5。

    (2) Range("A1:B10")(12,13)指定单元格M12,即用这种方式引用单元格,该单元格不必一定要包含在区域内。

    同时,也不需要索引数值是正值,例如:

    ① Range("D4:F6")(0,0)代表单元格C3;

    ② Range("D4:F6")(-1,-2)代表单元格A2。

    而Range("D4:F6")(1,1)代表单元格D4。

    (3) 也可以在单元格区域中循环,例如:

    Range("D4:F6")(2,2)(3,4)代表单元格H7,即该单元格位于作为左上角单元格E5的第3行第4列(因为E5是开始于区域中左上角单元格D4起的第2行第2列)。

    (4) 也能使用一个单个的索引数值进行引用。计数方式为从左向右,即在区域中的第一行开始从左向右计数,第一行结束后,然后从第二行开始从左到右接着计数,依次

    类推。(注:从区域中第一行第一个单元格开始计数,当第一行结束时,转入第二行最左边的单元格,这样按一行一行从左向右依次计数。以单元格区域中第1个单

    元格开始,按上述规则依次为第2个单元格、第3个单元格….等等),例如:

    Range("A1:B2")(1) 代表单元格A1;

    Range("A1:B2")(2) 代表单元格B1;

    Range("A1:B2")(3) 代表单元格A2;

    Range("A1:B2")(4) 代表单元格B2。

    这种方法可在工作表中连续向下引用单元格(即不一定是在单元格区域内,但在遵循相同的规律),例如:

    Range("A1:B2")(5)代表单元格A3;

    Range("A1:B2")(14)代表单元格B7,等等。

    也可以使用单个的负数索引值。

    这种使用单个索引值的方法对遍历列是有用的,例如,Range("D4")(1)代表单元格D4,Range("D4")(2)代表单元格D5,Range

    ("D4")(11)代表单元格D14,等等。

    同理,稍作调整后也可遍历行,例如:

    Range("D4").Columns(2)代表单元格E4,Range("D4").Columns(5)指定单元格H4,等等。

    (5)当与对象变量配合使用时,Item属性能提供简洁并有效的代码,例如:

    Set rng = Worksheets(1).[a1]

    定义了对象变量后,像单元格方法一样,Item属性允许使用两个索引数值引用工作表中的任一单元格,例如,rng(3,4)指定单元格D3。(By ChipPearson)

    问题十一:在VBA代码中,如何引用当前工作表中的整行或整列?

    回答:见下面的示例代码:

    (1) Range("C:C").Select,表示选择C列。

    Range("C:E").Select,表示选择C列至E列。

    (2) Range("1:1").Select,表示选择第一行。

    Range("1:3").Select,表示选择第1行至第3行。

    (3) Range("C:C").EntireColumn,表示C列;

    Range("D1").EntireColumn,表示D列。

    同样的方式,也可以选择整行,然后可以使用如AutoFit方法对整列或整行进行调整。

    问题十二:在VBA代码中,如何引用当前工作表中的所有单元格?

    回答:可以使用下面的代码:

    (1) Cells,表示当前工作表中的所有单元格。

    (2) Range(Cells(1, 1), Cells(Cells.Rows.Count, Cells.Columns.Count)),其中Cells.Rows表示工作表所有行,Cells. Columns表示工作表所有列。

    问题十三:在VBA代码中,如何引用工作表中的特定单元格区域?

    回答:在工作表中,您可能使用过“定位条件”对话框。可以通过选择菜单“编辑——定位”,单击“定位”对话框中的“定位条件”按钮显示该对话框。这个对话框可以允许用户选择特定的单元格。例如:

    (1)Worksheets("sheet1").Cells.SpecialCells(xlCellTypeAllFormatConditions),表示工作表sheet1中由带有条件格式的单元格所组成的区域。

    (2)ActiveCell.CurrentRegion.SpecialCells(xlCellTypeBlanks),表示当前工作表中活动单元格所在区域中所有空白单元格所组成的区域。

    问题十四:在VBA代码中,如何引用其它工作表或其它工作簿中的单元格区域?

    回答:要引用其它工作表或其它工作簿中的单元格区域,只需在单元格对象前加上相应的引用对象即可,例如:

    (1) Worksheets(“Sheet3”).Range(“C3:D5”),表示引用工作表sheet3中的单元格区域C3:D5。

    (2)Workbooks(“MyBook.xls”).Worksheets(“sheet1”).Range(“B2”),表示引用MyBook工作簿中工作表Sheet1上的单元格B2。

    问题十五:还有其它的一些情形吗?

    回答:列举如下:

    (1)Cells(15),表示单元格O1,即可在Cells属性中指定单元格数字来选择单元格,其计数顺序为自左至右、从上到下,又如Cells(257),表示单元格B1。

    (2) Cells(, 256),表示单元格IV1,但是如果Cells(, 257),则会返回错误。

    结语

    我们用VBA对Excel进行处理,一般是对其工作表中的数据进行处理,因此,引用单元格区域是ExcelVBA编程中最基本的操作之一,只有确定了所处理的单元格区域,才能使用相应的属性和方法进行下一步的操作。

    上面列举了一些引用单元格区域的情形和方式,可以看出,引用单元格区域有很多方式,有一些可能不常用,可以根据工作表的所处的环境和个人编程习惯进行选择使用。

    当然,在编写程序时,也可能会将上面的一些属性联合使用,以达到选取特定操作对象的目的,例如Offset属性、Resize属性、CurrentRegion属性、UsedRange属性等的组合。

    如何选择当前工作表中的单元格?

    例如,可以使用下面的代码选择当前工作表中的单元格D5:

    ActiveSheet.Cells(5, 4).Select

    或:ActiveSheet.Range("D5").Select

    如何选择同一工作簿中其它工作表上的单元格?

    例如,要选择同一工作簿中另一工作表上的单元格E6,可以使用下面的代码:

    Application.Goto ActiveWorkbook.Sheets("Sheet2").Cells(6, 5)

    或:Application.Goto (ActiveWorkbook.Sheets("Sheet2").Range("E6"))

    也可以先激活该工作表,然后再选择:

    Sheets("Sheet2").Activate

    ActiveSheet.Cells(6, 5).Select

    如何选择不同工作簿中的单元格?

    例如,要选择另一工作簿中的一个工作表上的单元格F7,可以使用下面的代码:

    Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Cells(7, 6)

    或:Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("F7")

    也可以先激活该工作簿中的工作表,然后再选择:

    Workbooks("BOOK2.XLS").Sheets("Sheet1").Activate

    ActiveSheet.Cells(7, 6).Select

    如何选择当前工作表中的单元格区域?

    例如,要选择当前工作表中的单元格区域C2:D10,可以使用下面的代码:

    ActiveSheet.Range(Cells(2, 3), Cells(10, 4)).Select

    或:ActiveSheet.Range("C2:D10").Select

    或:ActiveSheet.Range("C2", "D10").Select

    如何选择同一工作簿中另一工作表上的单元格区域?

    例如,要选择同一工作簿中另一工作表上的单元格区域D3:E11,可以使用下面的代码:

    Application.Goto ActiveWorkbook.Sheets("Sheet3").Range("D3:E11")

    或:Application.Goto ActiveWorkbook.Sheets("Sheet3").Range("D3", "E11")

    也可以先激活该工作表,然后再选择:

    Sheets("Sheet3").Activate

    ActiveSheet.Range(Cells(3, 4), Cells(11, 5)).Select

    如何选择不同工作簿中工作表上的单元格区域?

    例如,要选择另一工作簿中某工作表上的单元格区域E4:F12,可以使用下面的代码:

    Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("E4:F12")

    或:Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("E4", "F12")

    也可以先激活该工作表,然后再选择:

    Workbooks("BOOK2.XLS").Sheets("Sheet1").Activate

    ActiveSheet.Range(Cells(4, 5), Cells(12, 6)).Select

    如何在当前工作表中选择命名区域?

    例如,要选择当前工作表中名为“Test”的区域,可以使用下面的代码:

    Range("Test").Select

    或:Application.Goto "Test"

    如何选择同一工作簿中另一工作表上的命名区域?

    例如,选择同一工作簿中另一工作表上名为“Test”的区域,可使用下面的代码:

    Application.Goto Sheets("Sheet1").Range("Test")

    也可以先激活工作表,再选择:

    Sheets("Sheet1").Activate

    Range("Test").Select

    如何选择不同工作簿中工作表上的命名区域?

    例如,要选择不同工作簿中工作表上名为“Test”的区域,可使用下面的代码:

    Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet2").Range("Test")

    也可以先激活工作表,再选择:

    Workbooks("BOOK2.XLS").Sheets("Sheet2").Activate

    Range("Test").Select

    如何选择与当前单元格相关的单元格?

    例如,要选择距当前单元格下面5行左侧4列的单元格,可以使用下面的代码:

    ActiveCell.Offset(5, -4).Select

    要选择距当前单元格上方2行右侧3列的单元格,可以使用下面的代码:

    ActiveCell.Offset(-2, 3).Select

    注意:一定要保证当前单元格与所选单元格之间的距离在工作表范围内,否则会出错。

    如何选择与另一单元格(不是当前单元格)相关的单元格?

    例如,要选择距单元格C7下方5行右侧4列的单元格,可以使用下面的代码:

    ActiveSheet.Cells(7, 3).Offset(5, 4).Select

    或:ActiveSheet.Range("C7").Offset(5, 4).Select

    如何选择偏离指定区域的一个单元格区域?

    例如,要选择与名为“Test”的区域大小相同但在该区域下方4行右侧3列的一个区域,可以使用下面的代码:

    ActiveSheet.Range("Test").Offset(4, 3).Select

    如果该命名区域不在当前工作表中,可以先激活该工作表,然后再选择,如下面的代码:

    Sheets("Sheet3").Activate

    ActiveSheet.Range("Test").Offset(4, 3).Select

    如何选择一个指定的区域并扩展区域的大小?

    例如,要选择当前工作表中名为“Database”区域,然后将该区域向下扩展5行,可以使用下面的代码:

    Range("Database").Select

    Selection.Resize(Selection.Rows.Count + 5, Selection.Columns.Count).Select

    如何选择一个指定的区域,再偏离,然后扩展区域的大小?

    例如,选择名为“Database”区域下方4行右侧3列的一个区域,然后扩展2行和1列,可以使用下面的代码:

    Range("Database").Select

    Selection.Offset(4, 3).Resize(Selection.Rows.Count + 2, Selection.Columns.Count + 1).Select

    如何选择两个或多个指定区域?

    例如,为了同时选择名为“Test”和“Sample”的两个区域,可以使用下面的代码:

    Application.Union(Range("Test"), Range("Sample")).Select

    注意,这两个区域须在同一工作表中,如下面的代码:

    Set y = Application.Union(Range("Sheet1!A1:B2"), Range("Sheet1!C3:D4"))

    但Union方法不能处理不同工作表中的区域,可下面的代码:

    Set y = Application.Union(Range("Sheet1!A1:B2"), Range("Sheet2!C3:D4"))

    将会出错。

    如何选择两个或多个指定区域的交叉区域?

    例如,要选择名为“Test”和“Sample”的两个区域的交叉区域,可以使用下面的代码:

    Application.Intersect(Range("Test"), Range("Sample")).Select

    注意,两个区域必须在同一工作表中。

    = = = = = = = = = = = = = = = = = = = = = = = = =

    下面的示例使用了如下图所示的工作表。

     

    如何选择连续数据列中的最后一个单元格?

    例如,要选择一个连续列中的最后一个单元格,可以使用下面的代码:

    ActiveSheet.Range("a1").End(xlDown).Select

    该代码使用在上面的工作表中,单元格A4被选择。

    如何选择连续数据列底部的空单元格?

    例如,要选择连续单元格区域下面的单元格,可以使用下面的代码:

    ActiveSheet.Range("a1").End(xlDown).Offset(1, 0).Select

    该代码使用在上面的工作表中,单元格A5被选择。

    如何选择某列中连续数据单元格区域?

    例如,要选择一列中的连续数据单元格区域,可以使用下面的代码:

    ActiveSheet.Range("a1", ActiveSheet.Range("a1").End(xlDown)).Select

    或:ActiveSheet.Range("a1:" & ActiveSheet.Range("a1").End(xlDown).Address).Select

    该代码使用在上面的工作表中,单元格区域A1:A4将被选择。

    如何选择某列中非连续数据单元格区域?

    例如,要选择某列中非连续数据单元格区域,可以使用下面的代码:

    ActiveSheet.Range("a1", ActiveSheet.Range("a65536").End(xlUp)).Select

    或:ActiveSheet.Range("a1:" & ActiveSheet.Range("a65536").End(xlUp).Address).Select

    该代码使用在上面的工作表中,单元格区域A1:A6将被选择。

    如何选择一个矩形(规则的)单元格区域?

    要选择围绕某单元格的一个矩形区域,可以使用CurrentRegion方法。CurrentRegion方法将选择四周被空行和空列围绕的区域,如下面的代码:

    ActiveSheet.Range("a1").CurrentRegion.Select

    该代码使用在上面的工作表中,将选择单元格区域A1:C4。也可以使用下面的代码:

    ActiveSheet.Range("a1", ActiveSheet.Range("a1").End(xlDown).End(xlToRight)).Select

    或:

    ActiveSheet.Range("a1:" & ActiveSheet.Range("a1").End(xlDown).End(xlToRight).Address).Select

    若想选择单元格区域A1:C6,可使用下面的代码:

    lastCol = ActiveSheet.Range("a1").End(xlToRight).Column

    lastRow = ActiveSheet.Cells(65536, lastCol).End(xlUp).Row

    ActiveSheet.Range("a1", ActiveSheet.Cells(lastRow, lastCol)).Select

    或:

    lastCol = ActiveSheet.Range("a1").End(xlToRight).Column

    lastRow = ActiveSheet.Cells(65536, lastCol).End(xlUp).Row

    ActiveSheet.Range("a1:" & ActiveSheet.Cells(lastRow, lastCol).Address).Select

    = = = = = = = = = = = = = = = = = = = =

    如何选择多个不同长度的非连续列?

    例如,有下图所示的工作表:

     

    要同时选择A列和C列中的数据,即单元格区域A1:A3和C1:C6,可使用下面的代码:

    StartRange = "A1"

    EndRange = "C1"

    Set a = Range(StartRange, Range(StartRange).End(xlDown))

    Set b = Range(EndRange, Range(EndRange).End(xlDown))

    Union(a, b).Select

    = = = = = = = = = = = = = = = = = = = =

    注:使用Application.Goto方法,如果指定另一工作表(不是当前工作表)中的指定区域,在Range属性中使用两个Cells属性时,则必须包括Sheets对象,如:

    Application.Goto Sheets("Sheet1").Range(Sheets("Sheet1").Range(Sheets("Sheet1").Cells(2, 3), Sheets("Sheet1").Cells(4, 5)))

    = = = = = = = = = = = = = = = = = = = =

    在VBA中,Range 对象既可表示单个单元格,也可表示单元格区域。下面的内容说明了标识和处理Range对象最常用的方法。

    引用工作表上的所有单元格

    如果对工作表应用 Cells 属性时不指定索引号,该方法将返回代表工作表上所有单元格的 Range 对象。以下 Sub 过程清除活动工作簿中 Sheet1 上的所有单元格的内容。

    Sub ClearSheet()

    Worksheets("Sheet1").Cells.ClearContents

    End Sub

    使用 A1 表示法引用单元格和区域

    可使用 Range 属性引用 A1 引用样式中的单元格或单元格区域。下述子例程将单元格区域 A1:D5 的字体设置为加粗。

    Sub FormatRange()

    Workbooks("Book1").Sheets("Sheet1").Range("A1:D5") _

    .Font.Bold = True

    End Sub

    下表演示了使用 Range 属性的一些 A1 样式引用。

    引用 含义

    Range("A1") 单元格 A1

    Range("A1:B5") 从单元格 A1 到单元格 B5 的区域

    Range("C5:D9,G9:H16") 多块选定区域

    Range("A:A") A 列

    Range("1:1") 第一行

    Range("A:C") 从 A 列到 C 列的区域

    Range("1:5") 从第一行到第五行的区域

    Range("1:1,3:3,8:8") 第 1、3 和 8 行

    Range("A:A,C:C,F:F") A 、C 和 F 列

    引用行和列

    可用 Rows 属性或 Columns 属性来处理整行或整列。这两个属性返回代表单元格区域的 Range 对象。在下例中,Rows(1) 返回 Sheet1 上的第一行,然后将区域字体加粗。

    Sub RowBold()

    Worksheets("Sheet1").Rows(1).Font.Bold = True

    End Sub

    下表举例说明了使用 Rows 和 Columns 属性的一些行和列的引用。

    引用 含义

    Rows(1) 第一行

    Rows 工作表上所有的行

    Columns(1) 第一列

    Columns("A") 第一列

    Columns 工作表上所有的列

    若要同时处理若干行或列,可创建一个对象变量并使用 Union 方法,将对 Rows 属性或 Columns 属性的多个调用组合起来。下例将活动工作簿中第一张工作表上的第一行、第三行和第五行的字体设置为加粗。

    Sub SeveralRows()

    Worksheets("Sheet1").Activate

    Dim myUnion As Range

    Set myUnion = Union(Rows(1), Rows(3), Rows(5))

    myUnion.Font.Bold = True

    End Sub

    使用索引号引用单元格

    通过使用行列索引号,可用 Cells 属性引用单个单元格。该属性返回代表单个单元格的 Range 对象。在下例中,Cells(6,1) 返回 Sheet1 上的单元格 A6,然后将 Value 属性设置为 10。

    Sub EnterValue()

    Worksheets("Sheet1").Cells(6, 1).Value = 10

    End Sub

    因为可用变量替代编号,所以 Cells 属性非常适合于在单元格区域中循环,如下例中所示。

    Sub CycleThrough()

    Dim Counter As Integer

    For Counter = 1 To 20

    Worksheets("Sheet1").Cells(Counter, 3).Value = Counter

    Next Counter

    End Sub

    如果要同时更改某个区域中所有单元格的属性(或将方法应用于该区域中的所有单元格),建议使用 Range 属性。

    使用快捷表示法引用单元格

    可用方括号将 A1 引用样式或命名区域括起来,作为 Range 属性的快捷方式。这样就不必键入单词“Range”或使用引号了,如下例中所示。

    Sub ClearRange()

    Worksheets("Sheet1").[A1:B5].ClearContents

    End Sub

    Sub SetValue()

    [MyRange].Value = 30

    End Sub

    使用 Range 对象引用单元格

    如果将对象变量设置为 Range 对象,即可用变量名轻松地操作单元格区域。

    以下过程将创建对象变量 myRange,然后将活动工作簿中 Sheet1 上的区域 A1:D5 赋予该变量。随后的语句用该变量名称代替 Range 对象,以修改该区域的属性。

    Sub Random()

    Dim myRange As Range

    Set myRange = Worksheets("Sheet1").Range("A1:D5")

    myRange.Formula = "=RAND()"

    myRange.Font.Bold = True

    End Sub

    引用命名区域

    用名称比用 A1 样式记号更容易标识单元格区域。若要命名选定的单元格区域,请单击编辑栏左端的名称框,键入名称,再按 Enter。

    引用命名区域

    以下示例引用名为“MyBook.xls”的工作簿中名为“MyRange”的区域。

    Sub FormatRange()

    Range("MyBook.xls!MyRange").Font.Italic = True

    End Sub

    以下示例引用名为“Report.xls”的工作簿中特定于工作表的区域“Sheet1!Sales”。

    Sub FormatSales()

    Range("[Report.xls]Sheet1!Sales").BorderAround Weight:=xlthin

    End Sub

    要选定命名区域,可使用 GoTo 方法,该方法将激活工作簿和工作表,然后选定该区域。

    Sub ClearRange()

    Application.Goto Reference:="MyBook.xls!MyRange"

    Selection.ClearContents

    End Sub

    以下示例显示对于活动工作簿将如何编写与上例相同的过程。

    Sub ClearRange()

    Application.Goto Reference:="MyRange"

    Selection.ClearContents

    End Sub

    在命名区域中的单元格上循环

    下例用 For Each...Next 循环语句在命名区域中的每一个单元格上循环。如果该区域中的任一单元格的值超过 limit 的值,就将该单元格的颜色更改为黄色。

    Sub ApplyColor()

    Const Limit As Integer = 25

    For Each c In Range("MyRange")

    If c.Value > Limit Then

    c.Interior.ColorIndex = 27

    End If

    Next c

    End Sub

    引用多个区域

    使用适当的方法可以很容易地同时引用多个单元格区域。可用 Range 和 Union 方法引用任意组合的单元格区域;用 Areas 属性可引用工作表上选定的一组单元格区域。

    使用 Range 属性

    通过在两个或多个引用之间插入逗号,可使用 Range 属性引用多个区域。以下示例清除了 Sheet1 上三个区域的内容。

    Sub ClearRanges()

    Worksheets("Sheet1").Range("C5:D9,G9:H16,B14:D18"). _

    ClearContents

    End Sub

    命名区域使得用 Range 属性处理多个区域更加容易。以下示例可在所有这三个命名区域处于同一工作表时运行。

    Sub ClearNamed()

    Range("MyRange, YourRange, HisRange").ClearContents

    End Sub

    使用 Union 方法

    使用 Union 方法可将多个区域组合到一个 Range 对象中。以下示例创建了名为 myMultipleRange 的 Range 对象,并将其定义为区域 A1:B2 和 C3:D4 的组合,然后将该组合区域的字体设置为加粗。

    Sub MultipleRange()

    Dim r1, r2, myMultipleRange As Range

    Set r1 = Sheets("Sheet1").Range("A1:B2")

    Set r2 = Sheets("Sheet1").Range("C3:D4")

    Set myMultipleRange = Union(r1, r2)

    myMultipleRange.Font.Bold = True

    End Sub

    使用 Areas 属性

    可用 Areas 属性引用选定的单元格区域或多块选定区域中的区域集合。下述过程计算选定区域中的块数目,如果有多个块,就显示一则警告消息。

    Sub FindMultiple()

    If Selection.Areas.Count > 1 Then

    MsgBox "不能对多个选区进行操作."

    End If

    End Sub

    处理三维区域

    如果要处理若干工作表上相同位置的单元格区域,可用 Array 函数选定两张或多张工作表。下例设置三维单元格区域的边框格式。

    Sub FormatSheets()

    Sheets(Array("Sheet2", "Sheet3", "Sheet5")).Select

    Range("A1:H1").Select

    Selection.Borders(xlBottom).LineStyle = xlDouble

    End Sub

    下例应用 FillAcrossSheets 方法,将 Sheet2 上的区域中的格式和所有数据传送到活动工作簿中所有工作表上的相应区域。

    Sub FillAll()

    Worksheets("Sheet2").Range("A1:H1") _

    .Borders(xlBottom).LineStyle = xlDouble

    Worksheets.FillAcrossSheets (Worksheets("Sheet2") _

    .Range("A1:H1"))

    End Sub

    展开全文
  • Excel宏 取得sheet中最后一行的行号

    万次阅读 2012-08-31 09:49:18
    近日用到Excel宏,需要取得最后一行的行号,从网上找了找,方法很多,以下这个方法出自CSDN论坛帖子, 方法很简单,而且可以正常统计隐藏行(这个是关键!) n = ActiveSheet.UsedRange.Rows.Count a = ...
  • 网上找EXCEL多文件合并的方法,思路: 、Linux 或者window+cmder,直接用命令行cat合并EXCEL文件,但是,需要安装辅助东西才能直接处理(也许也不可以,但是,可以用文件格式转换工具转换是可行的,把EXCEL文件...
  • 浅谈VBA使用数组处理工作表数据

    千次阅读 2018-02-28 12:55:53
    这时经常用到的解决方法就是使用数组保存数据,内存进行数据处理和加工,最后一更新工作表,这样的操作方式往往会极大提升程序的运行效率。 读取数据 声明变量 首先如何声明用于保存单元格内容的...
  • oracle的伪和伪

    千次阅读 2017-01-23 16:13:56
    oracle的伪以及伪 ... oracle系统为了实现完整的关系数据库功能,系统专门提供了组成为伪(Pseudocolumn)的数据库,这些不是建立对象时由我们完成的,而是我们建立时由Oracle完成的。Ora
  • VBA单元格、工作表、工作簿

    千次阅读 2019-04-30 23:08:35
    详解VBA单元格、工作表、工作簿各种表示、方法,注意事项。
  • EXCEL如何获得工作表(sheet)的名称

    万次阅读 2018-05-11 14:12:23
    excel 取得工作表名2009-08-11 15:38方法 常规方法 cell函数 也可以这样取得工作表名,在任单元格输入:=RIGHT(CELL("filename"),LEN(CELL("filename"))-FIND("]",CELL("...
  • Python使用openpyxl和xlrd创建个新Excel并把原表格数据复制到新表中 新的开始 文科出生,经济学专业,年近四旬,纯粹是把这个当成个兴趣在学。很早之前就打算学Python,但是一直停留安装好Python,这几天...
  • 表格拆分的两种方式 拆分成多个excel工作表或多个excel文件 拆分Excel,可以分为3种层次:拆分excel单元格;拆分成多个excel工作表;拆分成多个excel文件 其中,第1种拆分是无法完成的,因为单元格是excel的最小...
  • Excel求最后一行的代码和公式

    千次阅读 2009-01-08 09:19:00
    Excel求最后一行的代码和公式×××××××××××××××××××××××××××××××××××××××求最后一行的代码:Sub ls()a = [b65536].End(xlUp).Row‘application.ExecuteExcel4Macro("get....
  • 您可以Excel工作表中活动单元格的上方左侧插入空白单元格,同时将同一列中的其他单元格下移将同一行中的其他单元格右移。同样,您可以在一行的上方插入多行和一列的左边插入多列。您还可以删除单元格、行和...
  • 使用VBA将Excel工作表分割成多个文件

    万次阅读 2015-11-04 12:02:08
    这里需要按城市(即B数据)对表格进行拆分,拆分出多个以城市名称命名的xlsx文件,每个xlsx文件都只包含当前城市的数据。  相关资料 之前没有接触过Excel相关的编程,也没有学习过VB语言,完全是摸着...
  • 数据来源之工作簿——智能提取汇总指定文件夹下的工作簿数据 要求:根据指定目录的文件夹内的所有工作薄进行汇总分析。 工资下每个年份每个部门1-12月的工资此维护,现在的要求是要看看每个年份,每个月一共发了...
  • .net/c#得到EXCEL表格的行数(有效)和数   找了很久,谢谢     每种方法上面的是Excel的行数,下面的是Excel的数。 方法七:经过加工修改已经可以读出来的是有效数据 方法1:  ActiveSheet....
  • VBA取得EXCEL表格的行数和

    千次阅读 2019-07-25 15:50:41
    VBA取得EXCEL表格的行数和数 请注意不要使用Columus等关键字作为变量,例如"Columus = ActiveSheet.UsedRange.Columns.Count"! 初学EXCEL宏的童鞋,总是很想知道表格含有数据的行数和数,尤其是行数和数...
  • 按键精灵---之工作表数据提取示例

    千次阅读 2010-05-08 14:35:00
    1. http://bbs.yyvcr.cn/read.php?tid=29工作表数据提取示例(按键精灵版) 条件是这样的:d:/盘下有工作表"1.xls",里面记录了一些用户的资料:姓名和密码。现在我,我们需要软件或者网页上提交登陆。用途:可以...
  • 使用 Excel 2003 工作表的 VBA 示例

    千次阅读 2004-11-05 17:14:00
    适用范围:Microsoft Office Excel 2003摘要:寻找能够为 Excel 工作表增加额外功能的宏。只需稍加练习,您就可以扩展这些程序,使其适合您自己的应用程序。 本页内容引言导出带有逗号和引号分隔符的文本文件计算...
  • 存储、存储

    万次阅读 2013-02-26 13:24:24
    Sybase2004年左右就推出了存储的Sybase IQ数据库系统,主要用于在线分析、数据挖掘等查询密集型应用。存储,缩写为DSM,相对于NSM(N-ary storage model),其主要区别在于: DSM将所有记录相同字段的数据...
  • 用VBA得到EXCEL表格的行数和数  每种方法上面的是Excel的行数,下面的是Excel的数。方法七:经过加工修改已经可以读...缺点:有时可能会比实际数大一些,原因是如果你把最后几行()数据清除后(非整行
  • 每种方法上面的是Excel的行数,下面的是Excel的... 缺点:有时可能会比实际数大一些,原因是如果你把最后几行()数据清除后(非整行整列删除),用这个命令仍返回未清除前的值。就是说现在虽然是空的,但是你曾
  • 用vi删除某一列

    千次阅读 2018-08-06 17:47:28
    vi 如何一次删除多?  如:  123aaaaa  !@#aaaaa  ABCaaaaa  +-/aaaaa  vi 如何一次删除前 3 呢? 最简单的方法: ...具体讲,光标先移动到第一行,第一,然后按ctrl + v, 然后把...
  • 对于普通使用者而言,Excel是个比较强大的数据处理工具。一般公司的普通职员常使用它来完成数据的...因此分析数据之前首先需要将多个.xlsx内的数据合并,再去除重复项,最后进行汇总分析才能得到相对准确的分析结
  • Oracle中表的几种类型

    千次阅读 2016-08-04 20:17:27
    的功能:存储、管理数据的基本单元(二维:有组成) 2、的类型: 1)堆:heap table :数据存储时,是无序的,对它的访问采用全扫描。 2)分区 >2G 3)索引组织(IOT) 4)簇 5)...
  • 找出两张表中匹配的记录

    千次阅读 2007-02-15 02:57:00
    工作中要维护一张,这张表根据另个部门发过来的Excel文件更新。每次发过来的Excel文件跟我当前相比,或者多了几条记录,或者少了几条记录。减少的记录我不用删除,因为我的是个历史记录,新增的记录我要...
  • 篇文章(Visual Web应用程序使用Java Persistence API) ,您已了解了如何使用Java Persistence API访问数据库和检索其中的数据,以及如何使用Visual Web Table组件显示该数据。本文,我将介绍...

空空如也

空空如也

1 2 3 4 5 ... 20
收藏数 182,755
精华内容 73,102
关键字:

在当前工作表中的最后一行或列中