循环判断首和判断循环首无论从字眼上和使用上都比较容易混淆，所以把这两个命令放在一起讲解，通过举例来学习的它们的区别和联系，以及使用技巧。

一、官方源码

判断循环首 （逻辑型 条件）
调用格式： 〈无返回值〉 判断循环首 （逻辑型 条件） - 系统核心支持库->流程控制
英文名称：while
本命令根据提供的逻辑参数的值，来决定是否进入循环。如果提供的逻辑参数值为真，程序顺序执行下一条命令进入循环，否则跳转到本命令所对应的“判断循环尾”命令的下一条命令处以跳出循环。本命令为初级命令。
参数<1>的名称为“条件”，类型为“逻辑型（bool）”。本条件值的结果决定下一步程序执行位置。

操作系统需求： Windows、Linux、Unix

对应命令：
调用格式： 〈无返回值〉 判断循环尾 （） - 系统核心支持库->流程控制
英文名称：wend
本命令已经被隐藏。
执行本命令将返回到对应的“判断循环首”命令处继续进行循环。本命令为初级命令。

操作系统需求： Windows、Linux、Unix

循环判断首 （）
调用格式： 〈无返回值〉 循环判断首 （） - 系统核心支持库->流程控制
英文名称：DoWhile
执行本命令后将顺序执行下一条命令进入程序循环。本命令为初级命令。

操作系统需求： Windows、Linux、Unix

对应命令：
调用格式： 〈无返回值〉 循环判断尾 （逻辑型 条件） - 系统核心支持库->流程控制
英文名称：loop
本命令已经被隐藏。
本命令根据提供的逻辑参数的值，来决定是否返回到循环首部继续进行循环。如果提供的逻辑参数值为真，程序返回到对应的“循环判断首”命令处继续进行循环，否则顺序执行下一条命令退出本程序循环。本命令为初级命令。
参数<1>的名称为“条件”，类型为“逻辑型（bool）”。本条件值的结果决定下一步程序执行位置。

操作系统需求： Windows、Linux、Unix

二、视频举例

判断循环首
.版本 2

' 先判断,条件为真了才进入循环体,while

.判断循环首 (a ＜ 100)
a ＝ a ＋ 1
编辑框1.加入文本 (到文本 (a) ＋ #换行符)

合计 ＝ 合计 ＋ a

.判断循环尾 ()

编辑框1.加入文本 (“1+2+3+...+100=” ＋ 到文本 (合计))
循环判断首
.版本 2

' 先进入循环体,后判断条件,为真了继续循环,不为真,循环结束.do while

.循环判断首 ()
a ＝ a ＋ 1
画板2.写文本行 (a)
合计 ＝ 合计 ＋ a
.循环判断尾 (a ＜ 100)

编辑框1.加入文本 (到文本 (合计))

易语言源码：

.版本 2

.程序集 窗口程序集_启动窗口

.子程序 _按钮_判断循环首_被单击
.局部变量 a, 整数型
.局部变量 合计, 整数型

' 先判断，再循环，条件为真的时候就进入循环，while
.判断循环首 (a ＜ 100)
    a ＝ a ＋ 1
    编辑框1.加入文本 (到文本 (a) ＋ #换行符)
    合计 ＝ 合计 ＋ a
.判断循环尾 ()
编辑框1.加入文本 (“1+2+3+...+100=” ＋ 到文本 (合计))


.子程序 _按钮_循环判断首_被单击
.局部变量 a, 整数型

' 先循环，再判断,后判断条件，如果为真，就继续循环，不为真，就循环结束， do  while
.循环判断首 ()
    a ＝ a ＋ 1
    ' 编辑框1.加入文本 (到文本 (a) ＋ #换行符)
    画板1.滚动写行 (a)

.循环判断尾 (a ＜ 100)

源码：易语言教程流程控制（循环判断首和判断循环首）

         511遇见易语言教程

本课视频教程示范了变量循环首的使用方法技巧，通过8个例子示范了命令的运用，同时把前面的计次循环首，循环判断首，判断循环首都总结类比了一次。

官方源码

调用格式： 〈无返回值〉 变量循环首 （整数型 变量起始值，整数型 变量目标值，整数型 变量递增值，［整数型变量 循环变量］） - 系统核心支持库->流程控制
英文名称：for
执行本命令将利用变量对循环体内的命令进行循环执行。第一次执行此命令时将使用“变量起始值”参数初始化“循环变量”参数所指定的变量。每次（包括第一次）执行到此命令处都将判断循环变量内的值是否已经超过“变量目标值”参数所指定的值，如已超过，则跳转到对应的“变量循环尾”命令的下一条命令处继续执行，否则顺序执行下一条语句继续进行循环。本命令为初级命令。
参数<1>的名称为“变量起始值”，类型为“整数型（int）”，初始值为“1”。定义循环变量的起始数值。
参数<2>的名称为“变量目标值”，类型为“整数型（int）”。定义循环变量的目标数值，在循环首部如果发现变量值已超出此目标值时将跳出循环。
参数<3>的名称为“变量递增值”，类型为“整数型（int）”，初始值为“1”。每次执行到循环尾部时都将把此值加入到循环变量中去，此值可为正数或负数，如为正数则递增，为负数则递减。
参数<4>的名称为“循环变量”，类型为“整数型（int）”，可以被省略，提供参数数据时只能提供变量。本数值型变量将用作控制循环执行次数，在循环尾部将自动递增或递减该变量内的数值。如果被省略，命令将自动使用内部临时变量。

操作系统需求： Windows、Linux、Unix

对应命令：
调用格式： 〈无返回值〉 变量循环尾 （） - 系统核心支持库->流程控制
英文名称：next
本命令已经被隐藏。
将在对应的“变量循环首”命令中所指定的数值变量递增或递减指定的值后返回到循环首部继续执行。本命令为初级命令。

操作系统需求： Windows、Linux、Unix

教程源码

.版本 2
.支持库 spec

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击

例1 ()

.子程序 例1
.局部变量 n, 整数型

编辑框1.内容 ＝ “”
.变量循环首 (50, -50, -1, n)
调试输出 (n)
编辑框1.加入文本 (到文本 (n) ＋ “,”)
.变量循环尾 ()

.子程序 _按钮2_被单击

例2 ()

.子程序 例2, , , 1--100内的奇数
.局部变量 i, 整数型

编辑框1.内容 ＝ “”
.变量循环首 (1, 100, 2, i)
编辑框1.加入文本 (到文本 (i) ＋ “,”)
调试输出 (i)
.变量循环尾 ()

.子程序 _按钮3_被单击

例3 ()

.子程序 例3, , , 1--100内偶数
.局部变量 m, 整数型

编辑框1.内容 ＝ “”
.变量循环首 (1, 100, 2, m)
编辑框1.加入文本 (到文本 (m ＋ 1) ＋ “,”)
调试输出 (到整数 (m ＋ 1))
.变量循环尾 ()

.子程序 _按钮4_被单击

例4 ()

.子程序 例4, , , 1--100内偶数
.局部变量 m, 整数型

编辑框1.内容 ＝ “”
.变量循环首 (2, 100, 2, m)
编辑框1.加入文本 (到文本 (m) ＋ “,”)
调试输出 (到整数 (m))
.变量循环尾 ()

.子程序 _按钮5_被单击

例5 ()

.子程序 例5, , , 1+2+3+...+100(变量循环首）
.局部变量 n, 整数型
.局部变量 和, 整数型
.局部变量 分割符, 文本型

编辑框1.内容 ＝ “”
.变量循环首 (1, 100, 1, n)
和 ＝ 和 ＋ n
编辑框1.加入文本 (分割符, 到文本 (n))
分割符 ＝ “，”
.变量循环尾 ()
调试输出 (和)
编辑框1.加入文本 (#换行符, #换行符, “1+2+3+...+100=” ＋ 到文本 (和))

.子程序 _按钮6_被单击

例6 ()

.子程序 例6, , , 1+2+3+...+100(计次循环首）
.局部变量 n, 整数型
.局部变量 和, 整数型
.局部变量 分割符, 文本型

编辑框1.内容 ＝ “”
.计次循环首 (100, n)
和 ＝ 和 ＋ n
编辑框1.加入文本 (分割符, 到文本 (n))
分割符 ＝ “，”
.计次循环尾 ()
编辑框1.加入文本 (#换行符, #换行符, “1+2+3+...+100=” ＋ 到文本 (和))

.子程序 _按钮7_被单击

例7 ()

.子程序 例7, , , 1+2+3+...+100(循环判断首）
.局部变量 n, 整数型
.局部变量 和, 整数型
.局部变量 分割符, 文本型

编辑框1.内容 ＝ “”
.循环判断首 ()
n ＝ n ＋ 1
和 ＝ 和 ＋ n
编辑框1.加入文本 (分割符, 到文本 (n))
分割符 ＝ “，”
.循环判断尾 (n ＜ 100)
编辑框1.加入文本 (#换行符, #换行符, “1+2+3+...+100=” ＋ 到文本 (和))

.子程序 _按钮8_被单击

例8 ()

.子程序 例8, , , 1+2+3+...+100(判断循环首）
.局部变量 n, 整数型
.局部变量 和, 整数型
.局部变量 分割符, 文本型

编辑框1.内容 ＝ “”
.判断循环首 (n ＜ 100)
n ＝ n ＋ 1
和 ＝ 和 ＋ n
编辑框1.加入文本 (分割符, 到文本 (n))
分割符 ＝ “，”
.判断循环尾 ()
编辑框1.加入文本 (#换行符, #换行符, “1+2+3+...+100=” ＋ 到文本 (和))

源码：易语言教程流程控制变量循环首

         511遇见易语言教程