unity3d 角色死亡_unity3d死亡 - CSDN
  • Unity Shader-死亡溶解效果

    万次阅读 多人点赞 2017-05-22 00:23:30
    简介 赶脚每个学习shader的,都得过死亡溶解这一关....毕竟这个效果灰常常用。今天,我也来研究一下死亡溶解效果的实现。 溶解效果实现

    简介


    游戏里面角色死亡的时候,有很多方式可以表现人物死亡效果。最简单粗暴的,播放完死亡动画直接删除或者直接Y轴逐渐降低,沉到地下;比较好的死亡效果就是今天要研究的这种效果-死亡溶解。个人印象比较深刻的就是《生化危机6》里面的克里斯篇,里面的功夫丧尸挂掉之后都是会有一个类似的死亡溶解效果。不过《生化危机6》这种3A大作的效果肯定不仅仅是一个shader能做出来的,还配合了粒子做出了消散以及着火的效果。

    赶脚一般学习shader的童鞋,都会研究一下这个东东....毕竟这个效果灰常常用。今天,我也来研究一下死亡溶解效果的实现。

    基本溶解效果


    溶解,也就是让这个模型逐渐消失。那么,最简单的,直接让这个像素的Fragment Shader操作discard,这个像素就消失了。然后,我们要做的就是让这个溶解的对象一部分消失,另一部分存在,所以,这个时候我们就需要一个Mask图进行控制,我们采样这张Mask图,就可以得到这个像素点当前的Mask值,然后用这个Mask值与我们设定的一个阈值来进行比较,小于阈值的部分discard,大于的部分正常计算。最终,我们将这个阈值从0逐渐增加到1,就可以实现模型的一部分像素先消失,直至整个模型完全消失的效果。
    简单的原理解释完了,先来一发基本的溶解效果:
    //溶解效果
    //by:puppet_master
    //2017.5.18
    
    Shader "ApcShader/DissolveEffect"
    {
    	Properties{
    		_Diffuse("Diffuse", Color) = (1,1,1,1)
    		_MainTex("Base 2D", 2D) = "white"{}
    		_DissolveMap("DissolveMap", 2D) = "white"{}
    		_DissolveThreshold("DissolveThreshold", Range(0,1)) = 0
    	}
    	
    	CGINCLUDE
    	#include "Lighting.cginc"
    	uniform fixed4 _Diffuse;
    	uniform sampler2D _MainTex;
    	uniform float4 _MainTex_ST;
    	uniform sampler2D _DissolveMap;
    	uniform float _DissolveThreshold;
    	
    	struct v2f
    	{
    		float4 pos : SV_POSITION;
    		float3 worldNormal : TEXCOORD0;
    		float2 uv : TEXCOORD1;
    	};
    	
    	v2f vert(appdata_base v)
    	{
    		v2f o;
    		o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
    		o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
    		o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
    		return o;
    	}
    	
    	fixed4 frag(v2f i) : SV_Target
    	{
    		//采样Dissolve Map
    		fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);
    		//小于阈值的部分直接discard
    		if (dissolveValue.r < _DissolveThreshold)
    		{
    			discard;
    		}
    		//Diffuse + Ambient光照计算
    		fixed3 worldNormal = normalize(i.worldNormal);
    		fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
    		fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
    		fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
    		fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
    		return fixed4(color, 1);
    	}
    	ENDCG
    	
    	SubShader
    	{
    		Tags{ "RenderType" = "Opaque" }
    		Pass
    		{
    			CGPROGRAM
    			#pragma vertex vert
    			#pragma fragment frag	
    			ENDCG
    		}
    	}
    	FallBack "Diffuse"
    }
    
    最近找了个比较帅气的模型,先爆个照(开启了BloomDepth Of Field):
    然后,让偶们把它溶解掉,这里我们直接使用了一张噪声图,最简单的雪花点的那种就可以啦,逐渐调大Dissolve Threshold,就可以了:


    增加过渡的溶解效果


    上面的溶解效果感觉就像被打成筛子一样...木有明显的过渡,感觉效果不是很好。下面写一个增加了过渡的溶解效果,让被溶解的部分边缘变成我们设置的颜色,为了增加丰富性,我们可以增加两个过渡颜色。分别设置两个阈值。首先是当阈值小于颜色A阈值的时候,返回颜色A,阈值小于颜色B的时候,返回颜色B,否则返回原始颜色。shader代码如下:
    //溶解效果
    //by:puppet_master
    //2017.5.18
    
    Shader "ApcShader/DissolveEffect"
    {
    	Properties{
    		_Diffuse("Diffuse", Color) = (1,1,1,1)
    		_DissolveColorA("Dissolve Color A", Color) = (0,0,0,0)
    		_DissolveColorB("Dissolve Color B", Color) = (1,1,1,1)
    		_MainTex("Base 2D", 2D) = "white"{}
    		_DissolveMap("DissolveMap", 2D) = "white"{}
    		_DissolveThreshold("DissolveThreshold", Range(0,1)) = 0
    		_ColorFactorA("ColorFactorA", Range(0,1)) = 0.7
    		_ColorFactorB("ColorFactorB", Range(0,1)) = 0.8
    	}
    	
    	CGINCLUDE
    	#include "Lighting.cginc"
    	uniform fixed4 _Diffuse;
    	uniform fixed4 _DissolveColorA;
    	uniform fixed4 _DissolveColorB;
    	uniform sampler2D _MainTex;
    	uniform float4 _MainTex_ST;
    	uniform sampler2D _DissolveMap;
    	uniform float _DissolveThreshold;
    	uniform float _ColorFactorA;
    	uniform float _ColorFactorB;
    	
    	struct v2f
    	{
    		float4 pos : SV_POSITION;
    		float3 worldNormal : TEXCOORD0;
    		float2 uv : TEXCOORD1;
    	};
    	
    	v2f vert(appdata_base v)
    	{
    		v2f o;
    		o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
    		o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
    		o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
    		return o;
    	}
    	
    	fixed4 frag(v2f i) : SV_Target
    	{
    		//采样Dissolve Map
    		fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);
    		//小于阈值的部分直接discard
    		if (dissolveValue.r < _DissolveThreshold)
    		{
    			discard;
    		}
    		//Diffuse + Ambient光照计算
    		fixed3 worldNormal = normalize(i.worldNormal);
    		fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
    		fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
    		fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
    		fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
    		//这里为了比较方便,直接用color和最终的边缘lerp了
    		float lerpValue = _DissolveThreshold / dissolveValue.r;
    		if (lerpValue > _ColorFactorA)
    		{
    			if (lerpValue > _ColorFactorB)
    				return _DissolveColorB;
    			return _DissolveColorA;
    		}
    		return fixed4(color, 1);
    	}
    	ENDCG
    	
    	SubShader
    	{
    		Tags{ "RenderType" = "Opaque" }
    		Pass
    		{
    			CGPROGRAM
    			#pragma vertex vert
    			#pragma fragment frag	
    			ENDCG
    		}
    	}
    	FallBack "Diffuse"
    }
    
    上面的模型,我们配置一个雷电类型的溶解效果,两个颜色值分别给白色和蓝色。然后噪声图给一张过渡更加柔和一些的,如下图:
    来一张动图,先逐渐增大溶解阈值,就是溶解效果;然后再减小阈值,就是闪亮登场的效果:

    上面的shader虽然比较容易理解,我们直接用了两个if进行判断的。不过感觉shader里面的分支还是尽量少,毕竟如果有动态分支(编译期的有些是可以自动优化掉的,比如我们写的固定次数的循环,这种应该是会直接在编译期展开了),运行时的shader有动态分支的话,是会先执行一遍A分支,然后再去执行B分支,效率就下去了,可以参考知乎大神们的讨论。so...我们还是老老实实地写一发用值来判断的(除了discard):
    //溶解效果
    //by:puppet_master
    //2017.5.19
    
    Shader "ApcShader/DissolveEffect"
    {
    	Properties{
    		_Diffuse("Diffuse", Color) = (1,1,1,1)
    		_DissolveColor("Dissolve Color", Color) = (0,0,0,0)
    		_DissolveEdgeColor("Dissolve Edge Color", Color) = (1,1,1,1)
    		_MainTex("Base 2D", 2D) = "white"{}
    		_DissolveMap("DissolveMap", 2D) = "white"{}
    		_DissolveThreshold("DissolveThreshold", Range(0,1)) = 0
    		_ColorFactor("ColorFactor", Range(0,1)) = 0.7
    		_DissolveEdge("DissolveEdge", Range(0,1)) = 0.8
    	}
    	
    	CGINCLUDE
    	#include "Lighting.cginc"
    	uniform fixed4 _Diffuse;
    	uniform fixed4 _DissolveColor;
    	uniform fixed4 _DissolveEdgeColor;
    	uniform sampler2D _MainTex;
    	uniform float4 _MainTex_ST;
    	uniform sampler2D _DissolveMap;
    	uniform float _DissolveThreshold;
    	uniform float _ColorFactor;
    	uniform float _DissolveEdge;
    	
    	struct v2f
    	{
    		float4 pos : SV_POSITION;
    		float3 worldNormal : TEXCOORD0;
    		float2 uv : TEXCOORD1;
    	};
    	
    	v2f vert(appdata_base v)
    	{
    		v2f o;
    		o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
    		o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
    		o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
    		return o;
    	}
    	
    	fixed4 frag(v2f i) : SV_Target
    	{
    		//采样Dissolve Map
    		fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);
    		//小于阈值的部分直接discard
    		if (dissolveValue.r < _DissolveThreshold)
    		{
    			discard;
    		}
    		//Diffuse + Ambient光照计算
    		fixed3 worldNormal = normalize(i.worldNormal);
    		fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
    		fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
    		fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
    		fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
    
    		//优化版本,尽量不在shader中用分支判断的版本,但是代码很难理解啊....
    		float percentage = _DissolveThreshold / dissolveValue.r;
    		//如果当前百分比 - 颜色权重 - 边缘颜色
    		float lerpEdge = sign(percentage - _ColorFactor - _DissolveEdge);
    		//貌似sign返回的值还得saturate一下,否则是一个很奇怪的值
    		fixed3 edgeColor = lerp(_DissolveEdgeColor.rgb, _DissolveColor.rgb, saturate(lerpEdge));
    		//最终输出颜色的lerp值
    		float lerpOut = sign(percentage - _ColorFactor);
    		//最终颜色在原颜色和上一步计算的颜色之间差值(其实经过saturate(sign(..))的lerpOut应该只能是0或1)
    		fixed3 colorOut = lerp(color, edgeColor, saturate(lerpOut));
    		return fixed4(colorOut, 1);
    	}
    	ENDCG
    	
    	SubShader
    	{
    		Tags{ "RenderType" = "Opaque" }
    		Pass
    		{
    			CGPROGRAM
    			#pragma vertex vert
    			#pragma fragment frag	
    			ENDCG
    		}
    	}
    	FallBack "Diffuse"
    }
    
    效果与上面基本一致,所以这次我们换个颜色再来一发燃烧溶解效果,把颜色调整成黄色和红色:

    再来一发动图:


    不仅仅是溶解,还要灰飞烟灭


    我们的模型溶解了,本来已经够惨了。如果我们让它更惨一点,那就让它灰飞烟灭吧。《生化危机6》中的消散效果感觉应该是粒子特效制作的,其实我们直接用shader应该也可以做出类似的效果,但是肯定没有专门再做一个特效的效果好,只能模拟一个类似的效果。首先,我们要想让模型溶解后的碎片飞出去,那么就要让光栅化之前的像素点位置有偏移,所以这个操作是要在vertex shader中做的。我们让模型的顶点坐标按照一定的规则做一些偏移,就可以达到飞出去的效果了。
    比如,我们试一下让模型按照法线方向外拓一下,再极小的范围下,可以实现模型的大小的扩张,不过这个扩张并不是多大都可以,如果太大了,就会出现“三角形爆炸”的情况,可以参考一下本篇文章最后的图片。我们只是轻轻的让它扩张一下就可以了。比如下面这句,当大于一定阈值的时候,才开始扩张效果:
    v.vertex.xyz += v.normal * saturate(_DissolveThreshold - _FlyThreshold) * _FlyFactor;
    这次我们换一个雪花点类型的噪声图,效果如下:


    关于沿着某个方向消散的效果的一点讨论


    感觉沿着法线方向飞出来感觉效果不好控制,尤其是容易看到三角形穿帮的情况。我们也可以让模型在溶解超过一定阈值之后向上飞,大概是这样的一个效果,还是那个帅帅哒模型,不过我们换了个角度:


    下面一段纯属废话,感兴趣的可以看一下本人的内心独白:
    要让模型向上运动,分为几种情况。第一种是模型空间的向上,这种最简单,直接在appdata_base传入的vertex的y轴坐标修改一下就可以了,不过这种情况下模型只会沿着所谓模型的Y轴进行偏移,如果运气好,Y轴正好在头顶,那么效果是正常的,但是如果Y轴不是头顶,我们所谓的向上就不一定向哪里了;第二种是在屏幕空间的向上,比如我们上面实验的角度上,我们可以直接在计算完MVP之后得到的坐标的y方向进行偏移,相对也比较简单,但是这种情况也会有一定的问题,比如我们相机换了个角度看的话,模型的偏移方向仍然是在屏幕上向上移动,这种效果也是不对的;第三种是在世界坐标向上,世界空间只有一个,而且所有的模型都共享这个世界空间,我们在这个空间上进行偏移操作的话,所有的模型不管自身坐标系是怎样的,也不管相机观察角度是怎样的,都会在世界空间的y方向进行偏移,这种最为符合我们现实世界,正所谓世界就在那,如果观察的角度不同,那么得到的结果也不同(恩恩,写个shader竟然还上升到哲学层面了= 。=)。那就看一下在世界空间上进行模型偏移的操作。这个就没有直接在模型空间或者屏幕空间进行操作方便了,因为这个操作是穿插在MVP变换中间的,我们需要先.........(等等,我好像想到了点什么),让模型从世界空间上向一个方向运动的话,不就是改Transform的Y轴方向吗(我是不是写shader写傻了=。=)!!!如果我在shader里面进行这步操作的话,模型有N个顶点,那么这个是个O(N)复杂度的运算,而如果我直接在脚本层面让模型朝Y方向位移一段的话,这个时间复杂度就是O(1)的(类似变换矩阵之类的都是在每帧针对每个物体计算好再传递给shader中进行运算,也就是shader中的uniform类型的变量)。所以,个人感觉实现这个的最好方法就是直接挂个脚本,按照时间大于某个值直接把模型在Y方向上向上平移一下就好了。

    总之,shader虽然强大,可以做出很多很有意思的效果,但是,并不是所有的效果都适合在shader中做。毕竟如果我们在脚本里面计算的话,对于一个模型来说,只需要计算一次。但是如果放到vertex shader中就需要模型顶点数次运算,放到fragment shader的话就需要光栅化后可见像素数次运算,性能还是不一样的。

    溶解效果副产品


    写个shader经常会写出一些副产品,虽然说效果和目前想要的不太一样(更直白的来说就是实验失败的版本....),但是效果有时候却挺好玩的,打算把shader的副产品也记录一下,万一以后用得上呢,2333。

    第一弹,直接在溶解效果后面计算一个叠加的颜色值,根据Noise采样叠加到原始模型上的效果:
    float lerpValue = (dissolveValue.r - _DissolveThreshold) * _DissolveEdge;
    fixed3 final = color + _DissolveColor * lerpValue;
    脑补一下使用的场景:从左到右分别是病毒感染了,闪瞎眼了(其实只是过暴,因为加上bloom比较出效果罢了),秽土转生要结束了(火影迷暴露无遗....)


    第二弹,爆炸效果...这个是调溶解残片飞出去的时候,权值给的太高,直接三角形炸开了....感觉好惨,其实主要就是沿着模型法线方向偏移:
    v.vertex.xyz += v.normal * _DissolveThreshold * 0.5;





    展开全文
  •  感谢对我的支持,在上一篇文章《 [Unity3D]Unity3D游戏开发之仿仙剑奇侠传角色控制效果》中,我们通过自定义脚本实现了在RPG游戏中的角色控制器,当然这个角色器目前还不完善,为什么这么说呢,我在后面的一篇...

             大家好,我是秦元培,欢迎大家关注我的博客,我的博客地址是blog.csdn.net/qinyuanpei

             感谢对我的支持,在上一篇文章《 [Unity3D]Unity3D游戏开发之仿仙剑奇侠传角色控制效果》中,我们通过自定义脚本实现了在RPG游戏中的角色控制器,当然这个角色器目前还不完善,在碰撞以及控制等方面还存在某些问题和不足,对于这些问题,我会在后面的一篇文章中会给大家做详细的说明,力图设计出一个为RPG游戏服务的角色控制器,方便大家开发RPG类型的游戏。那么,今天我想和大家分享的是在Unity3D中一个比较重要的组件——布娃娃(Ragdoll)。我们首先来看张图片吧!

     

              相信熟悉仙剑的朋友一定知道这样一句话:胜败乃兵家常事,大侠请重新来过。从仙剑一到仙剑五前传,仙剑带给我们的感动里不仅仅是一个个跌宕起伏、感人至深的故事,还有每一次战斗失败之后从头再来的勇敢。人生有时候就像游戏一样,我们总会遇到这样或着那样的挫折和困难。虽然在仙剑这样一个五灵六界的世界观下,人类基本作为最弱小的生命存在,但是每次我们的主角们不是一直在努力去做吗?所以我们的人生一定要积极向上,充满激情地去做一件事情。博主最讨厌的就是玩游戏玩到最后只剩下打嘴仗的这种玩家,游戏一定是有输有赢的,试问各位仙剑玩家哪一个没有被Boss虐过,可是游戏的乐趣不就是在于一遍遍地去超越自己吗?输不可怕,怕的是我们因为输了就丧失了努力的勇气。我觉得仙剑一直再像我们传递一种正能量,那就是我们一定要让自己勇敢,人生中有很多的事情或许我们都无法掌控,就像李逍遥剑术超凡却不能帮助灵儿逃脱宿命、云天河拥有神龙之息、后羿射日神弓,为救山下百姓而箭射琼华,却救不了心爱的女孩儿的性命、夏侯瑾轩以为 凡事尽心尽力就能做好,可是到最后他却只能拿匕首刺向瑕妹子,只是为了不让枯木占据她的身体。或许我们并不知道未来会是什么样子吧,但是至少在此时此刻,我们曾经努力过、我们很用心地做过某些事情,这样就够了。好了,我们不去评论这些玩家了,我们正式开始今天的内容。

             在RPG游戏中,当角色HP降低到0时,角色即进入了死亡状态,此时角色将倒在地上。在过去的游戏设计中,角色倒在地上的动作通常是由动画师绘制一定的动画来完成的,这种方式虽然简单,但是由于角色倒地的动作都是相同的,无法实时反映出角色受攻击的情况,所以在游戏开发领域逐渐形成了一种新的模型即布娃娃(Ragdoll),该模型就是用来模拟角色死亡的状态的。在Unity3D中,系统为我们提供了布娃娃组件,下面请大家和我一起来学习怎样使用布娃娃来模拟角色死亡的状态吧:

             首先我们创建一个新项目,在场景中创建一个Plane和平行光,接下来我们导入我们事先准备好的FBX模型,此时在游戏场景中应该可以看到下面的内容:


           接下来,我们选中模型Samuzai,为其创建一个布娃娃组件:


              我们一起来看打开的对话框:


            如果我们的模型中提供了骨骼动画的话,那么我们单击右侧的选择按钮就能找到相应的文件,然后我们点Create,此时模型下的骨骼组件应该会变成下面这个样子:


          我们将盒子碰撞器移除,将模型的动画设为None,现在我们来运行程序:


          可以看到,我们的角色很真实地倒在了地上,而且如果我们多次运行程序的话,会发现角色每次死亡的时候都是不一样的,这样大大增强了游戏的真实感,如果每次战斗死亡的姿势都是一样的,这样会不会视觉疲劳呢?虽然《轩辕剑6》的市场反响并不怎么样,然而得益于Unity3D中的强大物理引擎,每次怪物死亡的时候都死得比较有范儿,大家可以自己去玩玩试玩版啊,哈哈。这里希望仙剑奇侠传的后续作品能够注意到这个问题,作为大侠,我们要死得轰轰烈烈的嘛,好了,这就是今天的文章了,希望大家喜欢!

         喜欢我的博客请记住我的名字:秦元培,我的博客地址是:blog.csdn.net/qinyuanpei

         转载请注明出处,本文作者:秦元培,本文出处:http://blog.csdn.net/qinyuanpei/article/details/23869275


    展开全文
  • 这段代码是在Unity蛮牛给人解答的时候写的,第一次写Shader,Unity官方的语法还没来得及完全过一遍,比较仓促,还好效果实现了! 笔记:Alpha Blending则是一种中庸的方式,它使用当前fragment的alpha作为混合因子...

    这段代码是在Unity蛮牛给人解答的时候写的,第一次写Shader,Unity官方的语法还没来得及完全过一遍,比较仓促,还好效果实现了!

    笔记:Alpha Blending则是一种中庸的方式,它使用当前fragment的alpha作为混合因子,来混合之前写入到缓存中颜色值。但Alpha Blending麻烦的一点就是它需要关闭ZWrite,并且要十分小心物体的渲染顺序。如果不关闭ZWrite,那么在进行深度检测的时候,它背后的物体本来是可以透过它被我们看到的,但由于深度检测时大于它的深度就被剔除了,从而我们就看不到它后面的物体了。因此,我们需要保证物体的渲染顺序是从后往前,并且关闭该半透明对象的ZWrite。


    Shader "Custom/Test" {
    Properties {
            _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
        _Alpha("Alpha", Range (0.01,1.0)) = 0.5
    }
    SubShader {
        Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
        LOD 200
         Pass {
        ZWrite Off
        ColorMask 0
    }
    
        CGPROGRAM
        #pragma surface surf Lambert alpha
    
        sampler2D _MainTex;
        float _Alpha;
        fixed4 _Color;
    
        struct Input {
            float2 uv_MainTex;
        };
    
        void surf (Input IN, inout SurfaceOutput o) {
            half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
            o.Emission = c.rgb;
            o.Alpha = _Alpha;
        }
        ENDCG
    } 
    FallBack "Diffuse"}

    将上面的这段Shader放到Unity3D中,放到模型上。就可以自己调试Alpha值和模型的颜色了,只要在角色被攻击的时候改下颜色值,然后攻击完改回来就可以了,角色死亡的时候调整Alpha值减少,就可以看起来是渐隐消失的效果了!

    由于透明度在不同的移动端优化和ColorMask这玩意在移动端消耗比较大,所以有了下面的这个shader:

    Shader "Transparent/DiffuseS" {
                Properties {
                _Color ("Main Color", Color) = (1,1,1,1)
                _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
                }
    
                SubShader {
                    Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
                    LOD 200
    
                    CGPROGRAM
                    #pragma surface surf Lambert alpha
    
                    sampler2D _MainTex;
                    fixed4 _Color;
    
                    struct Input {
                    float2 uv_MainTex;
            };
    
            void surf (Input IN, inout SurfaceOutput o) {
            fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
            o.Emission = c.rgb;
            o.Alpha = c.a;
            }
        ENDCG
        }
    
        Fallback "Transparent/VertexLit"}

    这个shader可以在移动端使用没有问题,修改的时候只要修改_Color属性和颜色值即可!
    展开全文
  • Unity3D 角色死亡灰屏特效实现

    千次阅读 2017-02-13 09:54:17
    1.第一步,首先新建一个unity3d项目,导入Standard Assets>ImageEffects 插件(灰屏效果有用到噢),格外还导入Demo用到的角色资源[Spider Green插件];    2.第二步,需要在场景中创建一个摄像机,...
    1.第一步,首先新建一个unity3d项目,导入Standard Assets>ImageEffects 插件(灰屏效果有用到噢),格外还导入Demo用到的角色资源[Spider Green插件];

        

        2.第二步,需要在场景中创建一个摄像机,并且摄像机附加ColorCorrectionCurves.cs 组件;

        


        3.第三步,把Spider Green中的SPIDER.Prefab拖到场景中,并且新加组件GameOver.cs;

          

        GameOver.cs代码如下:

         
    [C#] 
    ?
     
    using System.Collections;
    using System.Collections.Generic;
    using UnityEngine;
    using UnityStandardAssets.ImageEffects;
     
    public class GameOver : MonoBehaviour {
     
            private  Animation _curAnim;
            private ColorCorrectionCurves _colorCor;
     
            // Use this for initialization
            void Start () {
                    if (_curAnim == null)
                            _curAnim = GetComponent<Animation> ();
     
                    if (_colorCor == null)
                            _colorCor = FindObjectOfType<ColorCorrectionCurves> ();
            }
     
            void OnGUI()
            {
                    if (GUI.Button (new Rect (50, 100, 100, 50), "怪物重生")) {
                            SetAnimationPlay ("Attack",WrapMode.Loop);
                            SetColorCorrectionCurvesSaturation (1);
     
                    }
                    if (GUI.Button (new Rect (50, 200, 100, 50), "杀死怪物")) {
                            SetAnimationPlay ("Death",WrapMode.Once);
                            SetColorCorrectionCurvesSaturation (0);
                    }
            }
            /// <summary>
            /// 设定当前播放的动画
            /// </summary>
            /// <param name="animName">Animation name.</param>
            /// <param name="wrapL">Wrap l.</param>
            void SetAnimationPlay(string animName,WrapMode wrapL)
            {
                    if (_curAnim) {
                            _curAnim.Play (animName);
                            _curAnim.wrapMode = wrapL;
                    }
            }
            /// <summary>
            /// 设定当前摄像机的颜色度
            /// </summary>
            /// <param name="duration">Duration.</param>
            void SetColorCorrectionCurvesSaturation(int duration)
            {
                    if (_colorCor)
                            _colorCor.saturation = duration;
            }
    }
    m>
        void SetColorCorrectio

        4.最后,直接运行项目看效果啦!

           


           
    展开全文
  • Unity3D实现的角色攻击、移动待机死亡以及怪物自动寻路AI等(直接Unity运行)
  • unity 角色死亡界面变灰实现

    千次阅读 2015-06-01 18:00:39
    导入Image Effects包。 方法一:给摄像机添加“Color Correction Curves”脚本,调整“Saturation”属性的值到0。 方法二:给摄像机添加“GrayscaleEffect”脚本,调整Ramp Offset属性可以修改画面亮度。...
  • Unity3d动画死亡动画一直播放的问题

    千次阅读 2019-09-28 20:19:09
    在学习unity3d的过程中遇到一个问题,就是在任务死亡的时候人物会一直重复死亡的动作,在设置animations的之后发现一起都没问题,触发器也是使用的trigger,一起都没问题,一直没找到解决的办法,终于在一片博客的帮助下...
  • Unity3D角色控制及敌人AI(寻路、攻击、死亡)示例工程包
  • 一,新建一个空物体LevelManager用来管理我们的复活,金币等脚本 二,为空物体LevelManager新建一个脚本LevelManager; 三,脚本  把Player和LevelManager拖到指定的公共变量中 1,PlayerController ...
  •  在前面的文章中,我们分别实现了一个自定义的角色控制器《[Unity3D]Unity3D游戏开发之仿仙剑奇侠传角色控制效果》和角色死亡的效果《[Unity3D]Unity3D游戏开发之仿仙剑奇侠传角色死亡效果实现》。今天我们继续来做...
  • unity 3D人物有动画

    2020-07-29 14:18:33
    unity 3D人物有动画 好几种人物 自带animator 攻击死亡站立跑。都有!
  • 如何判断Unity3D角色动作播放结束

    千次阅读 2012-12-06 15:32:52
    bool AnimationStillPlaying( string animationName ) { return _animation.IsPlaying(animationName) && _animation[animationName].normalizedTime; }   ... 范围0 -- 1, 0是动作开始,1是
  • Unity3D 2D角色看向鼠标方向 本篇文章是通过动画控制器 (Animator) 中的混合树 (Blend Tree) 来实现2D角色看向鼠标方向,希望能对您有帮助。 还记得我曾经的毕设,是一款2D解谜游戏,游戏中的小人会根据鼠标位置看...
  • Unity3D常见面试题

    万次阅读 多人点赞 2017-08-11 20:20:00
    Unity3D常见面试题
  • 关于2D游戏中游戏玩家的出生、无敌、死亡方法可以通过如下一个小实例详细讲解我们小时候都玩过一款游戏——坦克大战所以此实例为如何实现玩家坦克的出生、无敌、以及死亡方法首先我们制作一个出生动画特效(此动画...
  • 今天和大家分享的是在Unity3D中一个比较重要的组件——布娃娃(Ragdoll)。我们首先来看张图片吧! 相信熟悉仙剑的朋友一定知道这样一句话:胜败乃兵家常事,大侠请重新来过。从仙剑一到仙剑五前传,仙剑带给我们的...
  • unity3d 2d游戏(太空大战)开发笔记

    千次阅读 2018-10-22 13:50:04
    最近刚开始看unity3d游戏开发,感觉2d游戏似乎简单些,所以先从2d游戏入手试试看吧。 2d游戏大约要分为背景,角色(需要控制的己方角色car,敌机enemy,奖励物品prop),ui(分数显示,暂停继续等),音乐(背景...
  • 在RPG游戏中,当角色HP降低到0时,角色即进入了死亡状态,此时角色将倒在地上。在过去的游戏设计中,角色倒...在Unity3D中,系统为我们提供了布娃娃组件,下面请大家和我一起来学习怎样使用布娃娃来模拟角色死亡的状态
  • 本篇文章首发于作者个人博客,原链:https://www.huozk.com/2018/unity3d-bookofthedead.html 古埃及人相信,人死后要先经历一段去往冥国的旅程,通过各种考验后才能获得再生的机会。在埃及死者在通向复活之路时...
  • [Unity3D]Unity3D游戏开发之跑酷游戏项目讲解

    万次阅读 多人点赞 2015-01-04 14:43:03
    大家晚上好,我是秦元培,欢迎大家关注我的博客,我的博客地址是blog.csdn.net/...所以,今天的博客的主题就是《Unity3D游戏开发之跑酷游戏项目讲解》。从博主自身来考虑这件事情,当你选择做自己热爱的事情的时
1 2 3 4 5 ... 20
收藏数 548
精华内容 219
关键字:

unity3d 角色死亡