1.操作数栈

1.每一个独立的栈帧中除了包含局部变量表以外，还包含一个后进先出的操作数栈。
2.操作数栈，在方法执行过程中，根据字节码指令，往栈中写入数据或提取数据，即入栈和出栈操作。

3.操作数栈主要用于保存计算过程的中间结果，同时作为计算过程中变量临时的存储空间。
4.操作数栈是JVM执行引擎的一个工作区，当一个方法开始执行的时候，一个新的栈帧也会随之被创建出来，这时候栈帧里面的操作数栈是空的。（虽然是空的，但是是有大小的）
5.每一个操作数栈都会拥有一个明确的栈深度用于存储数值，其所需的最大深度在编译期就已经定义好了，保存在方法的Code属性中，为max_stack的值。
6.操作数栈中的数据可以是任何一个Java数据类型。32位的数据占用一个栈深度，64位的数据类型占用两个栈深度。
7.虽然操作数栈是使用数组的方式来实现的，但是操作数栈只能用入栈和出栈的操作来完成一次数据访问，而不能使用索引的方式。

8.如果被调用的方法有返回值的话，其返回值将会被压入当前栈帧的操作数栈中。
9.Java虚拟机的解释引擎是基于栈的执行引擎，其中的栈指的就是操作数栈。

2.涉及操作数栈的字节码指令执行过程分析

package jvn;
public class OperandStackTest {
    public void testAddOperation() {
        //byte、short、char、boolean：都以int型来保存
        byte i = 15;
        int j = 8;
        int k = i + j;
    }
}

使用Javap -v OperandStackTest 反编译上面的java代码产生的OperandStackTest.class。
产生的字节码如下：

D:\Eclipse_workspace\JVM\jvn\bin\jvn>javap -v OperandStackTest.class
Classfile /D:/Eclipse_workspace/JVM/jvn/bin/jvn/OperandStackTest.class
  Last modified 2020-7-3; size 429 bytes
  MD5 checksum 6b1bb437ad85e3c11b4d35892faaec7a
  Compiled from "OperandStackTest.java"
public class jvn.OperandStackTest
  minor version: 0
  major version: 52
  flags: ACC_PUBLIC, ACC_SUPER
Constant pool:
   #1 = Class              #2             // jvn/OperandStackTest
   #2 = Utf8               jvn/OperandStackTest
   #3 = Class              #4             // java/lang/Object
   #4 = Utf8               java/lang/Object
   #5 = Utf8               <init>
   #6 = Utf8               ()V
   #7 = Utf8               Code
   #8 = Methodref          #3.#9          // java/lang/Object."<init>":()V
   #9 = NameAndType        #5:#6          // "<init>":()V
  #10 = Utf8               LineNumberTable
  #11 = Utf8               LocalVariableTable
  #12 = Utf8               this
  #13 = Utf8               Ljvn/OperandStackTest;
  #14 = Utf8               testAddOperation
  #15 = Utf8               i
  #16 = Utf8               B
  #17 = Utf8               j
  #18 = Utf8               I
  #19 = Utf8               k
  #20 = Utf8               SourceFile
  #21 = Utf8               OperandStackTest.java
{
  public jvn.OperandStackTest();
    descriptor: ()V
    flags: ACC_PUBLIC
    Code:
      stack=1, locals=1, args_size=1
         0: aload_0
         1: invokespecial #8                  // Method java/lang/Object."<init>":()V
         4: return
      LineNumberTable:
        line 3: 0
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       5     0  this   Ljvn/OperandStackTest;

  public void testAddOperation();
    descriptor: ()V
    flags: ACC_PUBLIC
    Code:
      stack=2, locals=4, args_size=1
         0: bipush        15
         2: istore_1
         3: bipush        8
         5: istore_2
         6: iload_1
         7: iload_2
         8: iadd
         9: istore_3
        10: return
      LineNumberTable:
        line 6: 0
        line 7: 3
        line 8: 6
        line 9: 10
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0      11     0  this   Ljvn/OperandStackTest;
            3       8     1     i   B
            6       5     2     j   I
           10       1     3     k   I
}
SourceFile: "OperandStackTest.java"

主要关注下面这段code：

 	stack=2, locals=4, args_size=1
         0: bipush        15
         2: istore_1
         3: bipush        8
         5: istore_2
         6: iload_1
         7: iload_2
         8: iadd
         9: istore_3
        10: return

stack=2, locals=4, args_size=1 ： stack=2表示的是操作数栈的大小为2。locals=4表示的是局部变量表的长度是4。

如下图所示：
在刚开始执行这个方法的时候，PC寄存器记录了下一条要执行的字节码指令的起始地址。局部变量表和操作数栈都是空的。
1.第一条指令是0: bipush 15。表示的是将数字15压入操作数栈。
2.第二条指令是 2: istore_1。i表示的是存储在操作数栈中的数据的类型是int。 istore_1表示的是将操作数栈中的数据取出来放到局部变量表的索引等于1的位置。（为什么不是放在局部变量表索引为0的位置？因为对于非静态的方法，局部变量表中索引为0的位置存放的是this）。

3.第三条指令是 3: bipush 8。表示的是将数字8压入操作数栈。
4.第四条指令是 5: istore_2。表示的是将操作数栈中的数字8取出来放入局部变量表中索引为2的位置。

3.第五条指令是 6: iload_1。表示的是将数字15从局部变量表中索引为1的位置取出来压入操作数栈。
4.第六条指令是 7: iload_2。表示的是将数字8从局部变量表中索引为2的位置取出来压入操作数栈。
这时候操作数栈中有两个数据：8和15。

5.第七条指令8: iadd。表示的是将操作数栈中的两个数据出栈并且做一个求和运算，最后将求得的结果23压入操作数栈。
6.第八条指令9: istore_3。表示的是将操作数栈中的数据23出栈并且放入局部变量表的索引为3的位置。
7.最后的指令 10: return。表示的是直接返回。

更多JVM相关文章请参考我的专栏：
https://blog.csdn.net/u011069294/category_10113093.html

Java栈——操作数栈

先明确一个概念，Java栈(虚拟机栈)内存储的是栈帧，多个栈帧组成了一个虚拟机栈。栈帧是JVM进行方法调用使用的数据结构。

栈帧内保存包含有操作数栈。操作数栈保存了方法执行过程中各指令的操作数。

看下边代码：

public class Test1 {

    public int add(int a, int b) {
        int c = a + b;
        return c;
    }

    public static void main(String[] args) {
        Test1 test1 = new Test1();
        test1.add(1,1);
    }
}

对应的字节码文件：

Classfile <Path to /com/sanren1024/jvm/Test1.class>
  Last modified ...; size 578 bytes
  SHA-256 checksum fd3bf061ff99b334ba84db7afd21242589b527334dee24ff7d0410c0927aa9be
  Compiled from "Test1.java"
public class com.sanren1024.jvm.Test1
  minor version: 0
  major version: 57
  flags: (0x0021) ACC_PUBLIC, ACC_SUPER
  this_class: #7                          // com/sanren1024/jvm/Test1
  super_class: #2                         // java/lang/Object
  interfaces: 0, fields: 0, methods: 3, attributes: 1
Constant pool:
   #1 = Methodref          #2.#3          // java/lang/Object."<init>":()V
   #2 = Class              #4             // java/lang/Object
   #3 = NameAndType        #5:#6          // "<init>":()V
   #4 = Utf8               java/lang/Object
   #5 = Utf8               <init>
   #6 = Utf8               ()V
   #7 = Class              #8             // com/sanren1024/jvm/Test1
   #8 = Utf8               com/sanren1024/jvm/Test1
   #9 = Methodref          #7.#3          // com/sanren1024/jvm/Test1."<init>":()V
  #10 = Methodref          #7.#11         // com/sanren1024/jvm/Test1.add:(II)I
  #11 = NameAndType        #12:#13        // add:(II)I
  #12 = Utf8               add
  #13 = Utf8               (II)I
  #14 = Utf8               Code
  #15 = Utf8               LineNumberTable
  #16 = Utf8               LocalVariableTable
  #17 = Utf8               this
  #18 = Utf8               Lcom/sanren1024/jvm/Test1;
  #19 = Utf8               a
  #20 = Utf8               I
  #21 = Utf8               b
  #22 = Utf8               c
  #23 = Utf8               main
  #24 = Utf8               ([Ljava/lang/String;)V
  #25 = Utf8               args
  #26 = Utf8               [Ljava/lang/String;
  #27 = Utf8               test1
  #28 = Utf8               SourceFile
  #29 = Utf8               Test1.java
{
  public com.sanren1024.jvm.Test1();
    descriptor: ()V
    flags: (0x0001) ACC_PUBLIC
    Code:
      stack=1, locals=1, args_size=1
         0: aload_0
         1: invokespecial #1                  // Method java/lang/Object."<init>":()V
         4: return
      LineNumberTable:
        line 3: 0
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       5     0  this   Lcom/sanren1024/jvm/Test1;

  public int add(int, int);
    descriptor: (II)I
    flags: (0x0001) ACC_PUBLIC
    Code:
      stack=2, locals=4, args_size=3
         0: iload_1
         1: iload_2
         2: iadd
         3: istore_3
         4: iload_3
         5: ireturn
      LineNumberTable:
        line 6: 0
        line 7: 4
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       6     0  this   Lcom/sanren1024/jvm/Test1;
            0       6     1     a   I
            0       6     2     b   I
            4       2     3     c   I

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: (0x0009) ACC_PUBLIC, ACC_STATIC
    Code:
      stack=3, locals=2, args_size=1
         0: new           #7                  // class com/sanren1024/jvm/Test1
         3: dup
         4: invokespecial #9                  // Method "<init>":()V
         7: astore_1
         8: aload_1
         9: iconst_1
        10: iconst_1
        11: invokevirtual #10                 // Method add:(II)I
        14: pop
        15: return
      LineNumberTable:
        line 11: 0
        line 12: 8
        line 13: 15
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0      16     0  args   [Ljava/lang/String;
            8       8     1 test1   Lcom/sanren1024/jvm/Test1;
}
SourceFile: "Test1.java"

看到局部变量表上，slot1是test1实例。源码文件中调用了 test1.add(1,1) 方法，可以查看字节码的指令的执行。

  public int add(int, int);
    descriptor: (II)I
    flags: (0x0001) ACC_PUBLIC
    Code:
      stack=2, locals=4, args_size=3
         0: iload_1             // 加载slot1操作数  slot1: a=1
         1: iload_2             // 加载slot2操作数  slot2: a=1
         2: iadd                // 执行add操作      结果：2
         3: istore_3            // 保存结果slot3    slot3:c=2
         4: iload_3             // 加载slot3
         5: ireturn             // 返回
      LineNumberTable:
        line 6: 0
        line 7: 4
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       6     0  this   Lcom/sanren1024/jvm/Test1;
            0       6     1     a   I
            0       6     2     b   I
            4       2     3     c   I

对应的操作数栈内表现：

c(2)

2

1(b)

1(a)

最后返回，就返回栈顶的值。

在JVM的优化中，有时候，几个栈帧会共用一个操作数栈，来节约内存。