精华内容
下载资源
问答
  • Win10镜像集成离线补丁 因为正常安装系统后再打补丁比较漫长,可以事先做好打过补丁的iso,备将来使用。 以管理员身份运行cmd,然后通过dism提取、挂载、集成补丁、保存install.wim镜像,最后用iso工具替换即可。 ...
    Win10镜像集成离线补丁
    因为正常安装系统后再打补丁比较漫长,可以事先做好打过补丁的iso,备将来使用。
    以管理员身份运行cmd,然后通过dism提取、挂载、集成补丁、保存install.wim镜像,最后用iso工具替换即可。
    
    独立补丁下载:
    最新的Win10 1607和Windows Server 2016补丁信息:
    https://support.microsoft.com/en-us/help/4000825/windows-10-windows-server-2016-update-history
    最新的Win10 1703补丁信息:
    https://support.microsoft.com/en-us/help/4018124
    选择一个最新的补丁(在最上方)后,点击页面内容里的Microsoft Update Catalog链接
        How to get this update
        ----------------------
        To get the standalone package for this update, go to the _Microsoft Update Catalog_ website.
    下载累计更新。
    
    补丁查询页面:
    http://www.catalog.update.microsoft.com/home.aspx
    
    制作集成补丁的iso详细步骤:
    1. 查看镜像源install.wim的索引号
    先将iso文件载入虚拟光驱,这里是G:盘,执行下面命令
    C:\>dism /get-imageinfo /imagefile:G:\sources\install.wim
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Details for image : G:\sources\install.wim
    
    Index : 1
    Name : Windows 10 企业版 2016 长期服务版
    Description : Windows 10 企业版 2016 长期服务版
    Size : 12,555,951,804 bytes
    
    The operation completed successfully.
    
    2. 提取镜像源install.wim加索引的镜像到本地磁盘install_exp.wim
    下面提取命令成功后,就可以弹出虚拟光驱了。
    C:\>dism /export-image /sourceimagefile:G:\sources\install.wim /sourceindex:1 /destinationimagefile:D:\install_exp.wim
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Exporting image
    [==========================100.0%==========================]
    The operation completed successfully.
    
    3. 挂载install_exp.wim到一个文件夹
    注意:被挂在的目标文件夹不能是ReFS文件系统
    C:\>mkdir D:\mount
    C:\>dism /mount-wim /wimfile:D:\install_exp.wim /index:1 /mountdir:D:\mount
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Mounting image
    [==========================100.0%==========================]
    The operation completed successfully.
    
    4. 将要被集成的补丁文件,集中放到一个文件夹里
    这里假设在D:\package
    
    5. 应用补丁到挂载文件夹(时间较长)
    C:\>dism /image:D:\mount /add-package /packagepath:D:\package
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Image Version: 10.0.14393.0
    
    Processing 1 of 1 - Adding package D:\package\windows10.0-kb4039396-x64_bd1f9e1c7add02b8f3334f1aeaa07cae6632c3cf.msu
    [==========================100.0%==========================]
    The operation completed successfully.
    
    6. 清理镜像WinSxS,清理后会减少体积,但将不能卸载集成过的补丁(时间较长,可跳过)
    C:\>dism /image:D:\mount /cleanup-image /startcomponentcleanup /resetbase
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Image Version: 10.0.14393.0
    
    [==========================100.0%==========================]
    The operation completed successfully.
    
    7. 卸载镜像保存修改(时间较长)
    C:\>dism /unmount-wim /mountdir:D:\mount /commit
    
    Deployment Image Servicing and Management tool
    Version: 10.0.14393.0
    
    Image File : D:\install_exp.wim
    Image Index : 1
    Saving image
    [==========================100.0%==========================]
    Unmounting image
    [==========================100.0%==========================]
    The operation completed successfully.
    
    8. 制作ISO
    1) 用imagex将这个wim最大化压缩导出新的install.wim
    注:如果没有imagex,可以直接把install_exp.wim重命名为install.wim,但是文件会比较大。
    C:\>imagex /export D:\install_exp.wim 1 D:\install.wim /compress maximum
    
    ImageX Tool for Windows
    Copyright (C) Microsoft Corp. All rights reserved.
    Version: 6.3.9600.16384
    
    Exporting: [D:\install_exp.wim, 1] ->
               [D:\install.wim]
    
    
    [ 100% ] Exporting progress
    
    Successfully exported image #1.
    
    
    Total elapsed time: 59 sec
    
    2) 将原ISO复制一份出来。假设新iso命名为cn_windows_10_enterprise_2016_ltsb_x64_with_kb4039396.iso
    3) 用UltraISO等工具将install.wim替换到新iso文件sources下同名文件,保存完成。
    ----------
    说明:如果不用UltraISO,可以使用微软官方的Windows ADK工具(完整的的Windows 8.1版本有4.1GB)
    其中的oscdimg命令可以制作iso
    命令帮助:https://technet.microsoft.com/zh-cn/library/cc749036(v=ws.10).aspx
    ADK介绍:https://msdn.microsoft.com/zh-cn/library/hh825420.aspx
    ADK下载页面:http://go.microsoft.com/fwlink/?LinkId=293840
    下面是离线下载Windows ADK的方法:
    1. 首先到下载页面下载到最新的Windows ADK安装在线安装程序adksetup.exe
    2. 在cmd下离线下载
    C:\>adksetup.exe /layout D:\adk
    也可以按功能安装,详细见 https://msdn.microsoft.com/zh-cn/library/hh825494.aspx
    
    ----------
    制作install.wim合集
    以Windows Server 2016为例,MSDN版本包含了4个镜像。
    在分别制作好wim文件,注意用imagex按相同的压缩方式(建议/compress maximum)导出4个wim,假设为:
    install1.wim
    install2.wim
    install3.wim
    install4.wim
    合并命令:
    C:\>dism /Export-Image /SourceImageFile:D:\install1.wim /SourceIndex:1 /DestinationImageFile:D:\install.wim
    C:\>dism /Export-Image /SourceImageFile:D:\install2.wim /SourceIndex:1 /DestinationImageFile:D:\install.wim
    C:\>dism /Export-Image /SourceImageFile:D:\install3.wim /SourceIndex:1 /DestinationImageFile:D:\install.wim
    C:\>dism /Export-Image /SourceImageFile:D:\install4.wim /SourceIndex:1 /DestinationImageFile:D:\install.wim
    全部合并到install.wim,替换iso,完成。
    

     

    patchwim.bat

    ::patchwim.bat sourceWim index packagePath mountPath outputPath [/nointeraction]
    ::patchwim.bat g:\sources\install.wim 1 D:\package D:\mount D:\output
    @echo off
    pushd %~dp0
    set sourceWim="%~1"
    set index=%2
    set packagePath="%~3"
    set mountPath="%~4"
    set outputPath=%~5
    set nointeraction=%6
    set outputWim="%outputPath%\install_%index%.wim"
    set outputWimFinal="%outputPath%\install%index%.wim"
    echo sourceWim: %sourceWim%
    echo index: %index%
    echo packagePath: %packagePath%
    echo mountPath: %mountPath%
    echo outputPath: "%outputPath%"
    echo outputWim: %outputWim%
    echo outputWimFinal: %outputWimFinal%
    if "%outputPath%"=="" goto :help
    if not exist %packagePath% goto :err1
    if /i "%nointeraction%"=="/nointeraction" goto :start
    set /p tmpInput=Are you ready? (Y/N):
    if /i "%tmpInput%"=="y" goto :start
    goto :eof
    :start
    if not exist %mountPath% md %mountPath%
    if not exist "%outputPath%" md "%outputPath%"
    
    echo dism /export-image /sourceimagefile:%sourceWim% /sourceindex:%index% /destinationimagefile:%outputWim%
    dism /export-image /sourceimagefile:%sourceWim% /sourceindex:%index% /destinationimagefile:%outputWim%
    if errorlevel 1  goto :error
    
    echo dism /mount-wim /wimfile:%outputWim% /index:1 /mountdir:%mountPath%
    dism /mount-wim /wimfile:%outputWim% /index:1 /mountdir:%mountPath%
    if errorlevel 1  goto :error
    
    echo dism /image:%mountPath% /add-package /packagepath:%packagePath%
    dism /image:%mountPath% /add-package /packagepath:%packagePath%
    if errorlevel 1  goto :error
    
    echo dism /image:%mountPath% /cleanup-image /startcomponentcleanup /resetbase
    dism /image:%mountPath% /cleanup-image /startcomponentcleanup /resetbase
    if errorlevel 1  goto :error
    
    echo dism /unmount-wim /mountdir:%mountPath% /commit
    dism /unmount-wim /mountdir:%mountPath% /commit
    if errorlevel 1  goto :error
    
    echo imagex /export %outputWim% 1 %outputWimFinal% /compress maximum
    imagex /export %outputWim% 1 %outputWimFinal% /compress maximum
    if errorlevel 1  goto :error
    
    del /q %outputWim%
    echo Completed.
    goto :end
    
    :error
    echo ERRORLEVEL: %ERRORLEVEL%
    goto :end
    
    :err1
    echo ERROR: The packagePath(%packagePath%) is not exist!
    goto :end
    
    :help
    echo.
    echo Usage:
    echo     patchwim.bat sourceWim index packagePath mountPath outputPath [/nointeraction]
    echo     /nointeraction: No interaction
    echo Example:
    echo     (1) patchwim.bat g:\sources\install.wim 1 D:\package D:\mount D:\output
    echo     (2) autopatch.bat:
    echo         patchwim.bat g:\sources\install.wim 1 D:\package D:\mount D:\output /nointeraction
    echo         patchwim.bat g:\sources\install.wim 2 D:\package D:\mount D:\output /nointeraction
    echo         patchwim.bat g:\sources\install.wim 3 D:\package D:\mount D:\output /nointeraction
    echo         patchwim.bat g:\sources\install.wim 4 D:\package D:\mount D:\output /nointeraction
    echo.
    
    :end
    if /i "%nointeraction%"=="/nointeraction" goto :eof
    echo Press any key to EXIT...
    pause>nul
    popd

     

    patchwimall.bat

    ::patchwimall.bat sourceWim packagePath mountPath outputPath [/nointeraction]
    ::patchwimall.bat g:\sources\install.wim D:\package D:\mount D:\output
    @echo off
    pushd %~dp0
    set patchwim=patchwim.bat
    set sourceWim="%~1"
    set packagePath="%~2"
    set mountPath="%~3"
    set outputPath=%~4
    set nointeraction=%5
    for /f "delims=: tokens=2" %%a in ('imagex /info %sourceWim%^|find /i "Image Count:"') do set imageCount=%%a
    set outWim="%outputPath%\install.wim"
    echo sourceWim: %sourceWim%
    echo imageCount: %imageCount%
    echo packagePath: %packagePath%
    echo mountPath: %mountPath%
    echo outputPath: "%outputPath%"
    echo outWim: %outWim%
    if "%outputPath%"=="" goto :help
    if not exist %packagePath% goto :err1
    if not exist %patchwim% goto :err2
    if /i "%nointeraction%"=="/nointeraction" goto :start
    set /p tmpInput=Are you ready? (Y/N):
    if /i "%tmpInput%"=="y" goto :start
    goto :eof
    :start
    for /l %%a in (1,1,%imageCount%) do (
        call %patchwim% %sourceWim% %%a %packagePath% %mountPath% "%outputPath%" /nointeraction
    )
    if %imageCount% equ 1 goto :rename
    for /l %%a in (1,1,%imageCount%) do (
        dism /Export-Image /SourceImageFile:"%outputPath%\install%%a.wim" /SourceIndex:1 /DestinationImageFile:%outWim%
    )
    goto :complete
    :rename
    move /y "%outputPath%\install1.wim" %outWim%
    goto :complete
    :complete
    echo All Completed! ImageInfo:
    dism /get-imageinfo /imagefile:%outWim%
    goto :end
    
    :err1
    echo ERROR: The packagePath(%packagePath%) is not exist!
    goto :end
    
    :err2
    echo ERROR: %patchwim% is not found!
    goto :end
    
    :help
    echo.
    echo Usage:
    echo     patchwimall.bat sourceWim packagePath mountPath outputPath [/nointeraction]
    echo     /nointeraction: No interaction
    echo Example:
    echo     patchwimall.bat g:\sources\install.wim D:\package D:\mount D:\output
    echo.
    
    :end
    if /i "%nointeraction%"=="/nointeraction" goto :eof
    echo Press any key to EXIT...
    pause>nul
    popd

     

    转载于:https://www.cnblogs.com/Bob-wei/p/7477780.html

    展开全文
  • Windows 10 离线下载与离线安装补丁教程 支持批量安装(其他win系统类似)离线下载与安装补丁从微软官网下载离线补丁离线补丁安装批量自动安装补丁步骤 加粗样式 离线下载与安装补丁 由于客户端获取不到wsus补丁...

    Windows server 2016 & Windows 10 离线下载与离线安装补丁教程 支持批量安装(其他win系统类似)


    加粗样式

    离线下载与安装补丁

    由于客户端获取不到wsus补丁服务器的补丁,所以暂时选择用离线下载补丁包,手动安装补丁,我这里主要针对Windows server 2016 && Windows 10 (公司系统都要求升级到了2016 和 win10)

    从微软官网下载离线补丁包

    微软官网补丁地址:

    http://www.catalog.update.microsoft.com/Home.aspx

    在这里插入图片描述或者你可以在url上直接加上要搜索的补丁的编号:(链接如下)

    http://www.catalog.update.microsoft.com/Search.aspx?q=KB4103720

    一般会下载到多种后缀的补丁包文件:如msu、exe等等

    离线补丁安装

    将下载好的补丁,双击打开运行及可
    

    批量自动安装补丁

    在这里呢是使用一个批处理脚本来完成的,当然可以使用其他的语言脚本来完成。

    这里主要使用自带的dism命令(可自行百度该命令用法)

    步骤

    1、把离线补丁存放到一个文件夹(作者这使用:D:\WSUS)

    2、新建一个bat文件,在里面输入:
    dism /online /add-package /packagepath:D:\WSUS

    3、管理员方式运行、等待漫长的时间。

    4、更新完需要重启则会提示,直接保存现编辑文件重启即可!

    5、在设置中查看是否添加了你安装的补丁!!!

    展开全文
  • 尽管如此,在国产操作系统未成气候,Win8、Win10等系统因为保密系统等一系列原因无法使用的情况下,尽可能的对Win7系统修修补补,在物理隔离之外提供更多的防护,是每一个对自己工作待遇比较满意的运维工程师该有的...

    很多单位(政府、军队、敏感领域国企等),由于各种原因(主要是出于保密需要),构建了与互联网物理隔离的办公用网络,并在网络内大量使用装有盗版Win7系统的办公电脑。2020年1月14日,微软已经官方官方宣布放弃Win7系统(安全更新之类的外延支持全部停止)。尽管如此,在国产操作系统未成气候,Win8、Win10等系统因为保密系统等一系列原因无法使用的情况下,尽可能的对Win7系统修修补补,在物理隔离之外提供更多的防护,是每一个对自己工作待遇比较满意的运维工程师该有的追求。
    据我有限的统计,用内网办公的单位,联网的计算机和硬盘基本上都饱受各种病毒的摧残。电脑越用越慢越来越卡是常态。在大多数人电脑知识仅限于不熟练使用各种办公软件的情况下,对运维而言而最省事的解决方法就是重装。但重装显然是治标不治本的解决方案,很多病毒实际上是在移动硬盘中或者是办公网服务器中的,没安装杀毒软件或者没及时更新系统漏洞的电脑中招是迟早的事。许多内网办公单位的另一个特点,就是领导不懂或者不重视单位的信息化建设,对办公网和电脑的要求就是能用就行,以至于很多单位没有预算或者无力支持一套补丁分发系统和反病毒系统。更新杀毒软件和给系统安装补丁的任务自然就落在了运维人员的头上。
    一、补丁获取
    获取补丁的方式比较多,最直接的就是去微软官网去寻找和下载(需要用到互联网电脑,且下载起来费时费力)。个人推荐用360安全卫士或者其他有补丁下载和安装功能的管家类软件,找一台能连接互联网的破电脑用单位常用的镜像重装系统之后下载补丁,找到软件存放补丁的路径然后将补丁复制出来。大部分补丁的后缀名为.cab,少数为.exe。
    二、补丁分发
    在没有补丁分发系统的情况下,我是没能找到好的能利用办公网推送补丁的方案,最多只能建个FTP站点然后通知各单位自行下载。
    三、补丁安装
    对于下载到电脑中的补丁,没法用Windows Update自动更新,需要手动进行安装。
    首先以管理员身份运行命令提示行。然后在命令提示行中键入以下命令:
    dism.exe /online /add-package /packagepath:d:\patch /ignorecheck
    注意:/packagepath参数后应填入补丁在电脑中存放的路径,建议建立一个文件夹(最好英文命名),把所有补丁放在里面,然后放在非系统盘根目录下(方便写路径)。
    按下回车后系统便开始安装下载好的补丁。
    四、补充说明
    为便于更新多台电脑的操作,可以将命令输入记事本中,路径统一填D:\Patch,然后将保存的文本文件后缀名改成.bat(编码要选ASCII码),在把这个文件跟所有补丁文件放在Patch文件夹内然后打包压缩。目标电脑直接将压缩包下载到电脑D盘,解压到当前文件夹后只需双击批处理文件即可,能够有效减少工作量。
    DISM.exe命令中如果有参数不清楚用法和功能,可以用/?来查询。
    如果电脑比较老旧应注意防止死机问题(一共115个补丁一口气安装结果到第55个的时候死机了,真的是哭,后来分了3批才顺利装完)。

    展开全文
  • 解决win7 离线安装IE10 IE11 32位 64位 安装需要更新问题,安装内部补丁包,轻松离线安装IE10 IE11,解决IE浏览问题
  • ie10离线安装包

    2018-04-25 11:05:25
    ie10 win7 64独立离线安装包说明: 1、整合安装IE10所必需的补丁,可独立离线安装; 2、禁止勾选IE10自动安装新版本; 3、禁止首次运行IE10弹出自定义设置对话框。 版本:10.0.9200.16521 更新版本:RTM(KB2718695...
  • IE10-Win7-X64离线

    2020-08-28 16:10:46
    IE10浏览器独立离线安装包(ie10中文版win7 64位)已经整合安装IE10所必需的补丁(KB2729094、KB2731771、KB2533623、KB2670838),可独立离线安装,安装时不会提示需要更新。有2345捆绑插件,安装时注意不要勾选
  • IE11离线安装包,集成了安装所必须的更新补丁,集成了简体中文语言包,可选调整优化,支持静默安装,真正实现断网离线安装。提供了18条调整优化项都是安全、稳定、可靠的,经大量测试实践真正稳定可用,即装即用,...
  • IE11_for_Win7_x64离线安装包

    千次下载 热门讨论 2016-10-17 10:44:03
    IE11离线安装包,集成了安装所必须的更新补丁,集成了简体中文语言包,可选调整优化,支持静默安装,真正实现断网离线安装。提供了18条调整优化项都是安全、稳定、可靠的,经大量测试实践真正稳定可用,即装即用,...
  • Windows 10 离线下载与离线安装补丁教程 支持批量安装(其他win系统类似) 上面这个链接中描述的比较详细。 以下是我的记录: 在设置 -> windows 更新中检查更新,可以看到补丁包的代号. 之后在Microsoft ...

    参考链接:
    Windows server 2016 & Windows 10 离线下载与离线安装补丁教程 支持批量安装(其他win系统类似)

    上面这个链接中描述的比较详细。

    以下是我的记录:

    在设置 -> windows 更新中检查更新,可以看到补丁包的代号.
    在这里插入图片描述

    之后在Microsoft update catalog 中搜索代号,然后对照系统类型以及补丁包名称,下载补丁包。

    在这里插入图片描述
    之后双击运行即可安装。

    展开全文
  • 双击脚本即可自动修补WIN7 IE9升级IE10或IE11时所需要在线下载的系统补丁,此脚本完全自动化,修复系统补丁后重启电脑,会自动修复系统漏洞,重启完毕后,再点击IE10或IE11安装包即可安装IE11正常情况不会弹出需要...
  • 最新版cuda9.1.85 for win10离线下载包,官网早就被封了根本下载不下来。附有cuda_9.1.85.1_windows补丁
  • 非常好用的一款win10 1703精简版

    千次阅读 2019-01-19 10:45:00
    介绍 非常优秀的精简系统,精简处理的非常专业,最大化接近原版系统,绝大部分无用的...Win10 1703 x64 msdn原盘,全部离线精简,全部为组件方式或者dism命令移除,可以直接打任何升级补丁,不存在过度精简无法...
  • ie10 win7 64独立离线安装包说明: 1、整合安装IE10所必需的补丁,可独立离线安装; 2、禁止勾选IE10自动安装新版本; 3、禁止首次运行IE10弹出自定义设置对话框。 版本:10.0.9200.16521 更新版本:RTM(KB2718695...
  • 现在升级win10系统后,原来运行在.net framework2.0或3.0程序组件下的程序运行不了,因系统默认为.Net framework4.5,这就需要我们手动安装.net framework2.0或3.0 1. 把所有补丁放进一个文件夾 2. 在开始>右键>...
  • UpdatePack 7,由俄罗斯人Simplix制作的Windows 7 更新补丁安装包,Win7累积更新离线安装包,整合所有关键更新和安全更新及NVMe/USB3.0驱动,使用它可以将累积更新封装到Install.wim映像文件内,支持Windows 7 SP1和...
  • 【Windows7SP1补丁包 (64位)概括介绍】 ...Windows7SP1补丁包(Win7补丁汇总)更新到2013年10月最新。包含Windows7SP1中文版所有重要补丁,可离线安装,适用于Windows 7 SP1 32位简体中文系统。包含Internet Explore
  • 【Windows7SP1补丁包 (32位)概括介绍】 ...Windows7SP1补丁包(Win7补丁汇总)更新到2013年10月最新。包含Windows7SP1中文版所有重要补丁,可离线安装,适用于Windows 7 SP1 32位简体中文系统。包含Internet Explore
  • 授人以鱼不如授人以渔. 这是一个开放源代码的批处理版的离线更新汇总包. ...1.喜欢在原版上安装更新,又觉得在线更新检测起来太慢...汇总了至发布日 99%的必要补丁(Win10推广和隐私获取的除外). 由于微软官方五月
  • 母版来自MSDN WIN10_20H2.19042.928,集成补到19042.964,20H2相比1909 2004版本要稳定很多,此版修复了上次的一些问题,精简方法基本上还是原来配方,为了保证稳定初心的系统全部都是离线精简和优化,非二次封装。...
  • 母版来自MSDN WIN10_20H2.19042.508,集成补到19042.662,20H2相比1909 2004版本要稳定很多,此版修复了上次的一些问题,精简方法基本上还是原来配方,为了保证稳定初心的系统全部都是离线精简和优化,非二次封装。...
  • 母版来自MSDN WIN10_20H2.19042.508,集成补到19042.610,20H2相比1909 2004版本要稳定很多,此版修复了上次的一些问题,应微软毒.粉的要求新增一版带Defender的版本,精简方法基本上还是原来配方,为了保证稳定初心...
  • 母版来自MSDN WIN10_21H1.19043.928正式版,集成补到19044.985,精简方法基本上还是原来配方,为了保证稳定初心的系统全部都是离线精简和优化,非二次封装。系统纯净、流畅、进程少无任何第三方软件,可正常更新补丁...
  • 微软已停止了IE11以下版本(包括IE10/9/8)的技术支持。以后Win7用IE11的机会也越来越多,但IE11官方安装包的安装是一件很抓狂的事。微软的IE官方包其实并不是离线安装包,安装前须下载先决更新,否则拒绝安装。若断网...
  • tensorflow-gpu配置

    2021-03-03 18:45:27
    win10 GEFORCE GTX1050Ti Inter® Core™ i5-7300HQ CPU 二、下载准备 1.更新显卡驱动 点此更新 搜索下载并安装 2显卡设置 . 下载VS2015社区版 点此下载 下载cuda9.0.176;选择local离线安装包;下载 Patch 1 ...
  •  屏幕翻录一直是视频产品被盗版的最大威胁之一,China-DRM推出的智能防屏录功能可以有效避免视频被翻录盗版的危险,加密视频播放时会智能分析客户电脑内所有进程的动态行为和操作,在播放后的3-10分钟内即可做出...
  • 基于新一代多媒体加密技术,更高安全性、支持WIN7;通过国内某安全组织三防一免认证: 防破解: 加密后的视频,用户无法绕过播放密码! 防提取: 加密后的视频用户无法提取到原始视频文件; 防劫持: 防止各种Dll...
  • 金盾视频加密器

    2014-01-07 22:52:05
    可以加密各种视频音频格式文件(wmv,avi,asf,mpg,rm,rmvb,mp4,flv,mp3,vob,mov,mkv,mpeg,dat等等其他各种音频视频格式,只要装上相关解码器可以支持所有视频格式),加密后的文件可以通过离线方式授权播放,也可以...
  • CVE-2019-0803 Win32k漏洞提权工具 脏牛Linux提权漏洞-reverse_dirty-更改的脏牛提权代码,可以往任意文件写入任意内容 远控免杀从入门到实践之白名单(113个)|远控免杀从入门到实践之白名单(113个)总结篇.pdf...
  • asp.net知识库

    2015-06-18 08:45:45
    技术基础 New Folder 多样式星期名字转换 [Design, C#] .NET关于string转换的一个小Bug Regular Expressions 完整的在.net后台执行javascript脚本集合 ASP.NET 中的正则表达式 常用的匹配正则表达式和实例 ...

空空如也

空空如也

1 2
收藏数 30
精华内容 12
关键字:

win10离线补丁